LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine dgerfsx ( character TRANS, character EQUED, integer N, integer NRHS, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( ldaf, * ) AF, integer LDAF, integer, dimension( * ) IPIV, double precision, dimension( * ) R, double precision, dimension( * ) C, double precision, dimension( ldb, * ) B, integer LDB, double precision, dimension( ldx , * ) X, integer LDX, double precision RCOND, double precision, dimension( * ) BERR, integer N_ERR_BNDS, double precision, dimension( nrhs, * ) ERR_BNDS_NORM, double precision, dimension( nrhs, * ) ERR_BNDS_COMP, integer NPARAMS, double precision, dimension( * ) PARAMS, double precision, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

DGERFSX

Purpose:
```    DGERFSX improves the computed solution to a system of linear
equations and provides error bounds and backward error estimates
for the solution.  In addition to normwise error bound, the code
provides maximum componentwise error bound if possible.  See
comments for ERR_BNDS_NORM and ERR_BNDS_COMP for details of the
error bounds.

The original system of linear equations may have been equilibrated
before calling this routine, as described by arguments EQUED, R
and C below. In this case, the solution and error bounds returned
are for the original unequilibrated system.```
```     Some optional parameters are bundled in the PARAMS array.  These
settings determine how refinement is performed, but often the
defaults are acceptable.  If the defaults are acceptable, users
can pass NPARAMS = 0 which prevents the source code from accessing
the PARAMS argument.```
Parameters
 [in] TRANS ``` TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose = Transpose)``` [in] EQUED ``` EQUED is CHARACTER*1 Specifies the form of equilibration that was done to A before calling this routine. This is needed to compute the solution and error bounds correctly. = 'N': No equilibration = 'R': Row equilibration, i.e., A has been premultiplied by diag(R). = 'C': Column equilibration, i.e., A has been postmultiplied by diag(C). = 'B': Both row and column equilibration, i.e., A has been replaced by diag(R) * A * diag(C). The right hand side B has been changed accordingly.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.``` [in] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) The original N-by-N matrix A.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [in] AF ``` AF is DOUBLE PRECISION array, dimension (LDAF,N) The factors L and U from the factorization A = P*L*U as computed by DGETRF.``` [in] LDAF ``` LDAF is INTEGER The leading dimension of the array AF. LDAF >= max(1,N).``` [in] IPIV ``` IPIV is INTEGER array, dimension (N) The pivot indices from DGETRF; for 1<=i<=N, row i of the matrix was interchanged with row IPIV(i).``` [in] R ``` R is DOUBLE PRECISION array, dimension (N) The row scale factors for A. If EQUED = 'R' or 'B', A is multiplied on the left by diag(R); if EQUED = 'N' or 'C', R is not accessed. If R is accessed, each element of R should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in] C ``` C is DOUBLE PRECISION array, dimension (N) The column scale factors for A. If EQUED = 'C' or 'B', A is multiplied on the right by diag(C); if EQUED = 'N' or 'R', C is not accessed. If C is accessed, each element of C should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in] B ``` B is DOUBLE PRECISION array, dimension (LDB,NRHS) The right hand side matrix B.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [in,out] X ``` X is DOUBLE PRECISION array, dimension (LDX,NRHS) On entry, the solution matrix X, as computed by DGETRS. On exit, the improved solution matrix X.``` [in] LDX ``` LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).``` [out] RCOND ``` RCOND is DOUBLE PRECISION Reciprocal scaled condition number. This is an estimate of the reciprocal Skeel condition number of the matrix A after equilibration (if done). If this is less than the machine precision (in particular, if it is zero), the matrix is singular to working precision. Note that the error may still be small even if this number is very small and the matrix appears ill- conditioned.``` [out] BERR ``` BERR is DOUBLE PRECISION array, dimension (NRHS) Componentwise relative backward error. This is the componentwise relative backward error of each solution vector X(j) (i.e., the smallest relative change in any element of A or B that makes X(j) an exact solution).``` [in] N_ERR_BNDS ``` N_ERR_BNDS is INTEGER Number of error bounds to return for each right hand side and each type (normwise or componentwise). See ERR_BNDS_NORM and ERR_BNDS_COMP below.``` [out] ERR_BNDS_NORM ``` ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the normwise relative error, which is defined as follows: Normwise relative error in the ith solution vector: max_j (abs(XTRUE(j,i) - X(j,i))) ------------------------------ max_j abs(X(j,i)) The array is indexed by the type of error information as described below. There currently are up to three pieces of information returned. The first index in ERR_BNDS_NORM(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_NORM(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * dlamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * dlamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated normwise reciprocal condition number. Compared with the threshold sqrt(n) * dlamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*A, where S scales each row by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [out] ERR_BNDS_COMP ``` ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the componentwise relative error, which is defined as follows: Componentwise relative error in the ith solution vector: abs(XTRUE(j,i) - X(j,i)) max_j ---------------------- abs(X(j,i)) The array is indexed by the right-hand side i (on which the componentwise relative error depends), and the type of error information as described below. There currently are up to three pieces of information returned for each right-hand side. If componentwise accuracy is not requested (PARAMS(3) = 0.0), then ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most the first (:,N_ERR_BNDS) entries are returned. The first index in ERR_BNDS_COMP(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_COMP(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * dlamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * dlamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated componentwise reciprocal condition number. Compared with the threshold sqrt(n) * dlamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*(A*diag(x)), where x is the solution for the current right-hand side and S scales each row of A*diag(x) by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [in] NPARAMS ``` NPARAMS is INTEGER Specifies the number of parameters set in PARAMS. If .LE. 0, the PARAMS array is never referenced and default values are used.``` [in,out] PARAMS ``` PARAMS is DOUBLE PRECISION array, dimension (NPARAMS) Specifies algorithm parameters. If an entry is .LT. 0.0, then that entry will be filled with default value used for that parameter. Only positions up to NPARAMS are accessed; defaults are used for higher-numbered parameters. PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative refinement or not. Default: 1.0D+0 = 0.0 : No refinement is performed, and no error bounds are computed. = 1.0 : Use the double-precision refinement algorithm, possibly with doubled-single computations if the compilation environment does not support DOUBLE PRECISION. (other values are reserved for future use) PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual computations allowed for refinement. Default: 10 Aggressive: Set to 100 to permit convergence using approximate factorizations or factorizations other than LU. If the factorization uses a technique other than Gaussian elimination, the guarantees in err_bnds_norm and err_bnds_comp may no longer be trustworthy. PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code will attempt to find a solution with small componentwise relative error in the double-precision algorithm. Positive is true, 0.0 is false. Default: 1.0 (attempt componentwise convergence)``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (4*N)` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: Successful exit. The solution to every right-hand side is guaranteed. < 0: If INFO = -i, the i-th argument had an illegal value > 0 and <= N: U(INFO,INFO) is exactly zero. The factorization has been completed, but the factor U is exactly singular, so the solution and error bounds could not be computed. RCOND = 0 is returned. = N+J: The solution corresponding to the Jth right-hand side is not guaranteed. The solutions corresponding to other right- hand sides K with K > J may not be guaranteed as well, but only the first such right-hand side is reported. If a small componentwise error is not requested (PARAMS(3) = 0.0) then the Jth right-hand side is the first with a normwise error bound that is not guaranteed (the smallest J such that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0) the Jth right-hand side is the first with either a normwise or componentwise error bound that is not guaranteed (the smallest J such that either ERR_BNDS_NORM(J,1) = 0.0 or ERR_BNDS_COMP(J,1) = 0.0). See the definition of ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information about all of the right-hand sides check ERR_BNDS_NORM or ERR_BNDS_COMP.```
Date
November 2011

Definition at line 416 of file dgerfsx.f.

416 *
417 * -- LAPACK computational routine (version 3.4.0) --
418 * -- LAPACK is a software package provided by Univ. of Tennessee, --
419 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
420 * November 2011
421 *
422 * .. Scalar Arguments ..
423  CHARACTER trans, equed
424  INTEGER info, lda, ldaf, ldb, ldx, n, nrhs, nparams,
425  \$ n_err_bnds
426  DOUBLE PRECISION rcond
427 * ..
428 * .. Array Arguments ..
429  INTEGER ipiv( * ), iwork( * )
430  DOUBLE PRECISION a( lda, * ), af( ldaf, * ), b( ldb, * ),
431  \$ x( ldx , * ), work( * )
432  DOUBLE PRECISION r( * ), c( * ), params( * ), berr( * ),
433  \$ err_bnds_norm( nrhs, * ),
434  \$ err_bnds_comp( nrhs, * )
435 * ..
436 *
437 * ==================================================================
438 *
439 * .. Parameters ..
440  DOUBLE PRECISION zero, one
441  parameter ( zero = 0.0d+0, one = 1.0d+0 )
442  DOUBLE PRECISION itref_default, ithresh_default
443  DOUBLE PRECISION componentwise_default, rthresh_default
444  DOUBLE PRECISION dzthresh_default
445  parameter ( itref_default = 1.0d+0 )
446  parameter ( ithresh_default = 10.0d+0 )
447  parameter ( componentwise_default = 1.0d+0 )
448  parameter ( rthresh_default = 0.5d+0 )
449  parameter ( dzthresh_default = 0.25d+0 )
450  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
451  \$ la_linrx_cwise_i
452  parameter ( la_linrx_itref_i = 1,
453  \$ la_linrx_ithresh_i = 2 )
454  parameter ( la_linrx_cwise_i = 3 )
455  INTEGER la_linrx_trust_i, la_linrx_err_i,
456  \$ la_linrx_rcond_i
457  parameter ( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
458  parameter ( la_linrx_rcond_i = 3 )
459 * ..
460 * .. Local Scalars ..
461  CHARACTER(1) norm
462  LOGICAL rowequ, colequ, notran
463  INTEGER j, trans_type, prec_type, ref_type
464  INTEGER n_norms
465  DOUBLE PRECISION anorm, rcond_tmp
466  DOUBLE PRECISION illrcond_thresh, err_lbnd, cwise_wrong
467  LOGICAL ignore_cwise
468  INTEGER ithresh
469  DOUBLE PRECISION rthresh, unstable_thresh
470 * ..
471 * .. External Subroutines ..
473 * ..
474 * .. Intrinsic Functions ..
475  INTRINSIC max, sqrt
476 * ..
477 * .. External Functions ..
478  EXTERNAL lsame, blas_fpinfo_x, ilatrans, ilaprec
479  EXTERNAL dlamch, dlange, dla_gercond
480  DOUBLE PRECISION dlamch, dlange, dla_gercond
481  LOGICAL lsame
482  INTEGER blas_fpinfo_x
483  INTEGER ilatrans, ilaprec
484 * ..
485 * .. Executable Statements ..
486 *
487 * Check the input parameters.
488 *
489  info = 0
490  trans_type = ilatrans( trans )
491  ref_type = int( itref_default )
492  IF ( nparams .GE. la_linrx_itref_i ) THEN
493  IF ( params( la_linrx_itref_i ) .LT. 0.0d+0 ) THEN
494  params( la_linrx_itref_i ) = itref_default
495  ELSE
496  ref_type = params( la_linrx_itref_i )
497  END IF
498  END IF
499 *
500 * Set default parameters.
501 *
502  illrcond_thresh = dble( n ) * dlamch( 'Epsilon' )
503  ithresh = int( ithresh_default )
504  rthresh = rthresh_default
505  unstable_thresh = dzthresh_default
506  ignore_cwise = componentwise_default .EQ. 0.0d+0
507 *
508  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
509  IF ( params( la_linrx_ithresh_i ).LT.0.0d+0 ) THEN
510  params( la_linrx_ithresh_i ) = ithresh
511  ELSE
512  ithresh = int( params( la_linrx_ithresh_i ) )
513  END IF
514  END IF
515  IF ( nparams.GE.la_linrx_cwise_i ) THEN
516  IF ( params( la_linrx_cwise_i ).LT.0.0d+0 ) THEN
517  IF ( ignore_cwise ) THEN
518  params( la_linrx_cwise_i ) = 0.0d+0
519  ELSE
520  params( la_linrx_cwise_i ) = 1.0d+0
521  END IF
522  ELSE
523  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0d+0
524  END IF
525  END IF
526  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
527  n_norms = 0
528  ELSE IF ( ignore_cwise ) THEN
529  n_norms = 1
530  ELSE
531  n_norms = 2
532  END IF
533 *
534  notran = lsame( trans, 'N' )
535  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
536  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
537 *
538 * Test input parameters.
539 *
540  IF( trans_type.EQ.-1 ) THEN
541  info = -1
542  ELSE IF( .NOT.rowequ .AND. .NOT.colequ .AND.
543  \$ .NOT.lsame( equed, 'N' ) ) THEN
544  info = -2
545  ELSE IF( n.LT.0 ) THEN
546  info = -3
547  ELSE IF( nrhs.LT.0 ) THEN
548  info = -4
549  ELSE IF( lda.LT.max( 1, n ) ) THEN
550  info = -6
551  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
552  info = -8
553  ELSE IF( ldb.LT.max( 1, n ) ) THEN
554  info = -13
555  ELSE IF( ldx.LT.max( 1, n ) ) THEN
556  info = -15
557  END IF
558  IF( info.NE.0 ) THEN
559  CALL xerbla( 'DGERFSX', -info )
560  RETURN
561  END IF
562 *
563 * Quick return if possible.
564 *
565  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
566  rcond = 1.0d+0
567  DO j = 1, nrhs
568  berr( j ) = 0.0d+0
569  IF ( n_err_bnds .GE. 1 ) THEN
570  err_bnds_norm( j, la_linrx_trust_i) = 1.0d+0
571  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
572  END IF
573  IF ( n_err_bnds .GE. 2 ) THEN
574  err_bnds_norm( j, la_linrx_err_i) = 0.0d+0
575  err_bnds_comp( j, la_linrx_err_i ) = 0.0d+0
576  END IF
577  IF ( n_err_bnds .GE. 3 ) THEN
578  err_bnds_norm( j, la_linrx_rcond_i) = 1.0d+0
579  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0d+0
580  END IF
581  END DO
582  RETURN
583  END IF
584 *
585 * Default to failure.
586 *
587  rcond = 0.0d+0
588  DO j = 1, nrhs
589  berr( j ) = 1.0d+0
590  IF ( n_err_bnds .GE. 1 ) THEN
591  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
592  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
593  END IF
594  IF ( n_err_bnds .GE. 2 ) THEN
595  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
596  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
597  END IF
598  IF ( n_err_bnds .GE. 3 ) THEN
599  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0d+0
600  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0d+0
601  END IF
602  END DO
603 *
604 * Compute the norm of A and the reciprocal of the condition
605 * number of A.
606 *
607  IF( notran ) THEN
608  norm = 'I'
609  ELSE
610  norm = '1'
611  END IF
612  anorm = dlange( norm, n, n, a, lda, work )
613  CALL dgecon( norm, n, af, ldaf, anorm, rcond, work, iwork, info )
614 *
615 * Perform refinement on each right-hand side
616 *
617  IF ( ref_type .NE. 0 ) THEN
618
619  prec_type = ilaprec( 'E' )
620
621  IF ( notran ) THEN
622  CALL dla_gerfsx_extended( prec_type, trans_type, n,
623  \$ nrhs, a, lda, af, ldaf, ipiv, colequ, c, b,
624  \$ ldb, x, ldx, berr, n_norms, err_bnds_norm,
625  \$ err_bnds_comp, work(n+1), work(1), work(2*n+1),
626  \$ work(1), rcond, ithresh, rthresh, unstable_thresh,
627  \$ ignore_cwise, info )
628  ELSE
629  CALL dla_gerfsx_extended( prec_type, trans_type, n,
630  \$ nrhs, a, lda, af, ldaf, ipiv, rowequ, r, b,
631  \$ ldb, x, ldx, berr, n_norms, err_bnds_norm,
632  \$ err_bnds_comp, work(n+1), work(1), work(2*n+1),
633  \$ work(1), rcond, ithresh, rthresh, unstable_thresh,
634  \$ ignore_cwise, info )
635  END IF
636  END IF
637
638  err_lbnd = max( 10.0d+0, sqrt( dble( n ) ) ) * dlamch( 'Epsilon' )
639  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 1 ) THEN
640 *
641 * Compute scaled normwise condition number cond(A*C).
642 *
643  IF ( colequ .AND. notran ) THEN
644  rcond_tmp = dla_gercond( trans, n, a, lda, af, ldaf, ipiv,
645  \$ -1, c, info, work, iwork )
646  ELSE IF ( rowequ .AND. .NOT. notran ) THEN
647  rcond_tmp = dla_gercond( trans, n, a, lda, af, ldaf, ipiv,
648  \$ -1, r, info, work, iwork )
649  ELSE
650  rcond_tmp = dla_gercond( trans, n, a, lda, af, ldaf, ipiv,
651  \$ 0, r, info, work, iwork )
652  END IF
653  DO j = 1, nrhs
654 *
655 * Cap the error at 1.0.
656 *
657  IF ( n_err_bnds .GE. la_linrx_err_i
658  \$ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0d+0 )
659  \$ err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
660 *
661 * Threshold the error (see LAWN).
662 *
663  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
664  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
665  err_bnds_norm( j, la_linrx_trust_i ) = 0.0d+0
666  IF ( info .LE. n ) info = n + j
667  ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
668  \$ THEN
669  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
670  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
671  END IF
672 *
673 * Save the condition number.
674 *
675  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
676  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
677  END IF
678  END DO
679  END IF
680
681  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 2 ) THEN
682 *
683 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
684 * each right-hand side using the current solution as an estimate of
685 * the true solution. If the componentwise error estimate is too
686 * large, then the solution is a lousy estimate of truth and the
687 * estimated RCOND may be too optimistic. To avoid misleading users,
688 * the inverse condition number is set to 0.0 when the estimated
689 * cwise error is at least CWISE_WRONG.
690 *
691  cwise_wrong = sqrt( dlamch( 'Epsilon' ) )
692  DO j = 1, nrhs
693  IF ( err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
694  \$ THEN
695  rcond_tmp = dla_gercond( trans, n, a, lda, af, ldaf,
696  \$ ipiv, 1, x(1,j), info, work, iwork )
697  ELSE
698  rcond_tmp = 0.0d+0
699  END IF
700 *
701 * Cap the error at 1.0.
702 *
703  IF ( n_err_bnds .GE. la_linrx_err_i
704  \$ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0d+0 )
705  \$ err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
706 *
707 * Threshold the error (see LAWN).
708 *
709  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
710  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
711  err_bnds_comp( j, la_linrx_trust_i ) = 0.0d+0
712  IF ( params( la_linrx_cwise_i ) .EQ. 1.0d+0
713  \$ .AND. info.LT.n + j ) info = n + j
714  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
715  \$ .LT. err_lbnd ) THEN
716  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
717  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
718  END IF
719 *
720 * Save the condition number.
721 *
722  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
723  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
724  END IF
725  END DO
726  END IF
727 *
728  RETURN
729 *
730 * End of DGERFSX
731 *
integer function ilatrans(TRANS)
ILATRANS
Definition: ilatrans.f:60
double precision function dla_gercond(TRANS, N, A, LDA, AF, LDAF, IPIV, CMODE, C, INFO, WORK, IWORK)
DLA_GERCOND estimates the Skeel condition number for a general matrix.
Definition: dla_gercond.f:154
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine dla_gerfsx_extended(PREC_TYPE, TRANS_TYPE, N, NRHS, A, LDA, AF, LDAF, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERRS_N, ERRS_C, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
DLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matric...
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:116
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:60
subroutine dgecon(NORM, N, A, LDA, ANORM, RCOND, WORK, IWORK, INFO)
DGECON
Definition: dgecon.f:126
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: