cgtt05.f

Go to the documentation of this file.

*> \brief \b CGTT05
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGTT05( TRANS, N, NRHS, DL, D, DU, B, LDB, X, LDX,
*                          XACT, LDXACT, FERR, BERR, RESLTS )
* 
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            LDB, LDX, LDXACT, N, NRHS
*       ..
*       .. Array Arguments ..
*       REAL               BERR( * ), FERR( * ), RESLTS( * )
*       COMPLEX            B( LDB, * ), D( * ), DL( * ), DU( * ),
*      $                   X( LDX, * ), XACT( LDXACT, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGTT05 tests the error bounds from iterative refinement for the
*> computed solution to a system of equations A*X = B, where A is a
*> general tridiagonal matrix of order n and op(A) = A or A**T,
*> depending on TRANS.
*>
*> RESLTS(1) = test of the error bound
*>           = norm(X - XACT) / ( norm(X) * FERR )
*>
*> A large value is returned if this ratio is not less than one.
*>
*> RESLTS(2) = residual from the iterative refinement routine
*>           = the maximum of BERR / ( NZ*EPS + (*) ), where
*>             (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
*>             and NZ = max. number of nonzeros in any row of A, plus 1
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          Specifies the form of the system of equations.
*>          = 'N':  A * X = B     (No transpose)
*>          = 'T':  A**T * X = B  (Transpose)
*>          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows of the matrices X and XACT.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of columns of the matrices X and XACT.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] DL
*> \verbatim
*>          DL is COMPLEX array, dimension (N-1)
*>          The (n-1) sub-diagonal elements of A.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is COMPLEX array, dimension (N)
*>          The diagonal elements of A.
*> \endverbatim
*>
*> \param[in] DU
*> \verbatim
*>          DU is COMPLEX array, dimension (N-1)
*>          The (n-1) super-diagonal elements of A.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          The right hand side vectors for the system of linear
*>          equations.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX array, dimension (LDX,NRHS)
*>          The computed solution vectors.  Each vector is stored as a
*>          column of the matrix X.
*> \endverbatim
*>
*> \param[in] LDX
*> \verbatim
*>          LDX is INTEGER
*>          The leading dimension of the array X.  LDX >= max(1,N).
*> \endverbatim
*>
*> \param[in] XACT
*> \verbatim
*>          XACT is COMPLEX array, dimension (LDX,NRHS)
*>          The exact solution vectors.  Each vector is stored as a
*>          column of the matrix XACT.
*> \endverbatim
*>
*> \param[in] LDXACT
*> \verbatim
*>          LDXACT is INTEGER
*>          The leading dimension of the array XACT.  LDXACT >= max(1,N).
*> \endverbatim
*>
*> \param[in] FERR
*> \verbatim
*>          FERR is REAL array, dimension (NRHS)
*>          The estimated forward error bounds for each solution vector
*>          X.  If XTRUE is the true solution, FERR bounds the magnitude
*>          of the largest entry in (X - XTRUE) divided by the magnitude
*>          of the largest entry in X.
*> \endverbatim
*>
*> \param[in] BERR
*> \verbatim
*>          BERR is REAL array, dimension (NRHS)
*>          The componentwise relative backward error of each solution
*>          vector (i.e., the smallest relative change in any entry of A
*>          or B that makes X an exact solution).
*> \endverbatim
*>
*> \param[out] RESLTS
*> \verbatim
*>          RESLTS is REAL array, dimension (2)
*>          The maximum over the NRHS solution vectors of the ratios:
*>          RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
*>          RESLTS(2) = BERR / ( NZ*EPS + (*) )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cgtt05( TRANS, N, NRHS, DL, D, DU, B, LDB, X, LDX,
     $                   xact, ldxact, ferr, berr, reslts )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDB, LDX, LDXACT, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               BERR( * ), FERR( * ), RESLTS( * )
      COMPLEX            B( ldb, * ), D( * ), DL( * ), DU( * ),
     $                   x( ldx, * ), xact( ldxact, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN
      INTEGER            I, IMAX, J, K, NZ
      REAL               AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAMCH
      EXTERNAL           lsame, icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, min, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( AIMAG( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      notran = lsame( trans, 'N' )
      nz = 4
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = icamax( n, x( 1, j ), 1 )
         xnorm = max( cabs1( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, cabs1( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
*
         IF( xnorm.GT.one ) THEN
            GO TO 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            GO TO 20
         ELSE
            errbnd = one / eps
            GO TO 30
         END IF
*
   20    CONTINUE
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 CONTINUE
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( NZ*EPS + (*) ), where
*     (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
*
      DO 60 k = 1, nrhs
         IF( notran ) THEN
            IF( n.EQ.1 ) THEN
               axbi = cabs1( b( 1, k ) ) +
     $                cabs1( d( 1 ) )*cabs1( x( 1, k ) )
            ELSE
               axbi = cabs1( b( 1, k ) ) +
     $                cabs1( d( 1 ) )*cabs1( x( 1, k ) ) +
     $                cabs1( du( 1 ) )*cabs1( x( 2, k ) )
               DO 40 i = 2, n - 1
                  tmp = cabs1( b( i, k ) ) +
     $                  cabs1( dl( i-1 ) )*cabs1( x( i-1, k ) ) +
     $                  cabs1( d( i ) )*cabs1( x( i, k ) ) +
     $                  cabs1( du( i ) )*cabs1( x( i+1, k ) )
                  axbi = min( axbi, tmp )
   40          CONTINUE
               tmp = cabs1( b( n, k ) ) + cabs1( dl( n-1 ) )*
     $               cabs1( x( n-1, k ) ) + cabs1( d( n ) )*
     $               cabs1( x( n, k ) )
               axbi = min( axbi, tmp )
            END IF
         ELSE
            IF( n.EQ.1 ) THEN
               axbi = cabs1( b( 1, k ) ) +
     $                cabs1( d( 1 ) )*cabs1( x( 1, k ) )
            ELSE
               axbi = cabs1( b( 1, k ) ) +
     $                cabs1( d( 1 ) )*cabs1( x( 1, k ) ) +
     $                cabs1( dl( 1 ) )*cabs1( x( 2, k ) )
               DO 50 i = 2, n - 1
                  tmp = cabs1( b( i, k ) ) +
     $                  cabs1( du( i-1 ) )*cabs1( x( i-1, k ) ) +
     $                  cabs1( d( i ) )*cabs1( x( i, k ) ) +
     $                  cabs1( dl( i ) )*cabs1( x( i+1, k ) )
                  axbi = min( axbi, tmp )
   50          CONTINUE
               tmp = cabs1( b( n, k ) ) + cabs1( du( n-1 ) )*
     $               cabs1( x( n-1, k ) ) + cabs1( d( n ) )*
     $               cabs1( x( n, k ) )
               axbi = min( axbi, tmp )
            END IF
         END IF
         tmp = berr( k ) / ( nz*eps+nz*unfl / max( axbi, nz*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   60 CONTINUE
*
      RETURN
*
*     End of CGTT05
*
      END