zhpgvd()

subroutine zhpgvd	(	integer	itype,
		character	jobz,
		character	uplo,
		integer	n,
		complex*16, dimension( * )	ap,
		complex*16, dimension( * )	bp,
		double precision, dimension( * )	w,
		complex*16, dimension( ldz, * )	z,
		integer	ldz,
		complex*16, dimension( * )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		integer	lrwork,
		integer, dimension( * )	iwork,
		integer	liwork,
		integer	info )

ZHPGVD

Download ZHPGVD + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZHPGVD computes all the eigenvalues and, optionally, the eigenvectors
!> of a complex generalized Hermitian-definite eigenproblem, of the form
!> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.  Here A and
!> B are assumed to be Hermitian, stored in packed format, and B is also
!> positive definite.
!> If eigenvectors are desired, it uses a divide and conquer algorithm.
!>
!> 

Parameters

[in]	ITYPE	!> ITYPE is INTEGER !> Specifies the problem type to be solved: !> = 1: A*x = (lambda)*B*x !> = 2: A*B*x = (lambda)*x !> = 3: B*A*x = (lambda)*x !>
[in]	JOBZ	!> JOBZ is CHARACTER*1 !> = 'N': Compute eigenvalues only; !> = 'V': Compute eigenvalues and eigenvectors. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangles of A and B are stored; !> = 'L': Lower triangles of A and B are stored. !>
[in]	N	!> N is INTEGER !> The order of the matrices A and B. N >= 0. !>
[in,out]	AP	!> AP is COMPLEX*16 array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangle of the Hermitian matrix !> A, packed columnwise in a linear array. The j-th column of A !> is stored in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n. !> !> On exit, the contents of AP are destroyed. !>
[in,out]	BP	!> BP is COMPLEX*16 array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangle of the Hermitian matrix !> B, packed columnwise in a linear array. The j-th column of B !> is stored in the array BP as follows: !> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j; !> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n. !> !> On exit, the triangular factor U or L from the Cholesky !> factorization B = U**H*U or B = L*L**H, in the same storage !> format as B. !>
[out]	W	!> W is DOUBLE PRECISION array, dimension (N) !> If INFO = 0, the eigenvalues in ascending order. !>
[out]	Z	!> Z is COMPLEX*16 array, dimension (LDZ, N) !> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of !> eigenvectors. The eigenvectors are normalized as follows: !> if ITYPE = 1 or 2, Z**H*B*Z = I; !> if ITYPE = 3, Z**H*inv(B)*Z = I. !> If JOBZ = 'N', then Z is not referenced. !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDZ >= 1, and if !> JOBZ = 'V', LDZ >= max(1,N). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the required LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If N <= 1, LWORK >= 1. !> If JOBZ = 'N' and N > 1, LWORK >= N. !> If JOBZ = 'V' and N > 1, LWORK >= 2*N. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the required sizes of the WORK, RWORK and !> IWORK arrays, returns these values as the first entries of !> the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (MAX(1,LRWORK)) !> On exit, if INFO = 0, RWORK(1) returns the required LRWORK. !>
[in]	LRWORK	!> LRWORK is INTEGER !> The dimension of array RWORK. !> If N <= 1, LRWORK >= 1. !> If JOBZ = 'N' and N > 1, LRWORK >= N. !> If JOBZ = 'V' and N > 1, LRWORK >= 1 + 5*N + 2*N**2. !> !> If LRWORK = -1, then a workspace query is assumed; the !> routine only calculates the required sizes of the WORK, RWORK !> and IWORK arrays, returns these values as the first entries !> of the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (MAX(1,LIWORK)) !> On exit, if INFO = 0, IWORK(1) returns the required LIWORK. !>
[in]	LIWORK	!> LIWORK is INTEGER !> The dimension of array IWORK. !> If JOBZ = 'N' or N <= 1, LIWORK >= 1. !> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N. !> !> If LIWORK = -1, then a workspace query is assumed; the !> routine only calculates the required sizes of the WORK, RWORK !> and IWORK arrays, returns these values as the first entries !> of the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: ZPPTRF or ZHPEVD returned an error code: !> <= N: if INFO = i, ZHPEVD failed to converge; !> i off-diagonal elements of an intermediate !> tridiagonal form did not convergeto zero; !> > N: if INFO = N + i, for 1 <= i <= n, then the leading !> principal minor of order i of B is not positive. !> The factorization of B could not be completed and !> no eigenvalues or eigenvectors were computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA

