LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
cunmql.f
Go to the documentation of this file.
1 *> \brief \b CUNMQL
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmql.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmql.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmql.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ),
30 * \$ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> CUNMQL overwrites the general complex M-by-N matrix C with
40 *>
41 *> SIDE = 'L' SIDE = 'R'
42 *> TRANS = 'N': Q * C C * Q
43 *> TRANS = 'C': Q**H * C C * Q**H
44 *>
45 *> where Q is a complex unitary matrix defined as the product of k
46 *> elementary reflectors
47 *>
48 *> Q = H(k) . . . H(2) H(1)
49 *>
50 *> as returned by CGEQLF. Q is of order M if SIDE = 'L' and of order N
51 *> if SIDE = 'R'.
52 *> \endverbatim
53 *
54 * Arguments:
55 * ==========
56 *
57 *> \param[in] SIDE
58 *> \verbatim
59 *> SIDE is CHARACTER*1
60 *> = 'L': apply Q or Q**H from the Left;
61 *> = 'R': apply Q or Q**H from the Right.
62 *> \endverbatim
63 *>
64 *> \param[in] TRANS
65 *> \verbatim
66 *> TRANS is CHARACTER*1
67 *> = 'N': No transpose, apply Q;
68 *> = 'C': Transpose, apply Q**H.
69 *> \endverbatim
70 *>
71 *> \param[in] M
72 *> \verbatim
73 *> M is INTEGER
74 *> The number of rows of the matrix C. M >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] N
78 *> \verbatim
79 *> N is INTEGER
80 *> The number of columns of the matrix C. N >= 0.
81 *> \endverbatim
82 *>
83 *> \param[in] K
84 *> \verbatim
85 *> K is INTEGER
86 *> The number of elementary reflectors whose product defines
87 *> the matrix Q.
88 *> If SIDE = 'L', M >= K >= 0;
89 *> if SIDE = 'R', N >= K >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] A
93 *> \verbatim
94 *> A is COMPLEX array, dimension (LDA,K)
95 *> The i-th column must contain the vector which defines the
96 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
97 *> CGEQLF in the last k columns of its array argument A.
98 *> \endverbatim
99 *>
100 *> \param[in] LDA
101 *> \verbatim
102 *> LDA is INTEGER
103 *> The leading dimension of the array A.
104 *> If SIDE = 'L', LDA >= max(1,M);
105 *> if SIDE = 'R', LDA >= max(1,N).
106 *> \endverbatim
107 *>
108 *> \param[in] TAU
109 *> \verbatim
110 *> TAU is COMPLEX array, dimension (K)
111 *> TAU(i) must contain the scalar factor of the elementary
112 *> reflector H(i), as returned by CGEQLF.
113 *> \endverbatim
114 *>
115 *> \param[in,out] C
116 *> \verbatim
117 *> C is COMPLEX array, dimension (LDC,N)
118 *> On entry, the M-by-N matrix C.
119 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
120 *> \endverbatim
121 *>
122 *> \param[in] LDC
123 *> \verbatim
124 *> LDC is INTEGER
125 *> The leading dimension of the array C. LDC >= max(1,M).
126 *> \endverbatim
127 *>
128 *> \param[out] WORK
129 *> \verbatim
130 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
131 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132 *> \endverbatim
133 *>
134 *> \param[in] LWORK
135 *> \verbatim
136 *> LWORK is INTEGER
137 *> The dimension of the array WORK.
138 *> If SIDE = 'L', LWORK >= max(1,N);
139 *> if SIDE = 'R', LWORK >= max(1,M).
140 *> For good performance, LWORK should generally be larger.
141 *>
142 *> If LWORK = -1, then a workspace query is assumed; the routine
143 *> only calculates the optimal size of the WORK array, returns
144 *> this value as the first entry of the WORK array, and no error
145 *> message related to LWORK is issued by XERBLA.
146 *> \endverbatim
147 *>
148 *> \param[out] INFO
149 *> \verbatim
150 *> INFO is INTEGER
151 *> = 0: successful exit
152 *> < 0: if INFO = -i, the i-th argument had an illegal value
153 *> \endverbatim
154 *
155 * Authors:
156 * ========
157 *
158 *> \author Univ. of Tennessee
159 *> \author Univ. of California Berkeley
160 *> \author Univ. of Colorado Denver
161 *> \author NAG Ltd.
162 *
163 *> \date November 2015
164 *
165 *> \ingroup complexOTHERcomputational
166 *
167 * =====================================================================
168  SUBROUTINE cunmql( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
169  \$ work, lwork, info )
170 *
171 * -- LAPACK computational routine (version 3.6.0) --
172 * -- LAPACK is a software package provided by Univ. of Tennessee, --
173 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
174 * November 2015
175 *
176 * .. Scalar Arguments ..
177  CHARACTER SIDE, TRANS
178  INTEGER INFO, K, LDA, LDC, LWORK, M, N
179 * ..
180 * .. Array Arguments ..
181  COMPLEX A( lda, * ), C( ldc, * ), TAU( * ),
182  \$ work( * )
183 * ..
184 *
185 * =====================================================================
186 *
187 * .. Parameters ..
188  INTEGER NBMAX, LDT, TSIZE
189  parameter ( nbmax = 64, ldt = nbmax+1,
190  \$ tsize = ldt*nbmax )
191 * ..
192 * .. Local Scalars ..
193  LOGICAL LEFT, LQUERY, NOTRAN
194  INTEGER I, I1, I2, I3, IB, IINFO, IWT, LDWORK, LWKOPT,
195  \$ mi, nb, nbmin, ni, nq, nw
196 * ..
197 * .. External Functions ..
198  LOGICAL LSAME
199  INTEGER ILAENV
200  EXTERNAL lsame, ilaenv
201 * ..
202 * .. External Subroutines ..
203  EXTERNAL clarfb, clarft, cunm2l, xerbla
204 * ..
205 * .. Intrinsic Functions ..
206  INTRINSIC max, min
207 * ..
208 * .. Executable Statements ..
209 *
210 * Test the input arguments
211 *
212  info = 0
213  left = lsame( side, 'L' )
214  notran = lsame( trans, 'N' )
215  lquery = ( lwork.EQ.-1 )
216 *
217 * NQ is the order of Q and NW is the minimum dimension of WORK
218 *
219  IF( left ) THEN
220  nq = m
221  nw = max( 1, n )
222  ELSE
223  nq = n
224  nw = max( 1, m )
225  END IF
226  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
227  info = -1
228  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
229  info = -2
230  ELSE IF( m.LT.0 ) THEN
231  info = -3
232  ELSE IF( n.LT.0 ) THEN
233  info = -4
234  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
235  info = -5
236  ELSE IF( lda.LT.max( 1, nq ) ) THEN
237  info = -7
238  ELSE IF( ldc.LT.max( 1, m ) ) THEN
239  info = -10
240  ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
241  info = -12
242  END IF
243 *
244  IF( info.EQ.0 ) THEN
245 *
246 * Compute the workspace requirements
247 *
248  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
249  lwkopt = 1
250  ELSE
251  nb = min( nbmax, ilaenv( 1, 'CUNMQL', side // trans, m, n,
252  \$ k, -1 ) )
253  lwkopt = nw*nb + tsize
254  END IF
255  work( 1 ) = lwkopt
256  END IF
257 *
258  IF( info.NE.0 ) THEN
259  CALL xerbla( 'CUNMQL', -info )
260  RETURN
261  ELSE IF( lquery ) THEN
262  RETURN
263  END IF
264 *
265 * Quick return if possible
266 *
267  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
268  RETURN
269  END IF
270 *
271 * Determine the block size
272 *
273  nbmin = 2
274  ldwork = nw
275  IF( nb.GT.1 .AND. nb.LT.k ) THEN
276  IF( lwork.LT.(nw*nb+tsize) ) THEN
277  nb = (lwork-tsize) / ldwork
278  nbmin = max( 2, ilaenv( 2, 'CUNMQL', side // trans, m, n, k,
279  \$ -1 ) )
280  END IF
281  END IF
282 *
283  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
284 *
285 * Use unblocked code
286 *
287  CALL cunm2l( side, trans, m, n, k, a, lda, tau, c, ldc, work,
288  \$ iinfo )
289  ELSE
290 *
291 * Use blocked code
292 *
293  iwt = 1 + nw*nb
294  IF( ( left .AND. notran ) .OR.
295  \$ ( .NOT.left .AND. .NOT.notran ) ) THEN
296  i1 = 1
297  i2 = k
298  i3 = nb
299  ELSE
300  i1 = ( ( k-1 ) / nb )*nb + 1
301  i2 = 1
302  i3 = -nb
303  END IF
304 *
305  IF( left ) THEN
306  ni = n
307  ELSE
308  mi = m
309  END IF
310 *
311  DO 10 i = i1, i2, i3
312  ib = min( nb, k-i+1 )
313 *
314 * Form the triangular factor of the block reflector
315 * H = H(i+ib-1) . . . H(i+1) H(i)
316 *
317  CALL clarft( 'Backward', 'Columnwise', nq-k+i+ib-1, ib,
318  \$ a( 1, i ), lda, tau( i ), work( iwt ), ldt )
319  IF( left ) THEN
320 *
321 * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
322 *
323  mi = m - k + i + ib - 1
324  ELSE
325 *
326 * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
327 *
328  ni = n - k + i + ib - 1
329  END IF
330 *
331 * Apply H or H**H
332 *
333  CALL clarfb( side, trans, 'Backward', 'Columnwise', mi, ni,
334  \$ ib, a( 1, i ), lda, work( iwt ), ldt, c, ldc,
335  \$ work, ldwork )
336  10 CONTINUE
337  END IF
338  work( 1 ) = lwkopt
339  RETURN
340 *
341 * End of CUNMQL
342 *
343  END
subroutine clarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
CLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: clarft.f:165
subroutine cunm2l(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
CUNM2L multiplies a general matrix by the unitary matrix from a QL factorization determined by cgeqlf...
Definition: cunm2l.f:161
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine cunmql(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
CUNMQL
Definition: cunmql.f:170
subroutine clarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
CLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix...
Definition: clarfb.f:197