chpgv()

subroutine chpgv	(	integer	itype,
		character	jobz,
		character	uplo,
		integer	n,
		complex, dimension( * )	ap,
		complex, dimension( * )	bp,
		real, dimension( * )	w,
		complex, dimension( ldz, * )	z,
		integer	ldz,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	info )

CHPGV

Download CHPGV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHPGV computes all the eigenvalues and, optionally, the eigenvectors
!> of a complex generalized Hermitian-definite eigenproblem, of the form
!> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.
!> Here A and B are assumed to be Hermitian, stored in packed format,
!> and B is also positive definite.
!> 

Parameters

[in]	ITYPE	!> ITYPE is INTEGER !> Specifies the problem type to be solved: !> = 1: A*x = (lambda)*B*x !> = 2: A*B*x = (lambda)*x !> = 3: B*A*x = (lambda)*x !>
[in]	JOBZ	!> JOBZ is CHARACTER*1 !> = 'N': Compute eigenvalues only; !> = 'V': Compute eigenvalues and eigenvectors. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangles of A and B are stored; !> = 'L': Lower triangles of A and B are stored. !>
[in]	N	!> N is INTEGER !> The order of the matrices A and B. N >= 0. !>
[in,out]	AP	!> AP is COMPLEX array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangle of the Hermitian matrix !> A, packed columnwise in a linear array. The j-th column of A !> is stored in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n. !> !> On exit, the contents of AP are destroyed. !>
[in,out]	BP	!> BP is COMPLEX array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangle of the Hermitian matrix !> B, packed columnwise in a linear array. The j-th column of B !> is stored in the array BP as follows: !> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j; !> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n. !> !> On exit, the triangular factor U or L from the Cholesky !> factorization B = U**H*U or B = L*L**H, in the same storage !> format as B. !>
[out]	W	!> W is REAL array, dimension (N) !> If INFO = 0, the eigenvalues in ascending order. !>
[out]	Z	!> Z is COMPLEX array, dimension (LDZ, N) !> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of !> eigenvectors. The eigenvectors are normalized as follows: !> if ITYPE = 1 or 2, Z**H*B*Z = I; !> if ITYPE = 3, Z**H*inv(B)*Z = I. !> If JOBZ = 'N', then Z is not referenced. !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDZ >= 1, and if !> JOBZ = 'V', LDZ >= max(1,N). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (max(1, 2*N-1)) !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(1, 3*N-2)) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: CPPTRF or CHPEV returned an error code: !> <= N: if INFO = i, CHPEV failed to converge; !> i off-diagonal elements of an intermediate !> tridiagonal form did not convergeto zero; !> > N: if INFO = N + i, for 1 <= i <= n, then the leading !> principal minor of order i of B is not positive. !> The factorization of B could not be completed and !> no eigenvalues or eigenvectors were computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 161 of file chpgv.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            INFO, ITYPE, LDZ, N
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * ), W( * )
      COMPLEX            AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            UPPER, WANTZ
      CHARACTER          TRANS
      INTEGER            J, NEIG
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           chpev, chpgst, cpptrf, ctpmv, ctpsv,
     $                   xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      wantz = lsame( jobz, 'V' )
      upper = lsame( uplo, 'U' )
*
      info = 0
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHPGV ', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Form a Cholesky factorization of B.
*
      CALL cpptrf( uplo, n, bp, info )
      IF( info.NE.0 ) THEN
         info = n + info
         RETURN
      END IF
*
*     Transform problem to standard eigenvalue problem and solve.
*
      CALL chpgst( itype, uplo, n, ap, bp, info )
      CALL chpev( jobz, uplo, n, ap, w, z, ldz, work, rwork, info )
*
      IF( wantz ) THEN
*
*        Backtransform eigenvectors to the original problem.
*
         neig = n
         IF( info.GT.0 )
     $      neig = info - 1
         IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
*
*           For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
*           backtransform eigenvectors: x = inv(L)**H*y or inv(U)*y
*
            IF( upper ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
            DO 10 j = 1, neig
               CALL ctpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
     $                     1 )
   10       CONTINUE
*
         ELSE IF( itype.EQ.3 ) THEN
*
*           For B*A*x=(lambda)*x;
*           backtransform eigenvectors: x = L*y or U**H*y
*
            IF( upper ) THEN
               trans = 'C'
            ELSE
               trans = 'N'
            END IF
*
            DO 20 j = 1, neig
               CALL ctpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
     $                     1 )
   20       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of CHPGV
*

Here is the call graph for this function:

Here is the caller graph for this function: