LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
csprfs.f
Go to the documentation of this file.
1 *> \brief \b CSPRFS
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CSPRFS + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/csprfs.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/csprfs.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/csprfs.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CSPRFS( UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX,
22 * FERR, BERR, WORK, RWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER UPLO
26 * INTEGER INFO, LDB, LDX, N, NRHS
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IPIV( * )
30 * REAL BERR( * ), FERR( * ), RWORK( * )
31 * COMPLEX AFP( * ), AP( * ), B( LDB, * ), WORK( * ),
32 * $ X( LDX, * )
33 * ..
34 *
35 *
36 *> \par Purpose:
37 * =============
38 *>
39 *> \verbatim
40 *>
41 *> CSPRFS improves the computed solution to a system of linear
42 *> equations when the coefficient matrix is symmetric indefinite
43 *> and packed, and provides error bounds and backward error estimates
44 *> for the solution.
45 *> \endverbatim
46 *
47 * Arguments:
48 * ==========
49 *
50 *> \param[in] UPLO
51 *> \verbatim
52 *> UPLO is CHARACTER*1
53 *> = 'U': Upper triangle of A is stored;
54 *> = 'L': Lower triangle of A is stored.
55 *> \endverbatim
56 *>
57 *> \param[in] N
58 *> \verbatim
59 *> N is INTEGER
60 *> The order of the matrix A. N >= 0.
61 *> \endverbatim
62 *>
63 *> \param[in] NRHS
64 *> \verbatim
65 *> NRHS is INTEGER
66 *> The number of right hand sides, i.e., the number of columns
67 *> of the matrices B and X. NRHS >= 0.
68 *> \endverbatim
69 *>
70 *> \param[in] AP
71 *> \verbatim
72 *> AP is COMPLEX array, dimension (N*(N+1)/2)
73 *> The upper or lower triangle of the symmetric matrix A, packed
74 *> columnwise in a linear array. The j-th column of A is stored
75 *> in the array AP as follows:
76 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
77 *> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
78 *> \endverbatim
79 *>
80 *> \param[in] AFP
81 *> \verbatim
82 *> AFP is COMPLEX array, dimension (N*(N+1)/2)
83 *> The factored form of the matrix A. AFP contains the block
84 *> diagonal matrix D and the multipliers used to obtain the
85 *> factor U or L from the factorization A = U*D*U**T or
86 *> A = L*D*L**T as computed by CSPTRF, stored as a packed
87 *> triangular matrix.
88 *> \endverbatim
89 *>
90 *> \param[in] IPIV
91 *> \verbatim
92 *> IPIV is INTEGER array, dimension (N)
93 *> Details of the interchanges and the block structure of D
94 *> as determined by CSPTRF.
95 *> \endverbatim
96 *>
97 *> \param[in] B
98 *> \verbatim
99 *> B is COMPLEX array, dimension (LDB,NRHS)
100 *> The right hand side matrix B.
101 *> \endverbatim
102 *>
103 *> \param[in] LDB
104 *> \verbatim
105 *> LDB is INTEGER
106 *> The leading dimension of the array B. LDB >= max(1,N).
107 *> \endverbatim
108 *>
109 *> \param[in,out] X
110 *> \verbatim
111 *> X is COMPLEX array, dimension (LDX,NRHS)
112 *> On entry, the solution matrix X, as computed by CSPTRS.
113 *> On exit, the improved solution matrix X.
114 *> \endverbatim
115 *>
116 *> \param[in] LDX
117 *> \verbatim
118 *> LDX is INTEGER
119 *> The leading dimension of the array X. LDX >= max(1,N).
120 *> \endverbatim
121 *>
122 *> \param[out] FERR
123 *> \verbatim
124 *> FERR is REAL array, dimension (NRHS)
125 *> The estimated forward error bound for each solution vector
126 *> X(j) (the j-th column of the solution matrix X).
127 *> If XTRUE is the true solution corresponding to X(j), FERR(j)
128 *> is an estimated upper bound for the magnitude of the largest
129 *> element in (X(j) - XTRUE) divided by the magnitude of the
130 *> largest element in X(j). The estimate is as reliable as
131 *> the estimate for RCOND, and is almost always a slight
132 *> overestimate of the true error.
133 *> \endverbatim
134 *>
135 *> \param[out] BERR
136 *> \verbatim
137 *> BERR is REAL array, dimension (NRHS)
138 *> The componentwise relative backward error of each solution
139 *> vector X(j) (i.e., the smallest relative change in
140 *> any element of A or B that makes X(j) an exact solution).
141 *> \endverbatim
142 *>
143 *> \param[out] WORK
144 *> \verbatim
145 *> WORK is COMPLEX array, dimension (2*N)
146 *> \endverbatim
147 *>
148 *> \param[out] RWORK
149 *> \verbatim
150 *> RWORK is REAL array, dimension (N)
151 *> \endverbatim
152 *>
153 *> \param[out] INFO
154 *> \verbatim
155 *> INFO is INTEGER
156 *> = 0: successful exit
157 *> < 0: if INFO = -i, the i-th argument had an illegal value
158 *> \endverbatim
159 *
160 *> \par Internal Parameters:
161 * =========================
162 *>
163 *> \verbatim
164 *> ITMAX is the maximum number of steps of iterative refinement.
165 *> \endverbatim
166 *
167 * Authors:
168 * ========
169 *
170 *> \author Univ. of Tennessee
171 *> \author Univ. of California Berkeley
172 *> \author Univ. of Colorado Denver
173 *> \author NAG Ltd.
174 *
175 *> \date November 2011
176 *
177 *> \ingroup complexOTHERcomputational
178 *
179 * =====================================================================
180  SUBROUTINE csprfs( UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX,
181  $ ferr, berr, work, rwork, info )
182 *
183 * -- LAPACK computational routine (version 3.4.0) --
184 * -- LAPACK is a software package provided by Univ. of Tennessee, --
185 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
186 * November 2011
187 *
188 * .. Scalar Arguments ..
189  CHARACTER UPLO
190  INTEGER INFO, LDB, LDX, N, NRHS
191 * ..
192 * .. Array Arguments ..
193  INTEGER IPIV( * )
194  REAL BERR( * ), FERR( * ), RWORK( * )
195  COMPLEX AFP( * ), AP( * ), B( ldb, * ), WORK( * ),
196  $ x( ldx, * )
197 * ..
198 *
199 * =====================================================================
200 *
201 * .. Parameters ..
202  INTEGER ITMAX
203  parameter ( itmax = 5 )
204  REAL ZERO
205  parameter ( zero = 0.0e+0 )
206  COMPLEX ONE
207  parameter ( one = ( 1.0e+0, 0.0e+0 ) )
208  REAL TWO
209  parameter ( two = 2.0e+0 )
210  REAL THREE
211  parameter ( three = 3.0e+0 )
212 * ..
213 * .. Local Scalars ..
214  LOGICAL UPPER
215  INTEGER COUNT, I, IK, J, K, KASE, KK, NZ
216  REAL EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
217  COMPLEX ZDUM
218 * ..
219 * .. Local Arrays ..
220  INTEGER ISAVE( 3 )
221 * ..
222 * .. External Subroutines ..
223  EXTERNAL caxpy, ccopy, clacn2, cspmv, csptrs, xerbla
224 * ..
225 * .. Intrinsic Functions ..
226  INTRINSIC abs, aimag, max, real
227 * ..
228 * .. External Functions ..
229  LOGICAL LSAME
230  REAL SLAMCH
231  EXTERNAL lsame, slamch
232 * ..
233 * .. Statement Functions ..
234  REAL CABS1
235 * ..
236 * .. Statement Function definitions ..
237  cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( AIMAG( zdum ) )
238 * ..
239 * .. Executable Statements ..
240 *
241 * Test the input parameters.
242 *
243  info = 0
244  upper = lsame( uplo, 'U' )
245  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
246  info = -1
247  ELSE IF( n.LT.0 ) THEN
248  info = -2
249  ELSE IF( nrhs.LT.0 ) THEN
250  info = -3
251  ELSE IF( ldb.LT.max( 1, n ) ) THEN
252  info = -8
253  ELSE IF( ldx.LT.max( 1, n ) ) THEN
254  info = -10
255  END IF
256  IF( info.NE.0 ) THEN
257  CALL xerbla( 'CSPRFS', -info )
258  RETURN
259  END IF
260 *
261 * Quick return if possible
262 *
263  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
264  DO 10 j = 1, nrhs
265  ferr( j ) = zero
266  berr( j ) = zero
267  10 CONTINUE
268  RETURN
269  END IF
270 *
271 * NZ = maximum number of nonzero elements in each row of A, plus 1
272 *
273  nz = n + 1
274  eps = slamch( 'Epsilon' )
275  safmin = slamch( 'Safe minimum' )
276  safe1 = nz*safmin
277  safe2 = safe1 / eps
278 *
279 * Do for each right hand side
280 *
281  DO 140 j = 1, nrhs
282 *
283  count = 1
284  lstres = three
285  20 CONTINUE
286 *
287 * Loop until stopping criterion is satisfied.
288 *
289 * Compute residual R = B - A * X
290 *
291  CALL ccopy( n, b( 1, j ), 1, work, 1 )
292  CALL cspmv( uplo, n, -one, ap, x( 1, j ), 1, one, work, 1 )
293 *
294 * Compute componentwise relative backward error from formula
295 *
296 * max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
297 *
298 * where abs(Z) is the componentwise absolute value of the matrix
299 * or vector Z. If the i-th component of the denominator is less
300 * than SAFE2, then SAFE1 is added to the i-th components of the
301 * numerator and denominator before dividing.
302 *
303  DO 30 i = 1, n
304  rwork( i ) = cabs1( b( i, j ) )
305  30 CONTINUE
306 *
307 * Compute abs(A)*abs(X) + abs(B).
308 *
309  kk = 1
310  IF( upper ) THEN
311  DO 50 k = 1, n
312  s = zero
313  xk = cabs1( x( k, j ) )
314  ik = kk
315  DO 40 i = 1, k - 1
316  rwork( i ) = rwork( i ) + cabs1( ap( ik ) )*xk
317  s = s + cabs1( ap( ik ) )*cabs1( x( i, j ) )
318  ik = ik + 1
319  40 CONTINUE
320  rwork( k ) = rwork( k ) + cabs1( ap( kk+k-1 ) )*xk + s
321  kk = kk + k
322  50 CONTINUE
323  ELSE
324  DO 70 k = 1, n
325  s = zero
326  xk = cabs1( x( k, j ) )
327  rwork( k ) = rwork( k ) + cabs1( ap( kk ) )*xk
328  ik = kk + 1
329  DO 60 i = k + 1, n
330  rwork( i ) = rwork( i ) + cabs1( ap( ik ) )*xk
331  s = s + cabs1( ap( ik ) )*cabs1( x( i, j ) )
332  ik = ik + 1
333  60 CONTINUE
334  rwork( k ) = rwork( k ) + s
335  kk = kk + ( n-k+1 )
336  70 CONTINUE
337  END IF
338  s = zero
339  DO 80 i = 1, n
340  IF( rwork( i ).GT.safe2 ) THEN
341  s = max( s, cabs1( work( i ) ) / rwork( i ) )
342  ELSE
343  s = max( s, ( cabs1( work( i ) )+safe1 ) /
344  $ ( rwork( i )+safe1 ) )
345  END IF
346  80 CONTINUE
347  berr( j ) = s
348 *
349 * Test stopping criterion. Continue iterating if
350 * 1) The residual BERR(J) is larger than machine epsilon, and
351 * 2) BERR(J) decreased by at least a factor of 2 during the
352 * last iteration, and
353 * 3) At most ITMAX iterations tried.
354 *
355  IF( berr( j ).GT.eps .AND. two*berr( j ).LE.lstres .AND.
356  $ count.LE.itmax ) THEN
357 *
358 * Update solution and try again.
359 *
360  CALL csptrs( uplo, n, 1, afp, ipiv, work, n, info )
361  CALL caxpy( n, one, work, 1, x( 1, j ), 1 )
362  lstres = berr( j )
363  count = count + 1
364  GO TO 20
365  END IF
366 *
367 * Bound error from formula
368 *
369 * norm(X - XTRUE) / norm(X) .le. FERR =
370 * norm( abs(inv(A))*
371 * ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
372 *
373 * where
374 * norm(Z) is the magnitude of the largest component of Z
375 * inv(A) is the inverse of A
376 * abs(Z) is the componentwise absolute value of the matrix or
377 * vector Z
378 * NZ is the maximum number of nonzeros in any row of A, plus 1
379 * EPS is machine epsilon
380 *
381 * The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
382 * is incremented by SAFE1 if the i-th component of
383 * abs(A)*abs(X) + abs(B) is less than SAFE2.
384 *
385 * Use CLACN2 to estimate the infinity-norm of the matrix
386 * inv(A) * diag(W),
387 * where W = abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) )))
388 *
389  DO 90 i = 1, n
390  IF( rwork( i ).GT.safe2 ) THEN
391  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i )
392  ELSE
393  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i ) +
394  $ safe1
395  END IF
396  90 CONTINUE
397 *
398  kase = 0
399  100 CONTINUE
400  CALL clacn2( n, work( n+1 ), work, ferr( j ), kase, isave )
401  IF( kase.NE.0 ) THEN
402  IF( kase.EQ.1 ) THEN
403 *
404 * Multiply by diag(W)*inv(A**T).
405 *
406  CALL csptrs( uplo, n, 1, afp, ipiv, work, n, info )
407  DO 110 i = 1, n
408  work( i ) = rwork( i )*work( i )
409  110 CONTINUE
410  ELSE IF( kase.EQ.2 ) THEN
411 *
412 * Multiply by inv(A)*diag(W).
413 *
414  DO 120 i = 1, n
415  work( i ) = rwork( i )*work( i )
416  120 CONTINUE
417  CALL csptrs( uplo, n, 1, afp, ipiv, work, n, info )
418  END IF
419  GO TO 100
420  END IF
421 *
422 * Normalize error.
423 *
424  lstres = zero
425  DO 130 i = 1, n
426  lstres = max( lstres, cabs1( x( i, j ) ) )
427  130 CONTINUE
428  IF( lstres.NE.zero )
429  $ ferr( j ) = ferr( j ) / lstres
430 *
431  140 CONTINUE
432 *
433  RETURN
434 *
435 * End of CSPRFS
436 *
437  END
subroutine cspmv(UPLO, N, ALPHA, AP, X, INCX, BETA, Y, INCY)
CSPMV computes a matrix-vector product for complex vectors using a complex symmetric packed matrix ...
Definition: cspmv.f:153
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine csptrs(UPLO, N, NRHS, AP, IPIV, B, LDB, INFO)
CSPTRS
Definition: csptrs.f:117
subroutine csprfs(UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
CSPRFS
Definition: csprfs.f:182
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:52
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:53
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:135