LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cgebd2.f
Go to the documentation of this file.
1 *> \brief \b CGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgebd2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgebd2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgebd2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, LDA, M, N
25 * ..
26 * .. Array Arguments ..
27 * REAL D( * ), E( * )
28 * COMPLEX A( LDA, * ), TAUP( * ), TAUQ( * ), WORK( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> CGEBD2 reduces a complex general m by n matrix A to upper or lower
38 *> real bidiagonal form B by a unitary transformation: Q**H * A * P = B.
39 *>
40 *> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
41 *> \endverbatim
42 *
43 * Arguments:
44 * ==========
45 *
46 *> \param[in] M
47 *> \verbatim
48 *> M is INTEGER
49 *> The number of rows in the matrix A. M >= 0.
50 *> \endverbatim
51 *>
52 *> \param[in] N
53 *> \verbatim
54 *> N is INTEGER
55 *> The number of columns in the matrix A. N >= 0.
56 *> \endverbatim
57 *>
58 *> \param[in,out] A
59 *> \verbatim
60 *> A is COMPLEX array, dimension (LDA,N)
61 *> On entry, the m by n general matrix to be reduced.
62 *> On exit,
63 *> if m >= n, the diagonal and the first superdiagonal are
64 *> overwritten with the upper bidiagonal matrix B; the
65 *> elements below the diagonal, with the array TAUQ, represent
66 *> the unitary matrix Q as a product of elementary
67 *> reflectors, and the elements above the first superdiagonal,
68 *> with the array TAUP, represent the unitary matrix P as
69 *> a product of elementary reflectors;
70 *> if m < n, the diagonal and the first subdiagonal are
71 *> overwritten with the lower bidiagonal matrix B; the
72 *> elements below the first subdiagonal, with the array TAUQ,
73 *> represent the unitary matrix Q as a product of
74 *> elementary reflectors, and the elements above the diagonal,
75 *> with the array TAUP, represent the unitary matrix P as
76 *> a product of elementary reflectors.
77 *> See Further Details.
78 *> \endverbatim
79 *>
80 *> \param[in] LDA
81 *> \verbatim
82 *> LDA is INTEGER
83 *> The leading dimension of the array A. LDA >= max(1,M).
84 *> \endverbatim
85 *>
86 *> \param[out] D
87 *> \verbatim
88 *> D is REAL array, dimension (min(M,N))
89 *> The diagonal elements of the bidiagonal matrix B:
90 *> D(i) = A(i,i).
91 *> \endverbatim
92 *>
93 *> \param[out] E
94 *> \verbatim
95 *> E is REAL array, dimension (min(M,N)-1)
96 *> The off-diagonal elements of the bidiagonal matrix B:
97 *> if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
98 *> if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
99 *> \endverbatim
100 *>
101 *> \param[out] TAUQ
102 *> \verbatim
103 *> TAUQ is COMPLEX array dimension (min(M,N))
104 *> The scalar factors of the elementary reflectors which
105 *> represent the unitary matrix Q. See Further Details.
106 *> \endverbatim
107 *>
108 *> \param[out] TAUP
109 *> \verbatim
110 *> TAUP is COMPLEX array, dimension (min(M,N))
111 *> The scalar factors of the elementary reflectors which
112 *> represent the unitary matrix P. See Further Details.
113 *> \endverbatim
114 *>
115 *> \param[out] WORK
116 *> \verbatim
117 *> WORK is COMPLEX array, dimension (max(M,N))
118 *> \endverbatim
119 *>
120 *> \param[out] INFO
121 *> \verbatim
122 *> INFO is INTEGER
123 *> = 0: successful exit
124 *> < 0: if INFO = -i, the i-th argument had an illegal value.
125 *> \endverbatim
126 *
127 * Authors:
128 * ========
129 *
130 *> \author Univ. of Tennessee
131 *> \author Univ. of California Berkeley
132 *> \author Univ. of Colorado Denver
133 *> \author NAG Ltd.
134 *
135 *> \date September 2012
136 *
137 *> \ingroup complexGEcomputational
138 * @precisions normal c -> s d z
139 *
140 *> \par Further Details:
141 * =====================
142 *>
143 *> \verbatim
144 *>
145 *> The matrices Q and P are represented as products of elementary
146 *> reflectors:
147 *>
148 *> If m >= n,
149 *>
150 *> Q = H(1) H(2) . . . H(n) and P = G(1) G(2) . . . G(n-1)
151 *>
152 *> Each H(i) and G(i) has the form:
153 *>
154 *> H(i) = I - tauq * v * v**H and G(i) = I - taup * u * u**H
155 *>
156 *> where tauq and taup are complex scalars, and v and u are complex
157 *> vectors; v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
158 *> A(i+1:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
159 *> A(i,i+2:n); tauq is stored in TAUQ(i) and taup in TAUP(i).
160 *>
161 *> If m < n,
162 *>
163 *> Q = H(1) H(2) . . . H(m-1) and P = G(1) G(2) . . . G(m)
164 *>
165 *> Each H(i) and G(i) has the form:
166 *>
167 *> H(i) = I - tauq * v * v**H and G(i) = I - taup * u * u**H
168 *>
169 *> where tauq and taup are complex scalars, v and u are complex vectors;
170 *> v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
171 *> u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
172 *> tauq is stored in TAUQ(i) and taup in TAUP(i).
173 *>
174 *> The contents of A on exit are illustrated by the following examples:
175 *>
176 *> m = 6 and n = 5 (m > n): m = 5 and n = 6 (m < n):
177 *>
178 *> ( d e u1 u1 u1 ) ( d u1 u1 u1 u1 u1 )
179 *> ( v1 d e u2 u2 ) ( e d u2 u2 u2 u2 )
180 *> ( v1 v2 d e u3 ) ( v1 e d u3 u3 u3 )
181 *> ( v1 v2 v3 d e ) ( v1 v2 e d u4 u4 )
182 *> ( v1 v2 v3 v4 d ) ( v1 v2 v3 e d u5 )
183 *> ( v1 v2 v3 v4 v5 )
184 *>
185 *> where d and e denote diagonal and off-diagonal elements of B, vi
186 *> denotes an element of the vector defining H(i), and ui an element of
187 *> the vector defining G(i).
188 *> \endverbatim
189 *>
190 * =====================================================================
191  SUBROUTINE cgebd2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
192 *
193 * -- LAPACK computational routine (version 3.4.2) --
194 * -- LAPACK is a software package provided by Univ. of Tennessee, --
195 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
196 * September 2012
197 *
198 * .. Scalar Arguments ..
199  INTEGER INFO, LDA, M, N
200 * ..
201 * .. Array Arguments ..
202  REAL D( * ), E( * )
203  COMPLEX A( lda, * ), TAUP( * ), TAUQ( * ), WORK( * )
204 * ..
205 *
206 * =====================================================================
207 *
208 * .. Parameters ..
209  COMPLEX ZERO, ONE
210  parameter ( zero = ( 0.0e+0, 0.0e+0 ),
211  \$ one = ( 1.0e+0, 0.0e+0 ) )
212 * ..
213 * .. Local Scalars ..
214  INTEGER I
215  COMPLEX ALPHA
216 * ..
217 * .. External Subroutines ..
218  EXTERNAL clacgv, clarf, clarfg, xerbla
219 * ..
220 * .. Intrinsic Functions ..
221  INTRINSIC conjg, max, min
222 * ..
223 * .. Executable Statements ..
224 *
225 * Test the input parameters
226 *
227  info = 0
228  IF( m.LT.0 ) THEN
229  info = -1
230  ELSE IF( n.LT.0 ) THEN
231  info = -2
232  ELSE IF( lda.LT.max( 1, m ) ) THEN
233  info = -4
234  END IF
235  IF( info.LT.0 ) THEN
236  CALL xerbla( 'CGEBD2', -info )
237  RETURN
238  END IF
239 *
240  IF( m.GE.n ) THEN
241 *
242 * Reduce to upper bidiagonal form
243 *
244  DO 10 i = 1, n
245 *
246 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
247 *
248  alpha = a( i, i )
249  CALL clarfg( m-i+1, alpha, a( min( i+1, m ), i ), 1,
250  \$ tauq( i ) )
251  d( i ) = alpha
252  a( i, i ) = one
253 *
254 * Apply H(i)**H to A(i:m,i+1:n) from the left
255 *
256  IF( i.LT.n )
257  \$ CALL clarf( 'Left', m-i+1, n-i, a( i, i ), 1,
258  \$ conjg( tauq( i ) ), a( i, i+1 ), lda, work )
259  a( i, i ) = d( i )
260 *
261  IF( i.LT.n ) THEN
262 *
263 * Generate elementary reflector G(i) to annihilate
264 * A(i,i+2:n)
265 *
266  CALL clacgv( n-i, a( i, i+1 ), lda )
267  alpha = a( i, i+1 )
268  CALL clarfg( n-i, alpha, a( i, min( i+2, n ) ),
269  \$ lda, taup( i ) )
270  e( i ) = alpha
271  a( i, i+1 ) = one
272 *
273 * Apply G(i) to A(i+1:m,i+1:n) from the right
274 *
275  CALL clarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
276  \$ taup( i ), a( i+1, i+1 ), lda, work )
277  CALL clacgv( n-i, a( i, i+1 ), lda )
278  a( i, i+1 ) = e( i )
279  ELSE
280  taup( i ) = zero
281  END IF
282  10 CONTINUE
283  ELSE
284 *
285 * Reduce to lower bidiagonal form
286 *
287  DO 20 i = 1, m
288 *
289 * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
290 *
291  CALL clacgv( n-i+1, a( i, i ), lda )
292  alpha = a( i, i )
293  CALL clarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
294  \$ taup( i ) )
295  d( i ) = alpha
296  a( i, i ) = one
297 *
298 * Apply G(i) to A(i+1:m,i:n) from the right
299 *
300  IF( i.LT.m )
301  \$ CALL clarf( 'Right', m-i, n-i+1, a( i, i ), lda,
302  \$ taup( i ), a( i+1, i ), lda, work )
303  CALL clacgv( n-i+1, a( i, i ), lda )
304  a( i, i ) = d( i )
305 *
306  IF( i.LT.m ) THEN
307 *
308 * Generate elementary reflector H(i) to annihilate
309 * A(i+2:m,i)
310 *
311  alpha = a( i+1, i )
312  CALL clarfg( m-i, alpha, a( min( i+2, m ), i ), 1,
313  \$ tauq( i ) )
314  e( i ) = alpha
315  a( i+1, i ) = one
316 *
317 * Apply H(i)**H to A(i+1:m,i+1:n) from the left
318 *
319  CALL clarf( 'Left', m-i, n-i, a( i+1, i ), 1,
320  \$ conjg( tauq( i ) ), a( i+1, i+1 ), lda,
321  \$ work )
322  a( i+1, i ) = e( i )
323  ELSE
324  tauq( i ) = zero
325  END IF
326  20 CONTINUE
327  END IF
328  RETURN
329 *
330 * End of CGEBD2
331 *
332  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:130
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76
subroutine cgebd2(M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO)
CGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
Definition: cgebd2.f:192
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108