LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
sgglse.f
Go to the documentation of this file.
1 *> \brief <b> SGGLSE solves overdetermined or underdetermined systems for OTHER matrices</b>
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgglse.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgglse.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgglse.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SGGLSE( M, N, P, A, LDA, B, LDB, C, D, X, WORK, LWORK,
22 * INFO )
23 *
24 * .. Scalar Arguments ..
25 * INTEGER INFO, LDA, LDB, LWORK, M, N, P
26 * ..
27 * .. Array Arguments ..
28 * REAL A( LDA, * ), B( LDB, * ), C( * ), D( * ),
29 * \$ WORK( * ), X( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> SGGLSE solves the linear equality-constrained least squares (LSE)
39 *> problem:
40 *>
41 *> minimize || c - A*x ||_2 subject to B*x = d
42 *>
43 *> where A is an M-by-N matrix, B is a P-by-N matrix, c is a given
44 *> M-vector, and d is a given P-vector. It is assumed that
45 *> P <= N <= M+P, and
46 *>
47 *> rank(B) = P and rank( (A) ) = N.
48 *> ( (B) )
49 *>
50 *> These conditions ensure that the LSE problem has a unique solution,
51 *> which is obtained using a generalized RQ factorization of the
52 *> matrices (B, A) given by
53 *>
54 *> B = (0 R)*Q, A = Z*T*Q.
55 *> \endverbatim
56 *
57 * Arguments:
58 * ==========
59 *
60 *> \param[in] M
61 *> \verbatim
62 *> M is INTEGER
63 *> The number of rows of the matrix A. M >= 0.
64 *> \endverbatim
65 *>
66 *> \param[in] N
67 *> \verbatim
68 *> N is INTEGER
69 *> The number of columns of the matrices A and B. N >= 0.
70 *> \endverbatim
71 *>
72 *> \param[in] P
73 *> \verbatim
74 *> P is INTEGER
75 *> The number of rows of the matrix B. 0 <= P <= N <= M+P.
76 *> \endverbatim
77 *>
78 *> \param[in,out] A
79 *> \verbatim
80 *> A is REAL array, dimension (LDA,N)
81 *> On entry, the M-by-N matrix A.
82 *> On exit, the elements on and above the diagonal of the array
83 *> contain the min(M,N)-by-N upper trapezoidal matrix T.
84 *> \endverbatim
85 *>
86 *> \param[in] LDA
87 *> \verbatim
88 *> LDA is INTEGER
89 *> The leading dimension of the array A. LDA >= max(1,M).
90 *> \endverbatim
91 *>
92 *> \param[in,out] B
93 *> \verbatim
94 *> B is REAL array, dimension (LDB,N)
95 *> On entry, the P-by-N matrix B.
96 *> On exit, the upper triangle of the subarray B(1:P,N-P+1:N)
97 *> contains the P-by-P upper triangular matrix R.
98 *> \endverbatim
99 *>
100 *> \param[in] LDB
101 *> \verbatim
102 *> LDB is INTEGER
103 *> The leading dimension of the array B. LDB >= max(1,P).
104 *> \endverbatim
105 *>
106 *> \param[in,out] C
107 *> \verbatim
108 *> C is REAL array, dimension (M)
109 *> On entry, C contains the right hand side vector for the
110 *> least squares part of the LSE problem.
111 *> On exit, the residual sum of squares for the solution
112 *> is given by the sum of squares of elements N-P+1 to M of
113 *> vector C.
114 *> \endverbatim
115 *>
116 *> \param[in,out] D
117 *> \verbatim
118 *> D is REAL array, dimension (P)
119 *> On entry, D contains the right hand side vector for the
120 *> constrained equation.
121 *> On exit, D is destroyed.
122 *> \endverbatim
123 *>
124 *> \param[out] X
125 *> \verbatim
126 *> X is REAL array, dimension (N)
127 *> On exit, X is the solution of the LSE problem.
128 *> \endverbatim
129 *>
130 *> \param[out] WORK
131 *> \verbatim
132 *> WORK is REAL array, dimension (MAX(1,LWORK))
133 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
134 *> \endverbatim
135 *>
136 *> \param[in] LWORK
137 *> \verbatim
138 *> LWORK is INTEGER
139 *> The dimension of the array WORK. LWORK >= max(1,M+N+P).
140 *> For optimum performance LWORK >= P+min(M,N)+max(M,N)*NB,
141 *> where NB is an upper bound for the optimal blocksizes for
142 *> SGEQRF, SGERQF, SORMQR and SORMRQ.
143 *>
144 *> If LWORK = -1, then a workspace query is assumed; the routine
145 *> only calculates the optimal size of the WORK array, returns
146 *> this value as the first entry of the WORK array, and no error
147 *> message related to LWORK is issued by XERBLA.
148 *> \endverbatim
149 *>
150 *> \param[out] INFO
151 *> \verbatim
152 *> INFO is INTEGER
153 *> = 0: successful exit.
154 *> < 0: if INFO = -i, the i-th argument had an illegal value.
155 *> = 1: the upper triangular factor R associated with B in the
156 *> generalized RQ factorization of the pair (B, A) is
157 *> singular, so that rank(B) < P; the least squares
158 *> solution could not be computed.
159 *> = 2: the (N-P) by (N-P) part of the upper trapezoidal factor
160 *> T associated with A in the generalized RQ factorization
161 *> of the pair (B, A) is singular, so that
162 *> rank( (A) ) < N; the least squares solution could not
163 *> ( (B) )
164 *> be computed.
165 *> \endverbatim
166 *
167 * Authors:
168 * ========
169 *
170 *> \author Univ. of Tennessee
171 *> \author Univ. of California Berkeley
172 *> \author Univ. of Colorado Denver
173 *> \author NAG Ltd.
174 *
175 *> \date November 2011
176 *
177 *> \ingroup realOTHERsolve
178 *
179 * =====================================================================
180  SUBROUTINE sgglse( M, N, P, A, LDA, B, LDB, C, D, X, WORK, LWORK,
181  \$ info )
182 *
183 * -- LAPACK driver routine (version 3.4.0) --
184 * -- LAPACK is a software package provided by Univ. of Tennessee, --
185 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
186 * November 2011
187 *
188 * .. Scalar Arguments ..
189  INTEGER INFO, LDA, LDB, LWORK, M, N, P
190 * ..
191 * .. Array Arguments ..
192  REAL A( lda, * ), B( ldb, * ), C( * ), D( * ),
193  \$ work( * ), x( * )
194 * ..
195 *
196 * =====================================================================
197 *
198 * .. Parameters ..
199  REAL ONE
200  parameter ( one = 1.0e+0 )
201 * ..
202 * .. Local Scalars ..
203  LOGICAL LQUERY
204  INTEGER LOPT, LWKMIN, LWKOPT, MN, NB, NB1, NB2, NB3,
205  \$ nb4, nr
206 * ..
207 * .. External Subroutines ..
208  EXTERNAL saxpy, scopy, sgemv, sggrqf, sormqr, sormrq,
209  \$ strmv, strtrs, xerbla
210 * ..
211 * .. External Functions ..
212  INTEGER ILAENV
213  EXTERNAL ilaenv
214 * ..
215 * .. Intrinsic Functions ..
216  INTRINSIC int, max, min
217 * ..
218 * .. Executable Statements ..
219 *
220 * Test the input parameters
221 *
222  info = 0
223  mn = min( m, n )
224  lquery = ( lwork.EQ.-1 )
225  IF( m.LT.0 ) THEN
226  info = -1
227  ELSE IF( n.LT.0 ) THEN
228  info = -2
229  ELSE IF( p.LT.0 .OR. p.GT.n .OR. p.LT.n-m ) THEN
230  info = -3
231  ELSE IF( lda.LT.max( 1, m ) ) THEN
232  info = -5
233  ELSE IF( ldb.LT.max( 1, p ) ) THEN
234  info = -7
235  END IF
236 *
237 * Calculate workspace
238 *
239  IF( info.EQ.0) THEN
240  IF( n.EQ.0 ) THEN
241  lwkmin = 1
242  lwkopt = 1
243  ELSE
244  nb1 = ilaenv( 1, 'SGEQRF', ' ', m, n, -1, -1 )
245  nb2 = ilaenv( 1, 'SGERQF', ' ', m, n, -1, -1 )
246  nb3 = ilaenv( 1, 'SORMQR', ' ', m, n, p, -1 )
247  nb4 = ilaenv( 1, 'SORMRQ', ' ', m, n, p, -1 )
248  nb = max( nb1, nb2, nb3, nb4 )
249  lwkmin = m + n + p
250  lwkopt = p + mn + max( m, n )*nb
251  END IF
252  work( 1 ) = lwkopt
253 *
254  IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
255  info = -12
256  END IF
257  END IF
258 *
259  IF( info.NE.0 ) THEN
260  CALL xerbla( 'SGGLSE', -info )
261  RETURN
262  ELSE IF( lquery ) THEN
263  RETURN
264  END IF
265 *
266 * Quick return if possible
267 *
268  IF( n.EQ.0 )
269  \$ RETURN
270 *
271 * Compute the GRQ factorization of matrices B and A:
272 *
273 * B*Q**T = ( 0 T12 ) P Z**T*A*Q**T = ( R11 R12 ) N-P
274 * N-P P ( 0 R22 ) M+P-N
275 * N-P P
276 *
277 * where T12 and R11 are upper triangular, and Q and Z are
278 * orthogonal.
279 *
280  CALL sggrqf( p, m, n, b, ldb, work, a, lda, work( p+1 ),
281  \$ work( p+mn+1 ), lwork-p-mn, info )
282  lopt = work( p+mn+1 )
283 *
284 * Update c = Z**T *c = ( c1 ) N-P
285 * ( c2 ) M+P-N
286 *
287  CALL sormqr( 'Left', 'Transpose', m, 1, mn, a, lda, work( p+1 ),
288  \$ c, max( 1, m ), work( p+mn+1 ), lwork-p-mn, info )
289  lopt = max( lopt, int( work( p+mn+1 ) ) )
290 *
291 * Solve T12*x2 = d for x2
292 *
293  IF( p.GT.0 ) THEN
294  CALL strtrs( 'Upper', 'No transpose', 'Non-unit', p, 1,
295  \$ b( 1, n-p+1 ), ldb, d, p, info )
296 *
297  IF( info.GT.0 ) THEN
298  info = 1
299  RETURN
300  END IF
301 *
302 * Put the solution in X
303 *
304  CALL scopy( p, d, 1, x( n-p+1 ), 1 )
305 *
306 * Update c1
307 *
308  CALL sgemv( 'No transpose', n-p, p, -one, a( 1, n-p+1 ), lda,
309  \$ d, 1, one, c, 1 )
310  END IF
311 *
312 * Solve R11*x1 = c1 for x1
313 *
314  IF( n.GT.p ) THEN
315  CALL strtrs( 'Upper', 'No transpose', 'Non-unit', n-p, 1,
316  \$ a, lda, c, n-p, info )
317 *
318  IF( info.GT.0 ) THEN
319  info = 2
320  RETURN
321  END IF
322 *
323 * Put the solutions in X
324 *
325  CALL scopy( n-p, c, 1, x, 1 )
326  END IF
327 *
328 * Compute the residual vector:
329 *
330  IF( m.LT.n ) THEN
331  nr = m + p - n
332  IF( nr.GT.0 )
333  \$ CALL sgemv( 'No transpose', nr, n-m, -one, a( n-p+1, m+1 ),
334  \$ lda, d( nr+1 ), 1, one, c( n-p+1 ), 1 )
335  ELSE
336  nr = p
337  END IF
338  IF( nr.GT.0 ) THEN
339  CALL strmv( 'Upper', 'No transpose', 'Non unit', nr,
340  \$ a( n-p+1, n-p+1 ), lda, d, 1 )
341  CALL saxpy( nr, -one, d, 1, c( n-p+1 ), 1 )
342  END IF
343 *
344 * Backward transformation x = Q**T*x
345 *
346  CALL sormrq( 'Left', 'Transpose', n, 1, p, b, ldb, work( 1 ), x,
347  \$ n, work( p+mn+1 ), lwork-p-mn, info )
348  work( 1 ) = p + mn + max( lopt, int( work( p+mn+1 ) ) )
349 *
350  RETURN
351 *
352 * End of SGGLSE
353 *
354  END
subroutine sormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMQR
Definition: sormqr.f:170
subroutine strtrs(UPLO, TRANS, DIAG, N, NRHS, A, LDA, B, LDB, INFO)
STRTRS
Definition: strtrs.f:142
subroutine sgglse(M, N, P, A, LDA, B, LDB, C, D, X, WORK, LWORK, INFO)
SGGLSE solves overdetermined or underdetermined systems for OTHER matrices
Definition: sgglse.f:182
subroutine sggrqf(M, P, N, A, LDA, TAUA, B, LDB, TAUB, WORK, LWORK, INFO)
SGGRQF
Definition: sggrqf.f:216
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SGEMV
Definition: sgemv.f:158
subroutine strmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
STRMV
Definition: strmv.f:149
subroutine saxpy(N, SA, SX, INCX, SY, INCY)
SAXPY
Definition: saxpy.f:54
subroutine sormrq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMRQ
Definition: sormrq.f:170
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:53