LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
zunbdb2.f
Go to the documentation of this file.
1 *> \brief \b ZUNBDB2
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunbdb2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunbdb2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunbdb2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZUNBDB2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
22 * TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION PHI(*), THETA(*)
29 * COMPLEX*16 TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
30 * \$ X11(LDX11,*), X21(LDX21,*)
31 * ..
32 *
33 *
34 *> \par Purpose:
35 *> =============
36 *>
37 *>\verbatim
38 *>
39 *> ZUNBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
40 *> matrix X with orthonomal columns:
41 *>
42 *> [ B11 ]
43 *> [ X11 ] [ P1 | ] [ 0 ]
44 *> [-----] = [---------] [-----] Q1**T .
45 *> [ X21 ] [ | P2 ] [ B21 ]
46 *> [ 0 ]
47 *>
48 *> X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
49 *> Q, or M-Q. Routines ZUNBDB1, ZUNBDB3, and ZUNBDB4 handle cases in
50 *> which P is not the minimum dimension.
51 *>
52 *> The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
53 *> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
54 *> Householder vectors.
55 *>
56 *> B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
57 *> angles THETA, PHI.
58 *>
59 *>\endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] M
65 *> \verbatim
66 *> M is INTEGER
67 *> The number of rows X11 plus the number of rows in X21.
68 *> \endverbatim
69 *>
70 *> \param[in] P
71 *> \verbatim
72 *> P is INTEGER
73 *> The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
74 *> \endverbatim
75 *>
76 *> \param[in] Q
77 *> \verbatim
78 *> Q is INTEGER
79 *> The number of columns in X11 and X21. 0 <= Q <= M.
80 *> \endverbatim
81 *>
82 *> \param[in,out] X11
83 *> \verbatim
84 *> X11 is COMPLEX*16 array, dimension (LDX11,Q)
85 *> On entry, the top block of the matrix X to be reduced. On
86 *> exit, the columns of tril(X11) specify reflectors for P1 and
87 *> the rows of triu(X11,1) specify reflectors for Q1.
88 *> \endverbatim
89 *>
90 *> \param[in] LDX11
91 *> \verbatim
92 *> LDX11 is INTEGER
93 *> The leading dimension of X11. LDX11 >= P.
94 *> \endverbatim
95 *>
96 *> \param[in,out] X21
97 *> \verbatim
98 *> X21 is COMPLEX*16 array, dimension (LDX21,Q)
99 *> On entry, the bottom block of the matrix X to be reduced. On
100 *> exit, the columns of tril(X21) specify reflectors for P2.
101 *> \endverbatim
102 *>
103 *> \param[in] LDX21
104 *> \verbatim
105 *> LDX21 is INTEGER
106 *> The leading dimension of X21. LDX21 >= M-P.
107 *> \endverbatim
108 *>
109 *> \param[out] THETA
110 *> \verbatim
111 *> THETA is DOUBLE PRECISION array, dimension (Q)
112 *> The entries of the bidiagonal blocks B11, B21 are defined by
113 *> THETA and PHI. See Further Details.
114 *> \endverbatim
115 *>
116 *> \param[out] PHI
117 *> \verbatim
118 *> PHI is DOUBLE PRECISION array, dimension (Q-1)
119 *> The entries of the bidiagonal blocks B11, B21 are defined by
120 *> THETA and PHI. See Further Details.
121 *> \endverbatim
122 *>
123 *> \param[out] TAUP1
124 *> \verbatim
125 *> TAUP1 is COMPLEX*16 array, dimension (P)
126 *> The scalar factors of the elementary reflectors that define
127 *> P1.
128 *> \endverbatim
129 *>
130 *> \param[out] TAUP2
131 *> \verbatim
132 *> TAUP2 is COMPLEX*16 array, dimension (M-P)
133 *> The scalar factors of the elementary reflectors that define
134 *> P2.
135 *> \endverbatim
136 *>
137 *> \param[out] TAUQ1
138 *> \verbatim
139 *> TAUQ1 is COMPLEX*16 array, dimension (Q)
140 *> The scalar factors of the elementary reflectors that define
141 *> Q1.
142 *> \endverbatim
143 *>
144 *> \param[out] WORK
145 *> \verbatim
146 *> WORK is COMPLEX*16 array, dimension (LWORK)
147 *> \endverbatim
148 *>
149 *> \param[in] LWORK
150 *> \verbatim
151 *> LWORK is INTEGER
152 *> The dimension of the array WORK. LWORK >= M-Q.
153 *>
154 *> If LWORK = -1, then a workspace query is assumed; the routine
155 *> only calculates the optimal size of the WORK array, returns
156 *> this value as the first entry of the WORK array, and no error
157 *> message related to LWORK is issued by XERBLA.
158 *> \endverbatim
159 *>
160 *> \param[out] INFO
161 *> \verbatim
162 *> INFO is INTEGER
163 *> = 0: successful exit.
164 *> < 0: if INFO = -i, the i-th argument had an illegal value.
165 *> \endverbatim
166 *
167 * Authors:
168 * ========
169 *
170 *> \author Univ. of Tennessee
171 *> \author Univ. of California Berkeley
172 *> \author Univ. of Colorado Denver
173 *> \author NAG Ltd.
174 *
175 *> \date July 2012
176 *
177 *> \ingroup complex16OTHERcomputational
178 *
179 *> \par Further Details:
180 * =====================
181 *>
182 *> \verbatim
183 *>
184 *> The upper-bidiagonal blocks B11, B21 are represented implicitly by
185 *> angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
186 *> in each bidiagonal band is a product of a sine or cosine of a THETA
187 *> with a sine or cosine of a PHI. See [1] or ZUNCSD for details.
188 *>
189 *> P1, P2, and Q1 are represented as products of elementary reflectors.
190 *> See ZUNCSD2BY1 for details on generating P1, P2, and Q1 using ZUNGQR
191 *> and ZUNGLQ.
192 *> \endverbatim
193 *
194 *> \par References:
195 * ================
196 *>
197 *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
198 *> Algorithms, 50(1):33-65, 2009.
199 *>
200 * =====================================================================
201  SUBROUTINE zunbdb2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
202  \$ taup1, taup2, tauq1, work, lwork, info )
203 *
204 * -- LAPACK computational routine (version 3.6.1) --
205 * -- LAPACK is a software package provided by Univ. of Tennessee, --
206 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
207 * July 2012
208 *
209 * .. Scalar Arguments ..
210  INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
211 * ..
212 * .. Array Arguments ..
213  DOUBLE PRECISION PHI(*), THETA(*)
214  COMPLEX*16 TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
215  \$ x11(ldx11,*), x21(ldx21,*)
216 * ..
217 *
218 * ====================================================================
219 *
220 * .. Parameters ..
221  COMPLEX*16 NEGONE, ONE
222  parameter ( negone = (-1.0d0,0.0d0),
223  \$ one = (1.0d0,0.0d0) )
224 * ..
225 * .. Local Scalars ..
226  DOUBLE PRECISION C, S
227  INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
228  \$ lworkmin, lworkopt
229  LOGICAL LQUERY
230 * ..
231 * .. External Subroutines ..
232  EXTERNAL zlarf, zlarfgp, zunbdb5, zdrot, zscal, xerbla
233 * ..
234 * .. External Functions ..
235  DOUBLE PRECISION DZNRM2
236  EXTERNAL dznrm2
237 * ..
238 * .. Intrinsic Function ..
239  INTRINSIC atan2, cos, max, sin, sqrt
240 * ..
241 * .. Executable Statements ..
242 *
243 * Test input arguments
244 *
245  info = 0
246  lquery = lwork .EQ. -1
247 *
248  IF( m .LT. 0 ) THEN
249  info = -1
250  ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
251  info = -2
252  ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
253  info = -3
254  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
255  info = -5
256  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
257  info = -7
258  END IF
259 *
260 * Compute workspace
261 *
262  IF( info .EQ. 0 ) THEN
263  ilarf = 2
264  llarf = max( p-1, m-p, q-1 )
265  iorbdb5 = 2
266  lorbdb5 = q-1
267  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
268  lworkmin = lworkopt
269  work(1) = lworkopt
270  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
271  info = -14
272  END IF
273  END IF
274  IF( info .NE. 0 ) THEN
275  CALL xerbla( 'ZUNBDB2', -info )
276  RETURN
277  ELSE IF( lquery ) THEN
278  RETURN
279  END IF
280 *
281 * Reduce rows 1, ..., P of X11 and X21
282 *
283  DO i = 1, p
284 *
285  IF( i .GT. 1 ) THEN
286  CALL zdrot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c,
287  \$ s )
288  END IF
289  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
290  CALL zlarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
291  c = dble( x11(i,i) )
292  x11(i,i) = one
293  CALL zlarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
294  \$ x11(i+1,i), ldx11, work(ilarf) )
295  CALL zlarf( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11, tauq1(i),
296  \$ x21(i,i), ldx21, work(ilarf) )
297  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
298  s = sqrt( dznrm2( p-i, x11(i+1,i), 1 )**2
299  \$ + dznrm2( m-p-i+1, x21(i,i), 1 )**2 )
300  theta(i) = atan2( s, c )
301 *
302  CALL zunbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
303  \$ x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
304  \$ work(iorbdb5), lorbdb5, childinfo )
305  CALL zscal( p-i, negone, x11(i+1,i), 1 )
306  CALL zlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
307  IF( i .LT. p ) THEN
308  CALL zlarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
309  phi(i) = atan2( dble( x11(i+1,i) ), dble( x21(i,i) ) )
310  c = cos( phi(i) )
311  s = sin( phi(i) )
312  x11(i+1,i) = one
313  CALL zlarf( 'L', p-i, q-i, x11(i+1,i), 1, dconjg(taup1(i)),
314  \$ x11(i+1,i+1), ldx11, work(ilarf) )
315  END IF
316  x21(i,i) = one
317  CALL zlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, dconjg(taup2(i)),
318  \$ x21(i,i+1), ldx21, work(ilarf) )
319 *
320  END DO
321 *
322 * Reduce the bottom-right portion of X21 to the identity matrix
323 *
324  DO i = p + 1, q
325  CALL zlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
326  x21(i,i) = one
327  CALL zlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, dconjg(taup2(i)),
328  \$ x21(i,i+1), ldx21, work(ilarf) )
329  END DO
330 *
331  RETURN
332 *
333 * End of ZUNBDB2
334 *
335  END
336
subroutine zunbdb2(M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI, TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO)
ZUNBDB2
Definition: zunbdb2.f:203
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zdrot(N, CX, INCX, CY, INCY, C, S)
ZDROT
Definition: zdrot.f:100
subroutine zunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
ZUNBDB5
Definition: zunbdb5.f:158
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:106
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:54
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76