LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
strsv.f
Go to the documentation of this file.
1*> \brief \b STRSV
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE STRSV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
12*
13* .. Scalar Arguments ..
14* INTEGER INCX,LDA,N
15* CHARACTER DIAG,TRANS,UPLO
16* ..
17* .. Array Arguments ..
18* REAL A(LDA,*),X(*)
19* ..
20*
21*
22*> \par Purpose:
23* =============
24*>
25*> \verbatim
26*>
27*> STRSV solves one of the systems of equations
28*>
29*> A*x = b, or A**T*x = b,
30*>
31*> where b and x are n element vectors and A is an n by n unit, or
32*> non-unit, upper or lower triangular matrix.
33*>
34*> No test for singularity or near-singularity is included in this
35*> routine. Such tests must be performed before calling this routine.
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] UPLO
42*> \verbatim
43*> UPLO is CHARACTER*1
44*> On entry, UPLO specifies whether the matrix is an upper or
45*> lower triangular matrix as follows:
46*>
47*> UPLO = 'U' or 'u' A is an upper triangular matrix.
48*>
49*> UPLO = 'L' or 'l' A is a lower triangular matrix.
50*> \endverbatim
51*>
52*> \param[in] TRANS
53*> \verbatim
54*> TRANS is CHARACTER*1
55*> On entry, TRANS specifies the equations to be solved as
56*> follows:
57*>
58*> TRANS = 'N' or 'n' A*x = b.
59*>
60*> TRANS = 'T' or 't' A**T*x = b.
61*>
62*> TRANS = 'C' or 'c' A**T*x = b.
63*> \endverbatim
64*>
65*> \param[in] DIAG
66*> \verbatim
67*> DIAG is CHARACTER*1
68*> On entry, DIAG specifies whether or not A is unit
69*> triangular as follows:
70*>
71*> DIAG = 'U' or 'u' A is assumed to be unit triangular.
72*>
73*> DIAG = 'N' or 'n' A is not assumed to be unit
74*> triangular.
75*> \endverbatim
76*>
77*> \param[in] N
78*> \verbatim
79*> N is INTEGER
80*> On entry, N specifies the order of the matrix A.
81*> N must be at least zero.
82*> \endverbatim
83*>
84*> \param[in] A
85*> \verbatim
86*> A is REAL array, dimension ( LDA, N )
87*> Before entry with UPLO = 'U' or 'u', the leading n by n
88*> upper triangular part of the array A must contain the upper
89*> triangular matrix and the strictly lower triangular part of
90*> A is not referenced.
91*> Before entry with UPLO = 'L' or 'l', the leading n by n
92*> lower triangular part of the array A must contain the lower
93*> triangular matrix and the strictly upper triangular part of
94*> A is not referenced.
95*> Note that when DIAG = 'U' or 'u', the diagonal elements of
96*> A are not referenced either, but are assumed to be unity.
97*> \endverbatim
98*>
99*> \param[in] LDA
100*> \verbatim
101*> LDA is INTEGER
102*> On entry, LDA specifies the first dimension of A as declared
103*> in the calling (sub) program. LDA must be at least
104*> max( 1, n ).
105*> \endverbatim
106*>
107*> \param[in,out] X
108*> \verbatim
109*> X is REAL array, dimension at least
110*> ( 1 + ( n - 1 )*abs( INCX ) ).
111*> Before entry, the incremented array X must contain the n
112*> element right-hand side vector b. On exit, X is overwritten
113*> with the solution vector x.
114*> \endverbatim
115*>
116*> \param[in] INCX
117*> \verbatim
118*> INCX is INTEGER
119*> On entry, INCX specifies the increment for the elements of
120*> X. INCX must not be zero.
121*> \endverbatim
122*
123* Authors:
124* ========
125*
126*> \author Univ. of Tennessee
127*> \author Univ. of California Berkeley
128*> \author Univ. of Colorado Denver
129*> \author NAG Ltd.
130*
131*> \ingroup trsv
132*
133*> \par Further Details:
134* =====================
135*>
136*> \verbatim
137*>
138*> Level 2 Blas routine.
139*>
140*> -- Written on 22-October-1986.
141*> Jack Dongarra, Argonne National Lab.
142*> Jeremy Du Croz, Nag Central Office.
143*> Sven Hammarling, Nag Central Office.
144*> Richard Hanson, Sandia National Labs.
145*> \endverbatim
146*>
147* =====================================================================
148 SUBROUTINE strsv(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
149*
150* -- Reference BLAS level2 routine --
151* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
152* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
153*
154* .. Scalar Arguments ..
155 INTEGER INCX,LDA,N
156 CHARACTER DIAG,TRANS,UPLO
157* ..
158* .. Array Arguments ..
159 REAL A(LDA,*),X(*)
160* ..
161*
162* =====================================================================
163*
164* .. Parameters ..
165 REAL ZERO
166 parameter(zero=0.0e+0)
167* ..
168* .. Local Scalars ..
169 REAL TEMP
170 INTEGER I,INFO,IX,J,JX,KX
171 LOGICAL NOUNIT
172* ..
173* .. External Functions ..
174 LOGICAL LSAME
175 EXTERNAL lsame
176* ..
177* .. External Subroutines ..
178 EXTERNAL xerbla
179* ..
180* .. Intrinsic Functions ..
181 INTRINSIC max
182* ..
183*
184* Test the input parameters.
185*
186 info = 0
187 IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
188 info = 1
189 ELSE IF (.NOT.lsame(trans,'N') .AND.
190 + .NOT.lsame(trans,'T') .AND.
191 + .NOT.lsame(trans,'C')) THEN
192 info = 2
193 ELSE IF (.NOT.lsame(diag,'U') .AND.
194 + .NOT.lsame(diag,'N')) THEN
195 info = 3
196 ELSE IF (n.LT.0) THEN
197 info = 4
198 ELSE IF (lda.LT.max(1,n)) THEN
199 info = 6
200 ELSE IF (incx.EQ.0) THEN
201 info = 8
202 END IF
203 IF (info.NE.0) THEN
204 CALL xerbla('STRSV ',info)
205 RETURN
206 END IF
207*
208* Quick return if possible.
209*
210 IF (n.EQ.0) RETURN
211*
212 nounit = lsame(diag,'N')
213*
214* Set up the start point in X if the increment is not unity. This
215* will be ( N - 1 )*INCX too small for descending loops.
216*
217 IF (incx.LE.0) THEN
218 kx = 1 - (n-1)*incx
219 ELSE IF (incx.NE.1) THEN
220 kx = 1
221 END IF
222*
223* Start the operations. In this version the elements of A are
224* accessed sequentially with one pass through A.
225*
226 IF (lsame(trans,'N')) THEN
227*
228* Form x := inv( A )*x.
229*
230 IF (lsame(uplo,'U')) THEN
231 IF (incx.EQ.1) THEN
232 DO 20 j = n,1,-1
233 IF (x(j).NE.zero) THEN
234 IF (nounit) x(j) = x(j)/a(j,j)
235 temp = x(j)
236 DO 10 i = j - 1,1,-1
237 x(i) = x(i) - temp*a(i,j)
238 10 CONTINUE
239 END IF
240 20 CONTINUE
241 ELSE
242 jx = kx + (n-1)*incx
243 DO 40 j = n,1,-1
244 IF (x(jx).NE.zero) THEN
245 IF (nounit) x(jx) = x(jx)/a(j,j)
246 temp = x(jx)
247 ix = jx
248 DO 30 i = j - 1,1,-1
249 ix = ix - incx
250 x(ix) = x(ix) - temp*a(i,j)
251 30 CONTINUE
252 END IF
253 jx = jx - incx
254 40 CONTINUE
255 END IF
256 ELSE
257 IF (incx.EQ.1) THEN
258 DO 60 j = 1,n
259 IF (x(j).NE.zero) THEN
260 IF (nounit) x(j) = x(j)/a(j,j)
261 temp = x(j)
262 DO 50 i = j + 1,n
263 x(i) = x(i) - temp*a(i,j)
264 50 CONTINUE
265 END IF
266 60 CONTINUE
267 ELSE
268 jx = kx
269 DO 80 j = 1,n
270 IF (x(jx).NE.zero) THEN
271 IF (nounit) x(jx) = x(jx)/a(j,j)
272 temp = x(jx)
273 ix = jx
274 DO 70 i = j + 1,n
275 ix = ix + incx
276 x(ix) = x(ix) - temp*a(i,j)
277 70 CONTINUE
278 END IF
279 jx = jx + incx
280 80 CONTINUE
281 END IF
282 END IF
283 ELSE
284*
285* Form x := inv( A**T )*x.
286*
287 IF (lsame(uplo,'U')) THEN
288 IF (incx.EQ.1) THEN
289 DO 100 j = 1,n
290 temp = x(j)
291 DO 90 i = 1,j - 1
292 temp = temp - a(i,j)*x(i)
293 90 CONTINUE
294 IF (nounit) temp = temp/a(j,j)
295 x(j) = temp
296 100 CONTINUE
297 ELSE
298 jx = kx
299 DO 120 j = 1,n
300 temp = x(jx)
301 ix = kx
302 DO 110 i = 1,j - 1
303 temp = temp - a(i,j)*x(ix)
304 ix = ix + incx
305 110 CONTINUE
306 IF (nounit) temp = temp/a(j,j)
307 x(jx) = temp
308 jx = jx + incx
309 120 CONTINUE
310 END IF
311 ELSE
312 IF (incx.EQ.1) THEN
313 DO 140 j = n,1,-1
314 temp = x(j)
315 DO 130 i = n,j + 1,-1
316 temp = temp - a(i,j)*x(i)
317 130 CONTINUE
318 IF (nounit) temp = temp/a(j,j)
319 x(j) = temp
320 140 CONTINUE
321 ELSE
322 kx = kx + (n-1)*incx
323 jx = kx
324 DO 160 j = n,1,-1
325 temp = x(jx)
326 ix = kx
327 DO 150 i = n,j + 1,-1
328 temp = temp - a(i,j)*x(ix)
329 ix = ix - incx
330 150 CONTINUE
331 IF (nounit) temp = temp/a(j,j)
332 x(jx) = temp
333 jx = jx - incx
334 160 CONTINUE
335 END IF
336 END IF
337 END IF
338*
339 RETURN
340*
341* End of STRSV
342*
343 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine strsv(uplo, trans, diag, n, a, lda, x, incx)
STRSV
Definition strsv.f:149