LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
dormqr.f
Go to the documentation of this file.
1 *> \brief \b DORMQR
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DORMQR + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dormqr.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dormqr.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dormqr.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DORMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> DORMQR overwrites the general real M-by-N matrix C with
39 *>
40 *> SIDE = 'L' SIDE = 'R'
41 *> TRANS = 'N': Q * C C * Q
42 *> TRANS = 'T': Q**T * C C * Q**T
43 *>
44 *> where Q is a real orthogonal matrix defined as the product of k
45 *> elementary reflectors
46 *>
47 *> Q = H(1) H(2) . . . H(k)
48 *>
49 *> as returned by DGEQRF. Q is of order M if SIDE = 'L' and of order N
50 *> if SIDE = 'R'.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] SIDE
57 *> \verbatim
58 *> SIDE is CHARACTER*1
59 *> = 'L': apply Q or Q**T from the Left;
60 *> = 'R': apply Q or Q**T from the Right.
61 *> \endverbatim
62 *>
63 *> \param[in] TRANS
64 *> \verbatim
65 *> TRANS is CHARACTER*1
66 *> = 'N': No transpose, apply Q;
67 *> = 'T': Transpose, apply Q**T.
68 *> \endverbatim
69 *>
70 *> \param[in] M
71 *> \verbatim
72 *> M is INTEGER
73 *> The number of rows of the matrix C. M >= 0.
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The number of columns of the matrix C. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in] K
83 *> \verbatim
84 *> K is INTEGER
85 *> The number of elementary reflectors whose product defines
86 *> the matrix Q.
87 *> If SIDE = 'L', M >= K >= 0;
88 *> if SIDE = 'R', N >= K >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in] A
92 *> \verbatim
93 *> A is DOUBLE PRECISION array, dimension (LDA,K)
94 *> The i-th column must contain the vector which defines the
95 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
96 *> DGEQRF in the first k columns of its array argument A.
97 *> \endverbatim
98 *>
99 *> \param[in] LDA
100 *> \verbatim
101 *> LDA is INTEGER
102 *> The leading dimension of the array A.
103 *> If SIDE = 'L', LDA >= max(1,M);
104 *> if SIDE = 'R', LDA >= max(1,N).
105 *> \endverbatim
106 *>
107 *> \param[in] TAU
108 *> \verbatim
109 *> TAU is DOUBLE PRECISION array, dimension (K)
110 *> TAU(i) must contain the scalar factor of the elementary
111 *> reflector H(i), as returned by DGEQRF.
112 *> \endverbatim
113 *>
114 *> \param[in,out] C
115 *> \verbatim
116 *> C is DOUBLE PRECISION array, dimension (LDC,N)
117 *> On entry, the M-by-N matrix C.
118 *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
119 *> \endverbatim
120 *>
121 *> \param[in] LDC
122 *> \verbatim
123 *> LDC is INTEGER
124 *> The leading dimension of the array C. LDC >= max(1,M).
125 *> \endverbatim
126 *>
127 *> \param[out] WORK
128 *> \verbatim
129 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
130 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
131 *> \endverbatim
132 *>
133 *> \param[in] LWORK
134 *> \verbatim
135 *> LWORK is INTEGER
136 *> The dimension of the array WORK.
137 *> If SIDE = 'L', LWORK >= max(1,N);
138 *> if SIDE = 'R', LWORK >= max(1,M).
139 *> For good performance, LWORK should generally be larger.
140 *>
141 *> If LWORK = -1, then a workspace query is assumed; the routine
142 *> only calculates the optimal size of the WORK array, returns
143 *> this value as the first entry of the WORK array, and no error
144 *> message related to LWORK is issued by XERBLA.
145 *> \endverbatim
146 *>
147 *> \param[out] INFO
148 *> \verbatim
149 *> INFO is INTEGER
150 *> = 0: successful exit
151 *> < 0: if INFO = -i, the i-th argument had an illegal value
152 *> \endverbatim
153 *
154 * Authors:
155 * ========
156 *
157 *> \author Univ. of Tennessee
158 *> \author Univ. of California Berkeley
159 *> \author Univ. of Colorado Denver
160 *> \author NAG Ltd.
161 *
162 *> \date November 2015
163 *
164 *> \ingroup doubleOTHERcomputational
165 *
166 * =====================================================================
167  SUBROUTINE dormqr( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
168  $ work, lwork, info )
169 *
170 * -- LAPACK computational routine (version 3.6.0) --
171 * -- LAPACK is a software package provided by Univ. of Tennessee, --
172 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
173 * November 2015
174 *
175 * .. Scalar Arguments ..
176  CHARACTER SIDE, TRANS
177  INTEGER INFO, K, LDA, LDC, LWORK, M, N
178 * ..
179 * .. Array Arguments ..
180  DOUBLE PRECISION A( lda, * ), C( ldc, * ), TAU( * ), WORK( * )
181 * ..
182 *
183 * =====================================================================
184 *
185 * .. Parameters ..
186  INTEGER NBMAX, LDT, TSIZE
187  parameter ( nbmax = 64, ldt = nbmax+1,
188  $ tsize = ldt*nbmax )
189 * ..
190 * .. Local Scalars ..
191  LOGICAL LEFT, LQUERY, NOTRAN
192  INTEGER I, I1, I2, I3, IB, IC, IINFO, IWT, JC, LDWORK,
193  $ lwkopt, mi, nb, nbmin, ni, nq, nw
194 * ..
195 * .. External Functions ..
196  LOGICAL LSAME
197  INTEGER ILAENV
198  EXTERNAL lsame, ilaenv
199 * ..
200 * .. External Subroutines ..
201  EXTERNAL dlarfb, dlarft, dorm2r, xerbla
202 * ..
203 * .. Intrinsic Functions ..
204  INTRINSIC max, min
205 * ..
206 * .. Executable Statements ..
207 *
208 * Test the input arguments
209 *
210  info = 0
211  left = lsame( side, 'L' )
212  notran = lsame( trans, 'N' )
213  lquery = ( lwork.EQ.-1 )
214 *
215 * NQ is the order of Q and NW is the minimum dimension of WORK
216 *
217  IF( left ) THEN
218  nq = m
219  nw = n
220  ELSE
221  nq = n
222  nw = m
223  END IF
224  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
225  info = -1
226  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
227  info = -2
228  ELSE IF( m.LT.0 ) THEN
229  info = -3
230  ELSE IF( n.LT.0 ) THEN
231  info = -4
232  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
233  info = -5
234  ELSE IF( lda.LT.max( 1, nq ) ) THEN
235  info = -7
236  ELSE IF( ldc.LT.max( 1, m ) ) THEN
237  info = -10
238  ELSE IF( lwork.LT.max( 1, nw ) .AND. .NOT.lquery ) THEN
239  info = -12
240  END IF
241 *
242  IF( info.EQ.0 ) THEN
243 *
244 * Compute the workspace requirements
245 *
246  nb = min( nbmax, ilaenv( 1, 'DORMQR', side // trans, m, n, k,
247  $ -1 ) )
248  lwkopt = max( 1, nw )*nb + tsize
249  work( 1 ) = lwkopt
250  END IF
251 *
252  IF( info.NE.0 ) THEN
253  CALL xerbla( 'DORMQR', -info )
254  RETURN
255  ELSE IF( lquery ) THEN
256  RETURN
257  END IF
258 *
259 * Quick return if possible
260 *
261  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
262  work( 1 ) = 1
263  RETURN
264  END IF
265 *
266  nbmin = 2
267  ldwork = nw
268  IF( nb.GT.1 .AND. nb.LT.k ) THEN
269  IF( lwork.LT.nw*nb+tsize ) THEN
270  nb = (lwork-tsize) / ldwork
271  nbmin = max( 2, ilaenv( 2, 'DORMQR', side // trans, m, n, k,
272  $ -1 ) )
273  END IF
274  END IF
275 *
276  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
277 *
278 * Use unblocked code
279 *
280  CALL dorm2r( side, trans, m, n, k, a, lda, tau, c, ldc, work,
281  $ iinfo )
282  ELSE
283 *
284 * Use blocked code
285 *
286  iwt = 1 + nw*nb
287  IF( ( left .AND. .NOT.notran ) .OR.
288  $ ( .NOT.left .AND. notran ) ) THEN
289  i1 = 1
290  i2 = k
291  i3 = nb
292  ELSE
293  i1 = ( ( k-1 ) / nb )*nb + 1
294  i2 = 1
295  i3 = -nb
296  END IF
297 *
298  IF( left ) THEN
299  ni = n
300  jc = 1
301  ELSE
302  mi = m
303  ic = 1
304  END IF
305 *
306  DO 10 i = i1, i2, i3
307  ib = min( nb, k-i+1 )
308 *
309 * Form the triangular factor of the block reflector
310 * H = H(i) H(i+1) . . . H(i+ib-1)
311 *
312  CALL dlarft( 'Forward', 'Columnwise', nq-i+1, ib, a( i, i ),
313  $ lda, tau( i ), work( iwt ), ldt )
314  IF( left ) THEN
315 *
316 * H or H**T is applied to C(i:m,1:n)
317 *
318  mi = m - i + 1
319  ic = i
320  ELSE
321 *
322 * H or H**T is applied to C(1:m,i:n)
323 *
324  ni = n - i + 1
325  jc = i
326  END IF
327 *
328 * Apply H or H**T
329 *
330  CALL dlarfb( side, trans, 'Forward', 'Columnwise', mi, ni,
331  $ ib, a( i, i ), lda, work( iwt ), ldt,
332  $ c( ic, jc ), ldc, work, ldwork )
333  10 CONTINUE
334  END IF
335  work( 1 ) = lwkopt
336  RETURN
337 *
338 * End of DORMQR
339 *
340  END
subroutine dlarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
DLARFB applies a block reflector or its transpose to a general rectangular matrix.
Definition: dlarfb.f:197
subroutine dormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
DORMQR
Definition: dormqr.f:169
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
DLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: dlarft.f:165
subroutine dorm2r(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
DORM2R multiplies a general matrix by the orthogonal matrix from a QR factorization determined by sge...
Definition: dorm2r.f:161