LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
sormbr.f
Go to the documentation of this file.
1 *> \brief \b SORMBR
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormbr.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormbr.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormbr.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SORMBR( VECT, SIDE, TRANS, M, N, K, A, LDA, TAU, C,
22 * LDC, WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS, VECT
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * REAL A( LDA, * ), C( LDC, * ), TAU( * ),
30 * \$ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> If VECT = 'Q', SORMBR overwrites the general real M-by-N matrix C
40 *> with
41 *> SIDE = 'L' SIDE = 'R'
42 *> TRANS = 'N': Q * C C * Q
43 *> TRANS = 'T': Q**T * C C * Q**T
44 *>
45 *> If VECT = 'P', SORMBR overwrites the general real M-by-N matrix C
46 *> with
47 *> SIDE = 'L' SIDE = 'R'
48 *> TRANS = 'N': P * C C * P
49 *> TRANS = 'T': P**T * C C * P**T
50 *>
51 *> Here Q and P**T are the orthogonal matrices determined by SGEBRD when
52 *> reducing a real matrix A to bidiagonal form: A = Q * B * P**T. Q and
53 *> P**T are defined as products of elementary reflectors H(i) and G(i)
54 *> respectively.
55 *>
56 *> Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
57 *> order of the orthogonal matrix Q or P**T that is applied.
58 *>
59 *> If VECT = 'Q', A is assumed to have been an NQ-by-K matrix:
60 *> if nq >= k, Q = H(1) H(2) . . . H(k);
61 *> if nq < k, Q = H(1) H(2) . . . H(nq-1).
62 *>
63 *> If VECT = 'P', A is assumed to have been a K-by-NQ matrix:
64 *> if k < nq, P = G(1) G(2) . . . G(k);
65 *> if k >= nq, P = G(1) G(2) . . . G(nq-1).
66 *> \endverbatim
67 *
68 * Arguments:
69 * ==========
70 *
71 *> \param[in] VECT
72 *> \verbatim
73 *> VECT is CHARACTER*1
74 *> = 'Q': apply Q or Q**T;
75 *> = 'P': apply P or P**T.
76 *> \endverbatim
77 *>
78 *> \param[in] SIDE
79 *> \verbatim
80 *> SIDE is CHARACTER*1
81 *> = 'L': apply Q, Q**T, P or P**T from the Left;
82 *> = 'R': apply Q, Q**T, P or P**T from the Right.
83 *> \endverbatim
84 *>
85 *> \param[in] TRANS
86 *> \verbatim
87 *> TRANS is CHARACTER*1
88 *> = 'N': No transpose, apply Q or P;
89 *> = 'T': Transpose, apply Q**T or P**T.
90 *> \endverbatim
91 *>
92 *> \param[in] M
93 *> \verbatim
94 *> M is INTEGER
95 *> The number of rows of the matrix C. M >= 0.
96 *> \endverbatim
97 *>
98 *> \param[in] N
99 *> \verbatim
100 *> N is INTEGER
101 *> The number of columns of the matrix C. N >= 0.
102 *> \endverbatim
103 *>
104 *> \param[in] K
105 *> \verbatim
106 *> K is INTEGER
107 *> If VECT = 'Q', the number of columns in the original
108 *> matrix reduced by SGEBRD.
109 *> If VECT = 'P', the number of rows in the original
110 *> matrix reduced by SGEBRD.
111 *> K >= 0.
112 *> \endverbatim
113 *>
114 *> \param[in] A
115 *> \verbatim
116 *> A is REAL array, dimension
117 *> (LDA,min(nq,K)) if VECT = 'Q'
118 *> (LDA,nq) if VECT = 'P'
119 *> The vectors which define the elementary reflectors H(i) and
120 *> G(i), whose products determine the matrices Q and P, as
121 *> returned by SGEBRD.
122 *> \endverbatim
123 *>
124 *> \param[in] LDA
125 *> \verbatim
126 *> LDA is INTEGER
127 *> The leading dimension of the array A.
128 *> If VECT = 'Q', LDA >= max(1,nq);
129 *> if VECT = 'P', LDA >= max(1,min(nq,K)).
130 *> \endverbatim
131 *>
132 *> \param[in] TAU
133 *> \verbatim
134 *> TAU is REAL array, dimension (min(nq,K))
135 *> TAU(i) must contain the scalar factor of the elementary
136 *> reflector H(i) or G(i) which determines Q or P, as returned
137 *> by SGEBRD in the array argument TAUQ or TAUP.
138 *> \endverbatim
139 *>
140 *> \param[in,out] C
141 *> \verbatim
142 *> C is REAL array, dimension (LDC,N)
143 *> On entry, the M-by-N matrix C.
144 *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q
145 *> or P*C or P**T*C or C*P or C*P**T.
146 *> \endverbatim
147 *>
148 *> \param[in] LDC
149 *> \verbatim
150 *> LDC is INTEGER
151 *> The leading dimension of the array C. LDC >= max(1,M).
152 *> \endverbatim
153 *>
154 *> \param[out] WORK
155 *> \verbatim
156 *> WORK is REAL array, dimension (MAX(1,LWORK))
157 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
158 *> \endverbatim
159 *>
160 *> \param[in] LWORK
161 *> \verbatim
162 *> LWORK is INTEGER
163 *> The dimension of the array WORK.
164 *> If SIDE = 'L', LWORK >= max(1,N);
165 *> if SIDE = 'R', LWORK >= max(1,M).
166 *> For optimum performance LWORK >= N*NB if SIDE = 'L', and
167 *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal
168 *> blocksize.
169 *>
170 *> If LWORK = -1, then a workspace query is assumed; the routine
171 *> only calculates the optimal size of the WORK array, returns
172 *> this value as the first entry of the WORK array, and no error
173 *> message related to LWORK is issued by XERBLA.
174 *> \endverbatim
175 *>
176 *> \param[out] INFO
177 *> \verbatim
178 *> INFO is INTEGER
179 *> = 0: successful exit
180 *> < 0: if INFO = -i, the i-th argument had an illegal value
181 *> \endverbatim
182 *
183 * Authors:
184 * ========
185 *
186 *> \author Univ. of Tennessee
187 *> \author Univ. of California Berkeley
188 *> \author Univ. of Colorado Denver
189 *> \author NAG Ltd.
190 *
191 *> \date November 2011
192 *
193 *> \ingroup realOTHERcomputational
194 *
195 * =====================================================================
196  SUBROUTINE sormbr( VECT, SIDE, TRANS, M, N, K, A, LDA, TAU, C,
197  \$ ldc, work, lwork, info )
198 *
199 * -- LAPACK computational routine (version 3.4.0) --
200 * -- LAPACK is a software package provided by Univ. of Tennessee, --
201 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
202 * November 2011
203 *
204 * .. Scalar Arguments ..
205  CHARACTER SIDE, TRANS, VECT
206  INTEGER INFO, K, LDA, LDC, LWORK, M, N
207 * ..
208 * .. Array Arguments ..
209  REAL A( lda, * ), C( ldc, * ), TAU( * ),
210  \$ work( * )
211 * ..
212 *
213 * =====================================================================
214 *
215 * .. Local Scalars ..
216  LOGICAL APPLYQ, LEFT, LQUERY, NOTRAN
217  CHARACTER TRANST
218  INTEGER I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
219 * ..
220 * .. External Functions ..
221  LOGICAL LSAME
222  INTEGER ILAENV
223  EXTERNAL ilaenv, lsame
224 * ..
225 * .. External Subroutines ..
226  EXTERNAL sormlq, sormqr, xerbla
227 * ..
228 * .. Intrinsic Functions ..
229  INTRINSIC max, min
230 * ..
231 * .. Executable Statements ..
232 *
233 * Test the input arguments
234 *
235  info = 0
236  applyq = lsame( vect, 'Q' )
237  left = lsame( side, 'L' )
238  notran = lsame( trans, 'N' )
239  lquery = ( lwork.EQ.-1 )
240 *
241 * NQ is the order of Q or P and NW is the minimum dimension of WORK
242 *
243  IF( left ) THEN
244  nq = m
245  nw = n
246  ELSE
247  nq = n
248  nw = m
249  END IF
250  IF( .NOT.applyq .AND. .NOT.lsame( vect, 'P' ) ) THEN
251  info = -1
252  ELSE IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
253  info = -2
254  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
255  info = -3
256  ELSE IF( m.LT.0 ) THEN
257  info = -4
258  ELSE IF( n.LT.0 ) THEN
259  info = -5
260  ELSE IF( k.LT.0 ) THEN
261  info = -6
262  ELSE IF( ( applyq .AND. lda.LT.max( 1, nq ) ) .OR.
263  \$ ( .NOT.applyq .AND. lda.LT.max( 1, min( nq, k ) ) ) )
264  \$ THEN
265  info = -8
266  ELSE IF( ldc.LT.max( 1, m ) ) THEN
267  info = -11
268  ELSE IF( lwork.LT.max( 1, nw ) .AND. .NOT.lquery ) THEN
269  info = -13
270  END IF
271 *
272  IF( info.EQ.0 ) THEN
273  IF( applyq ) THEN
274  IF( left ) THEN
275  nb = ilaenv( 1, 'SORMQR', side // trans, m-1, n, m-1,
276  \$ -1 )
277  ELSE
278  nb = ilaenv( 1, 'SORMQR', side // trans, m, n-1, n-1,
279  \$ -1 )
280  END IF
281  ELSE
282  IF( left ) THEN
283  nb = ilaenv( 1, 'SORMLQ', side // trans, m-1, n, m-1,
284  \$ -1 )
285  ELSE
286  nb = ilaenv( 1, 'SORMLQ', side // trans, m, n-1, n-1,
287  \$ -1 )
288  END IF
289  END IF
290  lwkopt = max( 1, nw )*nb
291  work( 1 ) = lwkopt
292  END IF
293 *
294  IF( info.NE.0 ) THEN
295  CALL xerbla( 'SORMBR', -info )
296  RETURN
297  ELSE IF( lquery ) THEN
298  RETURN
299  END IF
300 *
301 * Quick return if possible
302 *
303  work( 1 ) = 1
304  IF( m.EQ.0 .OR. n.EQ.0 )
305  \$ RETURN
306 *
307  IF( applyq ) THEN
308 *
309 * Apply Q
310 *
311  IF( nq.GE.k ) THEN
312 *
313 * Q was determined by a call to SGEBRD with nq >= k
314 *
315  CALL sormqr( side, trans, m, n, k, a, lda, tau, c, ldc,
316  \$ work, lwork, iinfo )
317  ELSE IF( nq.GT.1 ) THEN
318 *
319 * Q was determined by a call to SGEBRD with nq < k
320 *
321  IF( left ) THEN
322  mi = m - 1
323  ni = n
324  i1 = 2
325  i2 = 1
326  ELSE
327  mi = m
328  ni = n - 1
329  i1 = 1
330  i2 = 2
331  END IF
332  CALL sormqr( side, trans, mi, ni, nq-1, a( 2, 1 ), lda, tau,
333  \$ c( i1, i2 ), ldc, work, lwork, iinfo )
334  END IF
335  ELSE
336 *
337 * Apply P
338 *
339  IF( notran ) THEN
340  transt = 'T'
341  ELSE
342  transt = 'N'
343  END IF
344  IF( nq.GT.k ) THEN
345 *
346 * P was determined by a call to SGEBRD with nq > k
347 *
348  CALL sormlq( side, transt, m, n, k, a, lda, tau, c, ldc,
349  \$ work, lwork, iinfo )
350  ELSE IF( nq.GT.1 ) THEN
351 *
352 * P was determined by a call to SGEBRD with nq <= k
353 *
354  IF( left ) THEN
355  mi = m - 1
356  ni = n
357  i1 = 2
358  i2 = 1
359  ELSE
360  mi = m
361  ni = n - 1
362  i1 = 1
363  i2 = 2
364  END IF
365  CALL sormlq( side, transt, mi, ni, nq-1, a( 1, 2 ), lda,
366  \$ tau, c( i1, i2 ), ldc, work, lwork, iinfo )
367  END IF
368  END IF
369  work( 1 ) = lwkopt
370  RETURN
371 *
372 * End of SORMBR
373 *
374  END
subroutine sormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMQR
Definition: sormqr.f:170
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sormlq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMLQ
Definition: sormlq.f:170
subroutine sormbr(VECT, SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMBR
Definition: sormbr.f:198