Definition at line 221 of file zhpgvd.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            INFO, ITYPE, LDZ, LIWORK, LRWORK, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      DOUBLE PRECISION   RWORK( * ), W( * )
      COMPLEX*16         AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER, WANTZ
      CHARACTER          TRANS
      INTEGER            J, LIWMIN, LRWMIN, LWMIN, NEIG
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zhpevd, zhpgst, zpptrf, ztpmv,
     $                   ztpsv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      wantz = lsame( jobz, 'V' )
      upper = lsame( uplo, 'U' )
      lquery = ( lwork.EQ.-1 .OR. lrwork.EQ.-1 .OR. liwork.EQ.-1 )
*
      info = 0
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
         info = -9
      END IF
*
      IF( info.EQ.0 ) THEN
         IF( n.LE.1 ) THEN
            lwmin = 1
            liwmin = 1
            lrwmin = 1
         ELSE
            IF( wantz ) THEN
               lwmin = 2*n
               lrwmin = 1 + 5*n + 2*n**2
               liwmin = 3 + 5*n
            ELSE
               lwmin = n
               lrwmin = n
               liwmin = 1
            END IF
         END IF
*
         work( 1 ) = lwmin
         rwork( 1 ) = real( lrwmin )
         iwork( 1 ) = liwmin
         IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
            info = -11
         ELSE IF( lrwork.LT.lrwmin .AND. .NOT.lquery ) THEN
            info = -13
         ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
            info = -15
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZHPGVD', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Form a Cholesky factorization of B.
*
      CALL zpptrf( uplo, n, bp, info )
      IF( info.NE.0 ) THEN
         info = n + info
         RETURN
      END IF
*
*     Transform problem to standard eigenvalue problem and solve.
*
      CALL zhpgst( itype, uplo, n, ap, bp, info )
      CALL zhpevd( jobz, uplo, n, ap, w, z, ldz, work, lwork, rwork,
     $             lrwork, iwork, liwork, info )
      lwmin = int( max( dble( lwmin ), dble( work( 1 ) ) ) )
      lrwmin = int( max( dble( lrwmin ), dble( rwork( 1 ) ) ) )
      liwmin = int( max( dble( liwmin ), dble( iwork( 1 ) ) ) )
*
      IF( wantz ) THEN
*
*        Backtransform eigenvectors to the original problem.
*
         neig = n
         IF( info.GT.0 )
     $      neig = info - 1
         IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
*
*           For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
*           backtransform eigenvectors: x = inv(L)**H *y or inv(U)*y
*
            IF( upper ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
            DO 10 j = 1, neig
               CALL ztpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
     $                     1 )
   10       CONTINUE
*
         ELSE IF( itype.EQ.3 ) THEN
*
*           For B*A*x=(lambda)*x;
*           backtransform eigenvectors: x = L*y or U**H *y
*
            IF( upper ) THEN
               trans = 'C'
            ELSE
               trans = 'N'
            END IF
*
            DO 20 j = 1, neig
               CALL ztpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
     $                     1 )
   20       CONTINUE
         END IF
      END IF
*
      work( 1 ) = lwmin
      rwork( 1 ) = real( lrwmin )
      iwork( 1 ) = liwmin
      RETURN
*
*     End of ZHPGVD
*

Here is the call graph for this function:

Here is the caller graph for this function: