LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
real function clange ( character  NORM,
integer  M,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  WORK 
)

CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.

Download CLANGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANGE  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex matrix A.
Returns
CLANGE
    CLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANGE as described
          above.
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.  When M = 0,
          CLANGE is set to zero.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.  When N = 0,
          CLANGE is set to zero.
[in]A
          A is COMPLEX array, dimension (LDA,N)
          The m by n matrix A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(M,1).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 117 of file clange.f.

117 *
118 * -- LAPACK auxiliary routine (version 3.4.2) --
119 * -- LAPACK is a software package provided by Univ. of Tennessee, --
120 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121 * September 2012
122 *
123 * .. Scalar Arguments ..
124  CHARACTER norm
125  INTEGER lda, m, n
126 * ..
127 * .. Array Arguments ..
128  REAL work( * )
129  COMPLEX a( lda, * )
130 * ..
131 *
132 * =====================================================================
133 *
134 * .. Parameters ..
135  REAL one, zero
136  parameter ( one = 1.0e+0, zero = 0.0e+0 )
137 * ..
138 * .. Local Scalars ..
139  INTEGER i, j
140  REAL scale, sum, VALUE, temp
141 * ..
142 * .. External Functions ..
143  LOGICAL lsame, sisnan
144  EXTERNAL lsame, sisnan
145 * ..
146 * .. External Subroutines ..
147  EXTERNAL classq
148 * ..
149 * .. Intrinsic Functions ..
150  INTRINSIC abs, min, sqrt
151 * ..
152 * .. Executable Statements ..
153 *
154  IF( min( m, n ).EQ.0 ) THEN
155  VALUE = zero
156  ELSE IF( lsame( norm, 'M' ) ) THEN
157 *
158 * Find max(abs(A(i,j))).
159 *
160  VALUE = zero
161  DO 20 j = 1, n
162  DO 10 i = 1, m
163  temp = abs( a( i, j ) )
164  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
165  10 CONTINUE
166  20 CONTINUE
167  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
168 *
169 * Find norm1(A).
170 *
171  VALUE = zero
172  DO 40 j = 1, n
173  sum = zero
174  DO 30 i = 1, m
175  sum = sum + abs( a( i, j ) )
176  30 CONTINUE
177  IF( VALUE.LT.sum .OR. sisnan( sum ) ) VALUE = sum
178  40 CONTINUE
179  ELSE IF( lsame( norm, 'I' ) ) THEN
180 *
181 * Find normI(A).
182 *
183  DO 50 i = 1, m
184  work( i ) = zero
185  50 CONTINUE
186  DO 70 j = 1, n
187  DO 60 i = 1, m
188  work( i ) = work( i ) + abs( a( i, j ) )
189  60 CONTINUE
190  70 CONTINUE
191  VALUE = zero
192  DO 80 i = 1, m
193  temp = work( i )
194  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
195  80 CONTINUE
196  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
197 *
198 * Find normF(A).
199 *
200  scale = zero
201  sum = one
202  DO 90 j = 1, n
203  CALL classq( m, a( 1, j ), 1, scale, sum )
204  90 CONTINUE
205  VALUE = scale*sqrt( sum )
206  END IF
207 *
208  clange = VALUE
209  RETURN
210 *
211 * End of CLANGE
212 *
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:61
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
real function clange(NORM, M, N, A, LDA, WORK)
CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clange.f:117
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: