LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cunmrz.f
Go to the documentation of this file.
1 *> \brief \b CUNMRZ
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmrz.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmrz.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmrz.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, L, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CUNMRZ overwrites the general complex M-by-N matrix C with
39 *>
40 *> SIDE = 'L' SIDE = 'R'
41 *> TRANS = 'N': Q * C C * Q
42 *> TRANS = 'C': Q**H * C C * Q**H
43 *>
44 *> where Q is a complex unitary matrix defined as the product of k
45 *> elementary reflectors
46 *>
47 *> Q = H(1) H(2) . . . H(k)
48 *>
49 *> as returned by CTZRZF. Q is of order M if SIDE = 'L' and of order N
50 *> if SIDE = 'R'.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] SIDE
57 *> \verbatim
58 *> SIDE is CHARACTER*1
59 *> = 'L': apply Q or Q**H from the Left;
60 *> = 'R': apply Q or Q**H from the Right.
61 *> \endverbatim
62 *>
63 *> \param[in] TRANS
64 *> \verbatim
65 *> TRANS is CHARACTER*1
66 *> = 'N': No transpose, apply Q;
67 *> = 'C': Conjugate transpose, apply Q**H.
68 *> \endverbatim
69 *>
70 *> \param[in] M
71 *> \verbatim
72 *> M is INTEGER
73 *> The number of rows of the matrix C. M >= 0.
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The number of columns of the matrix C. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in] K
83 *> \verbatim
84 *> K is INTEGER
85 *> The number of elementary reflectors whose product defines
86 *> the matrix Q.
87 *> If SIDE = 'L', M >= K >= 0;
88 *> if SIDE = 'R', N >= K >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in] L
92 *> \verbatim
93 *> L is INTEGER
94 *> The number of columns of the matrix A containing
95 *> the meaningful part of the Householder reflectors.
96 *> If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
97 *> \endverbatim
98 *>
99 *> \param[in] A
100 *> \verbatim
101 *> A is COMPLEX array, dimension
102 *> (LDA,M) if SIDE = 'L',
103 *> (LDA,N) if SIDE = 'R'
104 *> The i-th row must contain the vector which defines the
105 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
106 *> CTZRZF in the last k rows of its array argument A.
107 *> A is modified by the routine but restored on exit.
108 *> \endverbatim
109 *>
110 *> \param[in] LDA
111 *> \verbatim
112 *> LDA is INTEGER
113 *> The leading dimension of the array A. LDA >= max(1,K).
114 *> \endverbatim
115 *>
116 *> \param[in] TAU
117 *> \verbatim
118 *> TAU is COMPLEX array, dimension (K)
119 *> TAU(i) must contain the scalar factor of the elementary
120 *> reflector H(i), as returned by CTZRZF.
121 *> \endverbatim
122 *>
123 *> \param[in,out] C
124 *> \verbatim
125 *> C is COMPLEX array, dimension (LDC,N)
126 *> On entry, the M-by-N matrix C.
127 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
128 *> \endverbatim
129 *>
130 *> \param[in] LDC
131 *> \verbatim
132 *> LDC is INTEGER
133 *> The leading dimension of the array C. LDC >= max(1,M).
134 *> \endverbatim
135 *>
136 *> \param[out] WORK
137 *> \verbatim
138 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
139 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
140 *> \endverbatim
141 *>
142 *> \param[in] LWORK
143 *> \verbatim
144 *> LWORK is INTEGER
145 *> The dimension of the array WORK.
146 *> If SIDE = 'L', LWORK >= max(1,N);
147 *> if SIDE = 'R', LWORK >= max(1,M).
148 *> For good performance, LWORK should generally be larger.
149 *>
150 *> If LWORK = -1, then a workspace query is assumed; the routine
151 *> only calculates the optimal size of the WORK array, returns
152 *> this value as the first entry of the WORK array, and no error
153 *> message related to LWORK is issued by XERBLA.
154 *> \endverbatim
155 *>
156 *> \param[out] INFO
157 *> \verbatim
158 *> INFO is INTEGER
159 *> = 0: successful exit
160 *> < 0: if INFO = -i, the i-th argument had an illegal value
161 *> \endverbatim
162 *
163 * Authors:
164 * ========
165 *
166 *> \author Univ. of Tennessee
167 *> \author Univ. of California Berkeley
168 *> \author Univ. of Colorado Denver
169 *> \author NAG Ltd.
170 *
171 *> \date November 2015
172 *
173 *> \ingroup complexOTHERcomputational
174 *
175 *> \par Contributors:
176 * ==================
177 *>
178 *> A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
179 *
180 *> \par Further Details:
181 * =====================
182 *>
183 *> \verbatim
184 *> \endverbatim
185 *>
186 * =====================================================================
187  SUBROUTINE cunmrz( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
188  \$ work, lwork, info )
189 *
190 * -- LAPACK computational routine (version 3.6.0) --
191 * -- LAPACK is a software package provided by Univ. of Tennessee, --
192 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
193 * November 2015
194 *
195 * .. Scalar Arguments ..
196  CHARACTER SIDE, TRANS
197  INTEGER INFO, K, L, LDA, LDC, LWORK, M, N
198 * ..
199 * .. Array Arguments ..
200  COMPLEX A( lda, * ), C( ldc, * ), TAU( * ), WORK( * )
201 * ..
202 *
203 * =====================================================================
204 *
205 * .. Parameters ..
206  INTEGER NBMAX, LDT, TSIZE
207  parameter ( nbmax = 64, ldt = nbmax+1,
208  \$ tsize = ldt*nbmax )
209 * ..
210 * .. Local Scalars ..
211  LOGICAL LEFT, LQUERY, NOTRAN
212  CHARACTER TRANST
213  INTEGER I, I1, I2, I3, IB, IC, IINFO, IWT, JA, JC,
214  \$ ldwork, lwkopt, mi, nb, nbmin, ni, nq, nw
215 * ..
216 * .. External Functions ..
217  LOGICAL LSAME
218  INTEGER ILAENV
219  EXTERNAL lsame, ilaenv
220 * ..
221 * .. External Subroutines ..
222  EXTERNAL clarzb, clarzt, cunmr3, xerbla
223 * ..
224 * .. Intrinsic Functions ..
225  INTRINSIC max, min
226 * ..
227 * .. Executable Statements ..
228 *
229 * Test the input arguments
230 *
231  info = 0
232  left = lsame( side, 'L' )
233  notran = lsame( trans, 'N' )
234  lquery = ( lwork.EQ.-1 )
235 *
236 * NQ is the order of Q and NW is the minimum dimension of WORK
237 *
238  IF( left ) THEN
239  nq = m
240  nw = max( 1, n )
241  ELSE
242  nq = n
243  nw = max( 1, m )
244  END IF
245  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
246  info = -1
247  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
248  info = -2
249  ELSE IF( m.LT.0 ) THEN
250  info = -3
251  ELSE IF( n.LT.0 ) THEN
252  info = -4
253  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
254  info = -5
255  ELSE IF( l.LT.0 .OR. ( left .AND. ( l.GT.m ) ) .OR.
256  \$ ( .NOT.left .AND. ( l.GT.n ) ) ) THEN
257  info = -6
258  ELSE IF( lda.LT.max( 1, k ) ) THEN
259  info = -8
260  ELSE IF( ldc.LT.max( 1, m ) ) THEN
261  info = -11
262  ELSE IF( lwork.LT.max( 1, nw ) .AND. .NOT.lquery ) THEN
263  info = -13
264  END IF
265 *
266  IF( info.EQ.0 ) THEN
267 *
268 * Compute the workspace requirements
269 *
270  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
271  lwkopt = 1
272  ELSE
273  nb = min( nbmax, ilaenv( 1, 'CUNMRQ', side // trans, m, n,
274  \$ k, -1 ) )
275  lwkopt = nw*nb + tsize
276  END IF
277  work( 1 ) = lwkopt
278  END IF
279 *
280  IF( info.NE.0 ) THEN
281  CALL xerbla( 'CUNMRZ', -info )
282  RETURN
283  ELSE IF( lquery ) THEN
284  RETURN
285  END IF
286 *
287 * Quick return if possible
288 *
289  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
290  RETURN
291  END IF
292 *
293 * Determine the block size.
294 *
295  nb = min( nbmax, ilaenv( 1, 'CUNMRQ', side // trans, m, n, k,
296  \$ -1 ) )
297  nbmin = 2
298  ldwork = nw
299  IF( nb.GT.1 .AND. nb.LT.k ) THEN
300  IF( lwork.LT.nw*nb+tsize ) THEN
301  nb = (lwork-tsize) / ldwork
302  nbmin = max( 2, ilaenv( 2, 'CUNMRQ', side // trans, m, n, k,
303  \$ -1 ) )
304  END IF
305  END IF
306 *
307  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
308 *
309 * Use unblocked code
310 *
311  CALL cunmr3( side, trans, m, n, k, l, a, lda, tau, c, ldc,
312  \$ work, iinfo )
313  ELSE
314 *
315 * Use blocked code
316 *
317  iwt = 1 + nw*nb
318  IF( ( left .AND. .NOT.notran ) .OR.
319  \$ ( .NOT.left .AND. notran ) ) THEN
320  i1 = 1
321  i2 = k
322  i3 = nb
323  ELSE
324  i1 = ( ( k-1 ) / nb )*nb + 1
325  i2 = 1
326  i3 = -nb
327  END IF
328 *
329  IF( left ) THEN
330  ni = n
331  jc = 1
332  ja = m - l + 1
333  ELSE
334  mi = m
335  ic = 1
336  ja = n - l + 1
337  END IF
338 *
339  IF( notran ) THEN
340  transt = 'C'
341  ELSE
342  transt = 'N'
343  END IF
344 *
345  DO 10 i = i1, i2, i3
346  ib = min( nb, k-i+1 )
347 *
348 * Form the triangular factor of the block reflector
349 * H = H(i+ib-1) . . . H(i+1) H(i)
350 *
351  CALL clarzt( 'Backward', 'Rowwise', l, ib, a( i, ja ), lda,
352  \$ tau( i ), work( iwt ), ldt )
353 *
354  IF( left ) THEN
355 *
356 * H or H**H is applied to C(i:m,1:n)
357 *
358  mi = m - i + 1
359  ic = i
360  ELSE
361 *
362 * H or H**H is applied to C(1:m,i:n)
363 *
364  ni = n - i + 1
365  jc = i
366  END IF
367 *
368 * Apply H or H**H
369 *
370  CALL clarzb( side, transt, 'Backward', 'Rowwise', mi, ni,
371  \$ ib, l, a( i, ja ), lda, work( iwt ), ldt,
372  \$ c( ic, jc ), ldc, work, ldwork )
373  10 CONTINUE
374 *
375  END IF
376 *
377  work( 1 ) = lwkopt
378 *
379  RETURN
380 *
381 * End of CUNMRZ
382 *
383  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clarzb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
CLARZB applies a block reflector or its conjugate-transpose to a general matrix.
Definition: clarzb.f:185
subroutine cunmr3(SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC, WORK, INFO)
CUNMR3 multiplies a general matrix by the unitary matrix from a RZ factorization determined by ctzrzf...
Definition: cunmr3.f:180
subroutine clarzt(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
CLARZT forms the triangular factor T of a block reflector H = I - vtvH.
Definition: clarzt.f:187
subroutine cunmrz(SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
CUNMRZ
Definition: cunmrz.f:189