LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cpstrf.f
Go to the documentation of this file.
1 *> \brief \b CPSTRF computes the Cholesky factorization with complete pivoting of complex Hermitian positive semidefinite matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cpstrf.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cpstrf.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cpstrf.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CPSTRF( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * REAL TOL
25 * INTEGER INFO, LDA, N, RANK
26 * CHARACTER UPLO
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * )
30 * REAL WORK( 2*N )
31 * INTEGER PIV( N )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> CPSTRF computes the Cholesky factorization with complete
41 *> pivoting of a complex Hermitian positive semidefinite matrix A.
42 *>
43 *> The factorization has the form
44 *> P**T * A * P = U**H * U , if UPLO = 'U',
45 *> P**T * A * P = L * L**H, if UPLO = 'L',
46 *> where U is an upper triangular matrix and L is lower triangular, and
47 *> P is stored as vector PIV.
48 *>
49 *> This algorithm does not attempt to check that A is positive
50 *> semidefinite. This version of the algorithm calls level 3 BLAS.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] UPLO
57 *> \verbatim
58 *> UPLO is CHARACTER*1
59 *> Specifies whether the upper or lower triangular part of the
60 *> symmetric matrix A is stored.
61 *> = 'U': Upper triangular
62 *> = 'L': Lower triangular
63 *> \endverbatim
64 *>
65 *> \param[in] N
66 *> \verbatim
67 *> N is INTEGER
68 *> The order of the matrix A. N >= 0.
69 *> \endverbatim
70 *>
71 *> \param[in,out] A
72 *> \verbatim
73 *> A is COMPLEX array, dimension (LDA,N)
74 *> On entry, the symmetric matrix A. If UPLO = 'U', the leading
75 *> n by n upper triangular part of A contains the upper
76 *> triangular part of the matrix A, and the strictly lower
77 *> triangular part of A is not referenced. If UPLO = 'L', the
78 *> leading n by n lower triangular part of A contains the lower
79 *> triangular part of the matrix A, and the strictly upper
80 *> triangular part of A is not referenced.
81 *>
82 *> On exit, if INFO = 0, the factor U or L from the Cholesky
83 *> factorization as above.
84 *> \endverbatim
85 *>
86 *> \param[in] LDA
87 *> \verbatim
88 *> LDA is INTEGER
89 *> The leading dimension of the array A. LDA >= max(1,N).
90 *> \endverbatim
91 *>
92 *> \param[out] PIV
93 *> \verbatim
94 *> PIV is INTEGER array, dimension (N)
95 *> PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
96 *> \endverbatim
97 *>
98 *> \param[out] RANK
99 *> \verbatim
100 *> RANK is INTEGER
101 *> The rank of A given by the number of steps the algorithm
102 *> completed.
103 *> \endverbatim
104 *>
105 *> \param[in] TOL
106 *> \verbatim
107 *> TOL is REAL
108 *> User defined tolerance. If TOL < 0, then N*U*MAX( A(K,K) )
109 *> will be used. The algorithm terminates at the (K-1)st step
110 *> if the pivot <= TOL.
111 *> \endverbatim
112 *>
113 *> \param[out] WORK
114 *> \verbatim
115 *> WORK is REAL array, dimension (2*N)
116 *> Work space.
117 *> \endverbatim
118 *>
119 *> \param[out] INFO
120 *> \verbatim
121 *> INFO is INTEGER
122 *> < 0: If INFO = -K, the K-th argument had an illegal value,
123 *> = 0: algorithm completed successfully, and
124 *> > 0: the matrix A is either rank deficient with computed rank
125 *> as returned in RANK, or is not positive semidefinite. See
126 *> Section 7 of LAPACK Working Note #161 for further
127 *> information.
128 *> \endverbatim
129 *
130 * Authors:
131 * ========
132 *
133 *> \author Univ. of Tennessee
134 *> \author Univ. of California Berkeley
135 *> \author Univ. of Colorado Denver
136 *> \author NAG Ltd.
137 *
138 *> \date November 2015
139 *
140 *> \ingroup complexOTHERcomputational
141 *
142 * =====================================================================
143  SUBROUTINE cpstrf( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
144 *
145 * -- LAPACK computational routine (version 3.6.0) --
146 * -- LAPACK is a software package provided by Univ. of Tennessee, --
147 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
148 * November 2015
149 *
150 * .. Scalar Arguments ..
151  REAL TOL
152  INTEGER INFO, LDA, N, RANK
153  CHARACTER UPLO
154 * ..
155 * .. Array Arguments ..
156  COMPLEX A( lda, * )
157  REAL WORK( 2*n )
158  INTEGER PIV( n )
159 * ..
160 *
161 * =====================================================================
162 *
163 * .. Parameters ..
164  REAL ONE, ZERO
165  parameter ( one = 1.0e+0, zero = 0.0e+0 )
166  COMPLEX CONE
167  parameter ( cone = ( 1.0e+0, 0.0e+0 ) )
168 * ..
169 * .. Local Scalars ..
170  COMPLEX CTEMP
171  REAL AJJ, SSTOP, STEMP
172  INTEGER I, ITEMP, J, JB, K, NB, PVT
173  LOGICAL UPPER
174 * ..
175 * .. External Functions ..
176  REAL SLAMCH
177  INTEGER ILAENV
178  LOGICAL LSAME, SISNAN
179  EXTERNAL slamch, ilaenv, lsame, sisnan
180 * ..
181 * .. External Subroutines ..
182  EXTERNAL cgemv, cherk, clacgv, cpstf2, csscal, cswap,
183  \$ xerbla
184 * ..
185 * .. Intrinsic Functions ..
186  INTRINSIC conjg, max, min, REAL, SQRT, MAXLOC
187 * ..
188 * .. Executable Statements ..
189 *
190 * Test the input parameters.
191 *
192  info = 0
193  upper = lsame( uplo, 'U' )
194  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
195  info = -1
196  ELSE IF( n.LT.0 ) THEN
197  info = -2
198  ELSE IF( lda.LT.max( 1, n ) ) THEN
199  info = -4
200  END IF
201  IF( info.NE.0 ) THEN
202  CALL xerbla( 'CPSTRF', -info )
203  RETURN
204  END IF
205 *
206 * Quick return if possible
207 *
208  IF( n.EQ.0 )
209  \$ RETURN
210 *
211 * Get block size
212 *
213  nb = ilaenv( 1, 'CPOTRF', uplo, n, -1, -1, -1 )
214  IF( nb.LE.1 .OR. nb.GE.n ) THEN
215 *
216 * Use unblocked code
217 *
218  CALL cpstf2( uplo, n, a( 1, 1 ), lda, piv, rank, tol, work,
219  \$ info )
220  GO TO 230
221 *
222  ELSE
223 *
224 * Initialize PIV
225 *
226  DO 100 i = 1, n
227  piv( i ) = i
228  100 CONTINUE
229 *
230 * Compute stopping value
231 *
232  DO 110 i = 1, n
233  work( i ) = REAL( A( I, I ) )
234  110 CONTINUE
235  pvt = maxloc( work( 1:n ), 1 )
236  ajj = REAL( A( PVT, PVT ) )
237  IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
238  rank = 0
239  info = 1
240  GO TO 230
241  END IF
242 *
243 * Compute stopping value if not supplied
244 *
245  IF( tol.LT.zero ) THEN
246  sstop = n * slamch( 'Epsilon' ) * ajj
247  ELSE
248  sstop = tol
249  END IF
250 *
251 *
252  IF( upper ) THEN
253 *
254 * Compute the Cholesky factorization P**T * A * P = U**H * U
255 *
256  DO 160 k = 1, n, nb
257 *
258 * Account for last block not being NB wide
259 *
260  jb = min( nb, n-k+1 )
261 *
262 * Set relevant part of first half of WORK to zero,
263 * holds dot products
264 *
265  DO 120 i = k, n
266  work( i ) = 0
267  120 CONTINUE
268 *
269  DO 150 j = k, k + jb - 1
270 *
271 * Find pivot, test for exit, else swap rows and columns
272 * Update dot products, compute possible pivots which are
273 * stored in the second half of WORK
274 *
275  DO 130 i = j, n
276 *
277  IF( j.GT.k ) THEN
278  work( i ) = work( i ) +
279  \$ REAL( CONJG( A( J-1, I ) )*
280  \$ a( j-1, i ) )
281  END IF
282  work( n+i ) = REAL( A( I, I ) ) - WORK( i )
283 *
284  130 CONTINUE
285 *
286  IF( j.GT.1 ) THEN
287  itemp = maxloc( work( (n+j):(2*n) ), 1 )
288  pvt = itemp + j - 1
289  ajj = work( n+pvt )
290  IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
291  a( j, j ) = ajj
292  GO TO 220
293  END IF
294  END IF
295 *
296  IF( j.NE.pvt ) THEN
297 *
298 * Pivot OK, so can now swap pivot rows and columns
299 *
300  a( pvt, pvt ) = a( j, j )
301  CALL cswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
302  IF( pvt.LT.n )
303  \$ CALL cswap( n-pvt, a( j, pvt+1 ), lda,
304  \$ a( pvt, pvt+1 ), lda )
305  DO 140 i = j + 1, pvt - 1
306  ctemp = conjg( a( j, i ) )
307  a( j, i ) = conjg( a( i, pvt ) )
308  a( i, pvt ) = ctemp
309  140 CONTINUE
310  a( j, pvt ) = conjg( a( j, pvt ) )
311 *
312 * Swap dot products and PIV
313 *
314  stemp = work( j )
315  work( j ) = work( pvt )
316  work( pvt ) = stemp
317  itemp = piv( pvt )
318  piv( pvt ) = piv( j )
319  piv( j ) = itemp
320  END IF
321 *
322  ajj = sqrt( ajj )
323  a( j, j ) = ajj
324 *
325 * Compute elements J+1:N of row J.
326 *
327  IF( j.LT.n ) THEN
328  CALL clacgv( j-1, a( 1, j ), 1 )
329  CALL cgemv( 'Trans', j-k, n-j, -cone, a( k, j+1 ),
330  \$ lda, a( k, j ), 1, cone, a( j, j+1 ),
331  \$ lda )
332  CALL clacgv( j-1, a( 1, j ), 1 )
333  CALL csscal( n-j, one / ajj, a( j, j+1 ), lda )
334  END IF
335 *
336  150 CONTINUE
337 *
338 * Update trailing matrix, J already incremented
339 *
340  IF( k+jb.LE.n ) THEN
341  CALL cherk( 'Upper', 'Conj Trans', n-j+1, jb, -one,
342  \$ a( k, j ), lda, one, a( j, j ), lda )
343  END IF
344 *
345  160 CONTINUE
346 *
347  ELSE
348 *
349 * Compute the Cholesky factorization P**T * A * P = L * L**H
350 *
351  DO 210 k = 1, n, nb
352 *
353 * Account for last block not being NB wide
354 *
355  jb = min( nb, n-k+1 )
356 *
357 * Set relevant part of first half of WORK to zero,
358 * holds dot products
359 *
360  DO 170 i = k, n
361  work( i ) = 0
362  170 CONTINUE
363 *
364  DO 200 j = k, k + jb - 1
365 *
366 * Find pivot, test for exit, else swap rows and columns
367 * Update dot products, compute possible pivots which are
368 * stored in the second half of WORK
369 *
370  DO 180 i = j, n
371 *
372  IF( j.GT.k ) THEN
373  work( i ) = work( i ) +
374  \$ REAL( CONJG( A( I, J-1 ) )*
375  \$ a( i, j-1 ) )
376  END IF
377  work( n+i ) = REAL( A( I, I ) ) - WORK( i )
378 *
379  180 CONTINUE
380 *
381  IF( j.GT.1 ) THEN
382  itemp = maxloc( work( (n+j):(2*n) ), 1 )
383  pvt = itemp + j - 1
384  ajj = work( n+pvt )
385  IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
386  a( j, j ) = ajj
387  GO TO 220
388  END IF
389  END IF
390 *
391  IF( j.NE.pvt ) THEN
392 *
393 * Pivot OK, so can now swap pivot rows and columns
394 *
395  a( pvt, pvt ) = a( j, j )
396  CALL cswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
397  IF( pvt.LT.n )
398  \$ CALL cswap( n-pvt, a( pvt+1, j ), 1,
399  \$ a( pvt+1, pvt ), 1 )
400  DO 190 i = j + 1, pvt - 1
401  ctemp = conjg( a( i, j ) )
402  a( i, j ) = conjg( a( pvt, i ) )
403  a( pvt, i ) = ctemp
404  190 CONTINUE
405  a( pvt, j ) = conjg( a( pvt, j ) )
406 *
407 * Swap dot products and PIV
408 *
409  stemp = work( j )
410  work( j ) = work( pvt )
411  work( pvt ) = stemp
412  itemp = piv( pvt )
413  piv( pvt ) = piv( j )
414  piv( j ) = itemp
415  END IF
416 *
417  ajj = sqrt( ajj )
418  a( j, j ) = ajj
419 *
420 * Compute elements J+1:N of column J.
421 *
422  IF( j.LT.n ) THEN
423  CALL clacgv( j-1, a( j, 1 ), lda )
424  CALL cgemv( 'No Trans', n-j, j-k, -cone,
425  \$ a( j+1, k ), lda, a( j, k ), lda, cone,
426  \$ a( j+1, j ), 1 )
427  CALL clacgv( j-1, a( j, 1 ), lda )
428  CALL csscal( n-j, one / ajj, a( j+1, j ), 1 )
429  END IF
430 *
431  200 CONTINUE
432 *
433 * Update trailing matrix, J already incremented
434 *
435  IF( k+jb.LE.n ) THEN
436  CALL cherk( 'Lower', 'No Trans', n-j+1, jb, -one,
437  \$ a( j, k ), lda, one, a( j, j ), lda )
438  END IF
439 *
440  210 CONTINUE
441 *
442  END IF
443  END IF
444 *
445 * Ran to completion, A has full rank
446 *
447  rank = n
448 *
449  GO TO 230
450  220 CONTINUE
451 *
452 * Rank is the number of steps completed. Set INFO = 1 to signal
453 * that the factorization cannot be used to solve a system.
454 *
455  rank = j - 1
456  info = 1
457 *
458  230 CONTINUE
459  RETURN
460 *
461 * End of CPSTRF
462 *
463  END
subroutine cpstf2(UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO)
CPSTF2 computes the Cholesky factorization with complete pivoting of complex Hermitian positive semid...
Definition: cpstf2.f:144
subroutine cpstrf(UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO)
CPSTRF computes the Cholesky factorization with complete pivoting of complex Hermitian positive semid...
Definition: cpstrf.f:144
subroutine cherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
CHERK
Definition: cherk.f:175
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine cgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGEMV
Definition: cgemv.f:160
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76
subroutine cswap(N, CX, INCX, CY, INCY)
CSWAP
Definition: cswap.f:52
subroutine csscal(N, SA, CX, INCX)
CSSCAL
Definition: csscal.f:54