LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
dla_gerfsx_extended.f
Go to the documentation of this file.
1 *> \brief \b DLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DLA_GERFSX_EXTENDED + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DLA_GERFSX_EXTENDED( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
22 * LDA, AF, LDAF, IPIV, COLEQU, C, B,
23 * LDB, Y, LDY, BERR_OUT, N_NORMS,
24 * ERRS_N, ERRS_C, RES, AYB, DY,
25 * Y_TAIL, RCOND, ITHRESH, RTHRESH,
26 * DZ_UB, IGNORE_CWISE, INFO )
27 *
28 * .. Scalar Arguments ..
29 * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
30 * $ TRANS_TYPE, N_NORMS, ITHRESH
31 * LOGICAL COLEQU, IGNORE_CWISE
32 * DOUBLE PRECISION RTHRESH, DZ_UB
33 * ..
34 * .. Array Arguments ..
35 * INTEGER IPIV( * )
36 * DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
37 * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
38 * DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
39 * $ ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
40 * ..
41 *
42 *
43 *> \par Purpose:
44 * =============
45 *>
46 *> \verbatim
47 *>
48 *>
49 *> DLA_GERFSX_EXTENDED improves the computed solution to a system of
50 *> linear equations by performing extra-precise iterative refinement
51 *> and provides error bounds and backward error estimates for the solution.
52 *> This subroutine is called by DGERFSX to perform iterative refinement.
53 *> In addition to normwise error bound, the code provides maximum
54 *> componentwise error bound if possible. See comments for ERRS_N
55 *> and ERRS_C for details of the error bounds. Note that this
56 *> subroutine is only resonsible for setting the second fields of
57 *> ERRS_N and ERRS_C.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] PREC_TYPE
64 *> \verbatim
65 *> PREC_TYPE is INTEGER
66 *> Specifies the intermediate precision to be used in refinement.
67 *> The value is defined by ILAPREC(P) where P is a CHARACTER and
68 *> P = 'S': Single
69 *> = 'D': Double
70 *> = 'I': Indigenous
71 *> = 'X', 'E': Extra
72 *> \endverbatim
73 *>
74 *> \param[in] TRANS_TYPE
75 *> \verbatim
76 *> TRANS_TYPE is INTEGER
77 *> Specifies the transposition operation on A.
78 *> The value is defined by ILATRANS(T) where T is a CHARACTER and
79 *> T = 'N': No transpose
80 *> = 'T': Transpose
81 *> = 'C': Conjugate transpose
82 *> \endverbatim
83 *>
84 *> \param[in] N
85 *> \verbatim
86 *> N is INTEGER
87 *> The number of linear equations, i.e., the order of the
88 *> matrix A. N >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in] NRHS
92 *> \verbatim
93 *> NRHS is INTEGER
94 *> The number of right-hand-sides, i.e., the number of columns of the
95 *> matrix B.
96 *> \endverbatim
97 *>
98 *> \param[in] A
99 *> \verbatim
100 *> A is DOUBLE PRECISION array, dimension (LDA,N)
101 *> On entry, the N-by-N matrix A.
102 *> \endverbatim
103 *>
104 *> \param[in] LDA
105 *> \verbatim
106 *> LDA is INTEGER
107 *> The leading dimension of the array A. LDA >= max(1,N).
108 *> \endverbatim
109 *>
110 *> \param[in] AF
111 *> \verbatim
112 *> AF is DOUBLE PRECISION array, dimension (LDAF,N)
113 *> The factors L and U from the factorization
114 *> A = P*L*U as computed by DGETRF.
115 *> \endverbatim
116 *>
117 *> \param[in] LDAF
118 *> \verbatim
119 *> LDAF is INTEGER
120 *> The leading dimension of the array AF. LDAF >= max(1,N).
121 *> \endverbatim
122 *>
123 *> \param[in] IPIV
124 *> \verbatim
125 *> IPIV is INTEGER array, dimension (N)
126 *> The pivot indices from the factorization A = P*L*U
127 *> as computed by DGETRF; row i of the matrix was interchanged
128 *> with row IPIV(i).
129 *> \endverbatim
130 *>
131 *> \param[in] COLEQU
132 *> \verbatim
133 *> COLEQU is LOGICAL
134 *> If .TRUE. then column equilibration was done to A before calling
135 *> this routine. This is needed to compute the solution and error
136 *> bounds correctly.
137 *> \endverbatim
138 *>
139 *> \param[in] C
140 *> \verbatim
141 *> C is DOUBLE PRECISION array, dimension (N)
142 *> The column scale factors for A. If COLEQU = .FALSE., C
143 *> is not accessed. If C is input, each element of C should be a power
144 *> of the radix to ensure a reliable solution and error estimates.
145 *> Scaling by powers of the radix does not cause rounding errors unless
146 *> the result underflows or overflows. Rounding errors during scaling
147 *> lead to refining with a matrix that is not equivalent to the
148 *> input matrix, producing error estimates that may not be
149 *> reliable.
150 *> \endverbatim
151 *>
152 *> \param[in] B
153 *> \verbatim
154 *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
155 *> The right-hand-side matrix B.
156 *> \endverbatim
157 *>
158 *> \param[in] LDB
159 *> \verbatim
160 *> LDB is INTEGER
161 *> The leading dimension of the array B. LDB >= max(1,N).
162 *> \endverbatim
163 *>
164 *> \param[in,out] Y
165 *> \verbatim
166 *> Y is DOUBLE PRECISION array, dimension
167 *> (LDY,NRHS)
168 *> On entry, the solution matrix X, as computed by DGETRS.
169 *> On exit, the improved solution matrix Y.
170 *> \endverbatim
171 *>
172 *> \param[in] LDY
173 *> \verbatim
174 *> LDY is INTEGER
175 *> The leading dimension of the array Y. LDY >= max(1,N).
176 *> \endverbatim
177 *>
178 *> \param[out] BERR_OUT
179 *> \verbatim
180 *> BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
181 *> On exit, BERR_OUT(j) contains the componentwise relative backward
182 *> error for right-hand-side j from the formula
183 *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
184 *> where abs(Z) is the componentwise absolute value of the matrix
185 *> or vector Z. This is computed by DLA_LIN_BERR.
186 *> \endverbatim
187 *>
188 *> \param[in] N_NORMS
189 *> \verbatim
190 *> N_NORMS is INTEGER
191 *> Determines which error bounds to return (see ERRS_N
192 *> and ERRS_C).
193 *> If N_NORMS >= 1 return normwise error bounds.
194 *> If N_NORMS >= 2 return componentwise error bounds.
195 *> \endverbatim
196 *>
197 *> \param[in,out] ERRS_N
198 *> \verbatim
199 *> ERRS_N is DOUBLE PRECISION array, dimension
200 *> (NRHS, N_ERR_BNDS)
201 *> For each right-hand side, this array contains information about
202 *> various error bounds and condition numbers corresponding to the
203 *> normwise relative error, which is defined as follows:
204 *>
205 *> Normwise relative error in the ith solution vector:
206 *> max_j (abs(XTRUE(j,i) - X(j,i)))
207 *> ------------------------------
208 *> max_j abs(X(j,i))
209 *>
210 *> The array is indexed by the type of error information as described
211 *> below. There currently are up to three pieces of information
212 *> returned.
213 *>
214 *> The first index in ERRS_N(i,:) corresponds to the ith
215 *> right-hand side.
216 *>
217 *> The second index in ERRS_N(:,err) contains the following
218 *> three fields:
219 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
220 *> reciprocal condition number is less than the threshold
221 *> sqrt(n) * slamch('Epsilon').
222 *>
223 *> err = 2 "Guaranteed" error bound: The estimated forward error,
224 *> almost certainly within a factor of 10 of the true error
225 *> so long as the next entry is greater than the threshold
226 *> sqrt(n) * slamch('Epsilon'). This error bound should only
227 *> be trusted if the previous boolean is true.
228 *>
229 *> err = 3 Reciprocal condition number: Estimated normwise
230 *> reciprocal condition number. Compared with the threshold
231 *> sqrt(n) * slamch('Epsilon') to determine if the error
232 *> estimate is "guaranteed". These reciprocal condition
233 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
234 *> appropriately scaled matrix Z.
235 *> Let Z = S*A, where S scales each row by a power of the
236 *> radix so all absolute row sums of Z are approximately 1.
237 *>
238 *> This subroutine is only responsible for setting the second field
239 *> above.
240 *> See Lapack Working Note 165 for further details and extra
241 *> cautions.
242 *> \endverbatim
243 *>
244 *> \param[in,out] ERRS_C
245 *> \verbatim
246 *> ERRS_C is DOUBLE PRECISION array, dimension
247 *> (NRHS, N_ERR_BNDS)
248 *> For each right-hand side, this array contains information about
249 *> various error bounds and condition numbers corresponding to the
250 *> componentwise relative error, which is defined as follows:
251 *>
252 *> Componentwise relative error in the ith solution vector:
253 *> abs(XTRUE(j,i) - X(j,i))
254 *> max_j ----------------------
255 *> abs(X(j,i))
256 *>
257 *> The array is indexed by the right-hand side i (on which the
258 *> componentwise relative error depends), and the type of error
259 *> information as described below. There currently are up to three
260 *> pieces of information returned for each right-hand side. If
261 *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
262 *> ERRS_C is not accessed. If N_ERR_BNDS .LT. 3, then at most
263 *> the first (:,N_ERR_BNDS) entries are returned.
264 *>
265 *> The first index in ERRS_C(i,:) corresponds to the ith
266 *> right-hand side.
267 *>
268 *> The second index in ERRS_C(:,err) contains the following
269 *> three fields:
270 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
271 *> reciprocal condition number is less than the threshold
272 *> sqrt(n) * slamch('Epsilon').
273 *>
274 *> err = 2 "Guaranteed" error bound: The estimated forward error,
275 *> almost certainly within a factor of 10 of the true error
276 *> so long as the next entry is greater than the threshold
277 *> sqrt(n) * slamch('Epsilon'). This error bound should only
278 *> be trusted if the previous boolean is true.
279 *>
280 *> err = 3 Reciprocal condition number: Estimated componentwise
281 *> reciprocal condition number. Compared with the threshold
282 *> sqrt(n) * slamch('Epsilon') to determine if the error
283 *> estimate is "guaranteed". These reciprocal condition
284 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
285 *> appropriately scaled matrix Z.
286 *> Let Z = S*(A*diag(x)), where x is the solution for the
287 *> current right-hand side and S scales each row of
288 *> A*diag(x) by a power of the radix so all absolute row
289 *> sums of Z are approximately 1.
290 *>
291 *> This subroutine is only responsible for setting the second field
292 *> above.
293 *> See Lapack Working Note 165 for further details and extra
294 *> cautions.
295 *> \endverbatim
296 *>
297 *> \param[in] RES
298 *> \verbatim
299 *> RES is DOUBLE PRECISION array, dimension (N)
300 *> Workspace to hold the intermediate residual.
301 *> \endverbatim
302 *>
303 *> \param[in] AYB
304 *> \verbatim
305 *> AYB is DOUBLE PRECISION array, dimension (N)
306 *> Workspace. This can be the same workspace passed for Y_TAIL.
307 *> \endverbatim
308 *>
309 *> \param[in] DY
310 *> \verbatim
311 *> DY is DOUBLE PRECISION array, dimension (N)
312 *> Workspace to hold the intermediate solution.
313 *> \endverbatim
314 *>
315 *> \param[in] Y_TAIL
316 *> \verbatim
317 *> Y_TAIL is DOUBLE PRECISION array, dimension (N)
318 *> Workspace to hold the trailing bits of the intermediate solution.
319 *> \endverbatim
320 *>
321 *> \param[in] RCOND
322 *> \verbatim
323 *> RCOND is DOUBLE PRECISION
324 *> Reciprocal scaled condition number. This is an estimate of the
325 *> reciprocal Skeel condition number of the matrix A after
326 *> equilibration (if done). If this is less than the machine
327 *> precision (in particular, if it is zero), the matrix is singular
328 *> to working precision. Note that the error may still be small even
329 *> if this number is very small and the matrix appears ill-
330 *> conditioned.
331 *> \endverbatim
332 *>
333 *> \param[in] ITHRESH
334 *> \verbatim
335 *> ITHRESH is INTEGER
336 *> The maximum number of residual computations allowed for
337 *> refinement. The default is 10. For 'aggressive' set to 100 to
338 *> permit convergence using approximate factorizations or
339 *> factorizations other than LU. If the factorization uses a
340 *> technique other than Gaussian elimination, the guarantees in
341 *> ERRS_N and ERRS_C may no longer be trustworthy.
342 *> \endverbatim
343 *>
344 *> \param[in] RTHRESH
345 *> \verbatim
346 *> RTHRESH is DOUBLE PRECISION
347 *> Determines when to stop refinement if the error estimate stops
348 *> decreasing. Refinement will stop when the next solution no longer
349 *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
350 *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
351 *> default value is 0.5. For 'aggressive' set to 0.9 to permit
352 *> convergence on extremely ill-conditioned matrices. See LAWN 165
353 *> for more details.
354 *> \endverbatim
355 *>
356 *> \param[in] DZ_UB
357 *> \verbatim
358 *> DZ_UB is DOUBLE PRECISION
359 *> Determines when to start considering componentwise convergence.
360 *> Componentwise convergence is only considered after each component
361 *> of the solution Y is stable, which we definte as the relative
362 *> change in each component being less than DZ_UB. The default value
363 *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
364 *> more details.
365 *> \endverbatim
366 *>
367 *> \param[in] IGNORE_CWISE
368 *> \verbatim
369 *> IGNORE_CWISE is LOGICAL
370 *> If .TRUE. then ignore componentwise convergence. Default value
371 *> is .FALSE..
372 *> \endverbatim
373 *>
374 *> \param[out] INFO
375 *> \verbatim
376 *> INFO is INTEGER
377 *> = 0: Successful exit.
378 *> < 0: if INFO = -i, the ith argument to DGETRS had an illegal
379 *> value
380 *> \endverbatim
381 *
382 * Authors:
383 * ========
384 *
385 *> \author Univ. of Tennessee
386 *> \author Univ. of California Berkeley
387 *> \author Univ. of Colorado Denver
388 *> \author NAG Ltd.
389 *
390 *> \date September 2012
391 *
392 *> \ingroup doubleGEcomputational
393 *
394 * =====================================================================
395  SUBROUTINE dla_gerfsx_extended( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
396  $ lda, af, ldaf, ipiv, colequ, c, b,
397  $ ldb, y, ldy, berr_out, n_norms,
398  $ errs_n, errs_c, res, ayb, dy,
399  $ y_tail, rcond, ithresh, rthresh,
400  $ dz_ub, ignore_cwise, info )
401 *
402 * -- LAPACK computational routine (version 3.4.2) --
403 * -- LAPACK is a software package provided by Univ. of Tennessee, --
404 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
405 * September 2012
406 *
407 * .. Scalar Arguments ..
408  INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
409  $ trans_type, n_norms, ithresh
410  LOGICAL COLEQU, IGNORE_CWISE
411  DOUBLE PRECISION RTHRESH, DZ_UB
412 * ..
413 * .. Array Arguments ..
414  INTEGER IPIV( * )
415  DOUBLE PRECISION A( lda, * ), AF( ldaf, * ), B( ldb, * ),
416  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
417  DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
418  $ errs_n( nrhs, * ), errs_c( nrhs, * )
419 * ..
420 *
421 * =====================================================================
422 *
423 * .. Local Scalars ..
424  CHARACTER TRANS
425  INTEGER CNT, I, J, X_STATE, Z_STATE, Y_PREC_STATE
426  DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
427  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
428  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
429  $ eps, hugeval, incr_thresh
430  LOGICAL INCR_PREC
431 * ..
432 * .. Parameters ..
433  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
434  $ noprog_state, base_residual, extra_residual,
435  $ extra_y
436  parameter ( unstable_state = 0, working_state = 1,
437  $ conv_state = 2, noprog_state = 3 )
438  parameter ( base_residual = 0, extra_residual = 1,
439  $ extra_y = 2 )
440  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
441  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
442  INTEGER CMP_ERR_I, PIV_GROWTH_I
443  parameter ( final_nrm_err_i = 1, final_cmp_err_i = 2,
444  $ berr_i = 3 )
445  parameter ( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
446  parameter ( cmp_rcond_i = 7, cmp_err_i = 8,
447  $ piv_growth_i = 9 )
448  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
449  $ la_linrx_cwise_i
450  parameter ( la_linrx_itref_i = 1,
451  $ la_linrx_ithresh_i = 2 )
452  parameter ( la_linrx_cwise_i = 3 )
453  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
454  $ la_linrx_rcond_i
455  parameter ( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
456  parameter ( la_linrx_rcond_i = 3 )
457 * ..
458 * .. External Subroutines ..
459  EXTERNAL daxpy, dcopy, dgetrs, dgemv, blas_dgemv_x,
460  $ blas_dgemv2_x, dla_geamv, dla_wwaddw, dlamch,
462  DOUBLE PRECISION DLAMCH
463  CHARACTER CHLA_TRANSTYPE
464 * ..
465 * .. Intrinsic Functions ..
466  INTRINSIC abs, max, min
467 * ..
468 * .. Executable Statements ..
469 *
470  IF ( info.NE.0 ) RETURN
471  trans = chla_transtype(trans_type)
472  eps = dlamch( 'Epsilon' )
473  hugeval = dlamch( 'Overflow' )
474 * Force HUGEVAL to Inf
475  hugeval = hugeval * hugeval
476 * Using HUGEVAL may lead to spurious underflows.
477  incr_thresh = dble( n ) * eps
478 *
479  DO j = 1, nrhs
480  y_prec_state = extra_residual
481  IF ( y_prec_state .EQ. extra_y ) THEN
482  DO i = 1, n
483  y_tail( i ) = 0.0d+0
484  END DO
485  END IF
486 
487  dxrat = 0.0d+0
488  dxratmax = 0.0d+0
489  dzrat = 0.0d+0
490  dzratmax = 0.0d+0
491  final_dx_x = hugeval
492  final_dz_z = hugeval
493  prevnormdx = hugeval
494  prev_dz_z = hugeval
495  dz_z = hugeval
496  dx_x = hugeval
497 
498  x_state = working_state
499  z_state = unstable_state
500  incr_prec = .false.
501 
502  DO cnt = 1, ithresh
503 *
504 * Compute residual RES = B_s - op(A_s) * Y,
505 * op(A) = A, A**T, or A**H depending on TRANS (and type).
506 *
507  CALL dcopy( n, b( 1, j ), 1, res, 1 )
508  IF ( y_prec_state .EQ. base_residual ) THEN
509  CALL dgemv( trans, n, n, -1.0d+0, a, lda, y( 1, j ), 1,
510  $ 1.0d+0, res, 1 )
511  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
512  CALL blas_dgemv_x( trans_type, n, n, -1.0d+0, a, lda,
513  $ y( 1, j ), 1, 1.0d+0, res, 1, prec_type )
514  ELSE
515  CALL blas_dgemv2_x( trans_type, n, n, -1.0d+0, a, lda,
516  $ y( 1, j ), y_tail, 1, 1.0d+0, res, 1, prec_type )
517  END IF
518 
519 ! XXX: RES is no longer needed.
520  CALL dcopy( n, res, 1, dy, 1 )
521  CALL dgetrs( trans, n, 1, af, ldaf, ipiv, dy, n, info )
522 *
523 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
524 *
525  normx = 0.0d+0
526  normy = 0.0d+0
527  normdx = 0.0d+0
528  dz_z = 0.0d+0
529  ymin = hugeval
530 *
531  DO i = 1, n
532  yk = abs( y( i, j ) )
533  dyk = abs( dy( i ) )
534 
535  IF ( yk .NE. 0.0d+0 ) THEN
536  dz_z = max( dz_z, dyk / yk )
537  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
538  dz_z = hugeval
539  END IF
540 
541  ymin = min( ymin, yk )
542 
543  normy = max( normy, yk )
544 
545  IF ( colequ ) THEN
546  normx = max( normx, yk * c( i ) )
547  normdx = max( normdx, dyk * c( i ) )
548  ELSE
549  normx = normy
550  normdx = max( normdx, dyk )
551  END IF
552  END DO
553 
554  IF ( normx .NE. 0.0d+0 ) THEN
555  dx_x = normdx / normx
556  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
557  dx_x = 0.0d+0
558  ELSE
559  dx_x = hugeval
560  END IF
561 
562  dxrat = normdx / prevnormdx
563  dzrat = dz_z / prev_dz_z
564 *
565 * Check termination criteria
566 *
567  IF (.NOT.ignore_cwise
568  $ .AND. ymin*rcond .LT. incr_thresh*normy
569  $ .AND. y_prec_state .LT. extra_y)
570  $ incr_prec = .true.
571 
572  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
573  $ x_state = working_state
574  IF ( x_state .EQ. working_state ) THEN
575  IF ( dx_x .LE. eps ) THEN
576  x_state = conv_state
577  ELSE IF ( dxrat .GT. rthresh ) THEN
578  IF ( y_prec_state .NE. extra_y ) THEN
579  incr_prec = .true.
580  ELSE
581  x_state = noprog_state
582  END IF
583  ELSE
584  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
585  END IF
586  IF ( x_state .GT. working_state ) final_dx_x = dx_x
587  END IF
588 
589  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
590  $ z_state = working_state
591  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
592  $ z_state = working_state
593  IF ( z_state .EQ. working_state ) THEN
594  IF ( dz_z .LE. eps ) THEN
595  z_state = conv_state
596  ELSE IF ( dz_z .GT. dz_ub ) THEN
597  z_state = unstable_state
598  dzratmax = 0.0d+0
599  final_dz_z = hugeval
600  ELSE IF ( dzrat .GT. rthresh ) THEN
601  IF ( y_prec_state .NE. extra_y ) THEN
602  incr_prec = .true.
603  ELSE
604  z_state = noprog_state
605  END IF
606  ELSE
607  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
608  END IF
609  IF ( z_state .GT. working_state ) final_dz_z = dz_z
610  END IF
611 *
612 * Exit if both normwise and componentwise stopped working,
613 * but if componentwise is unstable, let it go at least two
614 * iterations.
615 *
616  IF ( x_state.NE.working_state ) THEN
617  IF ( ignore_cwise) GOTO 666
618  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
619  $ GOTO 666
620  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
621  END IF
622 
623  IF ( incr_prec ) THEN
624  incr_prec = .false.
625  y_prec_state = y_prec_state + 1
626  DO i = 1, n
627  y_tail( i ) = 0.0d+0
628  END DO
629  END IF
630 
631  prevnormdx = normdx
632  prev_dz_z = dz_z
633 *
634 * Update soluton.
635 *
636  IF ( y_prec_state .LT. extra_y ) THEN
637  CALL daxpy( n, 1.0d+0, dy, 1, y( 1, j ), 1 )
638  ELSE
639  CALL dla_wwaddw( n, y( 1, j ), y_tail, dy )
640  END IF
641 
642  END DO
643 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
644  666 CONTINUE
645 *
646 * Set final_* when cnt hits ithresh.
647 *
648  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
649  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
650 *
651 * Compute error bounds
652 *
653  IF (n_norms .GE. 1) THEN
654  errs_n( j, la_linrx_err_i ) = final_dx_x / (1 - dxratmax)
655  END IF
656  IF ( n_norms .GE. 2 ) THEN
657  errs_c( j, la_linrx_err_i ) = final_dz_z / (1 - dzratmax)
658  END IF
659 *
660 * Compute componentwise relative backward error from formula
661 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
662 * where abs(Z) is the componentwise absolute value of the matrix
663 * or vector Z.
664 *
665 * Compute residual RES = B_s - op(A_s) * Y,
666 * op(A) = A, A**T, or A**H depending on TRANS (and type).
667 *
668  CALL dcopy( n, b( 1, j ), 1, res, 1 )
669  CALL dgemv( trans, n, n, -1.0d+0, a, lda, y(1,j), 1, 1.0d+0,
670  $ res, 1 )
671 
672  DO i = 1, n
673  ayb( i ) = abs( b( i, j ) )
674  END DO
675 *
676 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
677 *
678  CALL dla_geamv ( trans_type, n, n, 1.0d+0,
679  $ a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )
680 
681  CALL dla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
682 *
683 * End of loop for each RHS.
684 *
685  END DO
686 *
687  RETURN
688  END
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:53
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine dla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
DLA_LIN_BERR computes a component-wise relative backward error.
Definition: dla_lin_berr.f:103
subroutine dgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGEMV
Definition: dgemv.f:158
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:54
subroutine dgetrs(TRANS, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
DGETRS
Definition: dgetrs.f:123
subroutine dla_gerfsx_extended(PREC_TYPE, TRANS_TYPE, N, NRHS, A, LDA, AF, LDAF, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERRS_N, ERRS_C, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
DLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matric...
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
subroutine dla_wwaddw(N, X, Y, W)
DLA_WWADDW adds a vector into a doubled-single vector.
Definition: dla_wwaddw.f:83
subroutine dla_geamv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DLA_GEAMV computes a matrix-vector product using a general matrix to calculate error bounds...
Definition: dla_geamv.f:176