LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cpptrf.f
Go to the documentation of this file.
1 *> \brief \b CPPTRF
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cpptrf.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cpptrf.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cpptrf.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CPPTRF( UPLO, N, AP, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER INFO, N
26 * ..
27 * .. Array Arguments ..
28 * COMPLEX AP( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> CPPTRF computes the Cholesky factorization of a complex Hermitian
38 *> positive definite matrix A stored in packed format.
39 *>
40 *> The factorization has the form
41 *> A = U**H * U, if UPLO = 'U', or
42 *> A = L * L**H, if UPLO = 'L',
43 *> where U is an upper triangular matrix and L is lower triangular.
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] UPLO
50 *> \verbatim
51 *> UPLO is CHARACTER*1
52 *> = 'U': Upper triangle of A is stored;
53 *> = 'L': Lower triangle of A is stored.
54 *> \endverbatim
55 *>
56 *> \param[in] N
57 *> \verbatim
58 *> N is INTEGER
59 *> The order of the matrix A. N >= 0.
60 *> \endverbatim
61 *>
62 *> \param[in,out] AP
63 *> \verbatim
64 *> AP is COMPLEX array, dimension (N*(N+1)/2)
65 *> On entry, the upper or lower triangle of the Hermitian matrix
66 *> A, packed columnwise in a linear array. The j-th column of A
67 *> is stored in the array AP as follows:
68 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
69 *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
70 *> See below for further details.
71 *>
72 *> On exit, if INFO = 0, the triangular factor U or L from the
73 *> Cholesky factorization A = U**H*U or A = L*L**H, in the same
74 *> storage format as A.
75 *> \endverbatim
76 *>
77 *> \param[out] INFO
78 *> \verbatim
79 *> INFO is INTEGER
80 *> = 0: successful exit
81 *> < 0: if INFO = -i, the i-th argument had an illegal value
82 *> > 0: if INFO = i, the leading minor of order i is not
83 *> positive definite, and the factorization could not be
84 *> completed.
85 *> \endverbatim
86 *
87 * Authors:
88 * ========
89 *
90 *> \author Univ. of Tennessee
91 *> \author Univ. of California Berkeley
92 *> \author Univ. of Colorado Denver
93 *> \author NAG Ltd.
94 *
95 *> \date November 2011
96 *
97 *> \ingroup complexOTHERcomputational
98 *
99 *> \par Further Details:
100 * =====================
101 *>
102 *> \verbatim
103 *>
104 *> The packed storage scheme is illustrated by the following example
105 *> when N = 4, UPLO = 'U':
106 *>
107 *> Two-dimensional storage of the Hermitian matrix A:
108 *>
109 *> a11 a12 a13 a14
110 *> a22 a23 a24
111 *> a33 a34 (aij = conjg(aji))
112 *> a44
113 *>
114 *> Packed storage of the upper triangle of A:
115 *>
116 *> AP = [ a11, a12, a22, a13, a23, a33, a14, a24, a34, a44 ]
117 *> \endverbatim
118 *>
119 * =====================================================================
120  SUBROUTINE cpptrf( UPLO, N, AP, INFO )
121 *
122 * -- LAPACK computational routine (version 3.4.0) --
123 * -- LAPACK is a software package provided by Univ. of Tennessee, --
124 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
125 * November 2011
126 *
127 * .. Scalar Arguments ..
128  CHARACTER UPLO
129  INTEGER INFO, N
130 * ..
131 * .. Array Arguments ..
132  COMPLEX AP( * )
133 * ..
134 *
135 * =====================================================================
136 *
137 * .. Parameters ..
138  REAL ZERO, ONE
139  parameter ( zero = 0.0e+0, one = 1.0e+0 )
140 * ..
141 * .. Local Scalars ..
142  LOGICAL UPPER
143  INTEGER J, JC, JJ
144  REAL AJJ
145 * ..
146 * .. External Functions ..
147  LOGICAL LSAME
148  COMPLEX CDOTC
149  EXTERNAL lsame, cdotc
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL chpr, csscal, ctpsv, xerbla
153 * ..
154 * .. Intrinsic Functions ..
155  INTRINSIC REAL, SQRT
156 * ..
157 * .. Executable Statements ..
158 *
159 * Test the input parameters.
160 *
161  info = 0
162  upper = lsame( uplo, 'U' )
163  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
164  info = -1
165  ELSE IF( n.LT.0 ) THEN
166  info = -2
167  END IF
168  IF( info.NE.0 ) THEN
169  CALL xerbla( 'CPPTRF', -info )
170  RETURN
171  END IF
172 *
173 * Quick return if possible
174 *
175  IF( n.EQ.0 )
176  \$ RETURN
177 *
178  IF( upper ) THEN
179 *
180 * Compute the Cholesky factorization A = U**H * U.
181 *
182  jj = 0
183  DO 10 j = 1, n
184  jc = jj + 1
185  jj = jj + j
186 *
187 * Compute elements 1:J-1 of column J.
188 *
189  IF( j.GT.1 )
190  \$ CALL ctpsv( 'Upper', 'Conjugate transpose', 'Non-unit',
191  \$ j-1, ap, ap( jc ), 1 )
192 *
193 * Compute U(J,J) and test for non-positive-definiteness.
194 *
195  ajj = REAL( AP( JJ ) ) - CDOTC( j-1, ap( jc ), 1, ap( jc ),
196  \$ 1 )
197  IF( ajj.LE.zero ) THEN
198  ap( jj ) = ajj
199  GO TO 30
200  END IF
201  ap( jj ) = sqrt( ajj )
202  10 CONTINUE
203  ELSE
204 *
205 * Compute the Cholesky factorization A = L * L**H.
206 *
207  jj = 1
208  DO 20 j = 1, n
209 *
210 * Compute L(J,J) and test for non-positive-definiteness.
211 *
212  ajj = REAL( AP( JJ ) )
213  IF( ajj.LE.zero ) THEN
214  ap( jj ) = ajj
215  GO TO 30
216  END IF
217  ajj = sqrt( ajj )
218  ap( jj ) = ajj
219 *
220 * Compute elements J+1:N of column J and update the trailing
221 * submatrix.
222 *
223  IF( j.LT.n ) THEN
224  CALL csscal( n-j, one / ajj, ap( jj+1 ), 1 )
225  CALL chpr( 'Lower', n-j, -one, ap( jj+1 ), 1,
226  \$ ap( jj+n-j+1 ) )
227  jj = jj + n - j + 1
228  END IF
229  20 CONTINUE
230  END IF
231  GO TO 40
232 *
233  30 CONTINUE
234  info = j
235 *
236  40 CONTINUE
237  RETURN
238 *
239 * End of CPPTRF
240 *
241  END
subroutine cpptrf(UPLO, N, AP, INFO)
CPPTRF
Definition: cpptrf.f:121
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine chpr(UPLO, N, ALPHA, X, INCX, AP)
CHPR
Definition: chpr.f:132
subroutine ctpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
CTPSV
Definition: ctpsv.f:146
subroutine csscal(N, SA, CX, INCX)
CSSCAL
Definition: csscal.f:54