LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
ztrtri.f
Go to the documentation of this file.
1 *> \brief \b ZTRTRI
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztrtri.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztrtri.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztrtri.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZTRTRI( UPLO, DIAG, N, A, LDA, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER DIAG, UPLO
25 * INTEGER INFO, LDA, N
26 * ..
27 * .. Array Arguments ..
28 * COMPLEX*16 A( LDA, * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> ZTRTRI computes the inverse of a complex upper or lower triangular
38 *> matrix A.
39 *>
40 *> This is the Level 3 BLAS version of the algorithm.
41 *> \endverbatim
42 *
43 * Arguments:
44 * ==========
45 *
46 *> \param[in] UPLO
47 *> \verbatim
48 *> UPLO is CHARACTER*1
49 *> = 'U': A is upper triangular;
50 *> = 'L': A is lower triangular.
51 *> \endverbatim
52 *>
53 *> \param[in] DIAG
54 *> \verbatim
55 *> DIAG is CHARACTER*1
56 *> = 'N': A is non-unit triangular;
57 *> = 'U': A is unit triangular.
58 *> \endverbatim
59 *>
60 *> \param[in] N
61 *> \verbatim
62 *> N is INTEGER
63 *> The order of the matrix A. N >= 0.
64 *> \endverbatim
65 *>
66 *> \param[in,out] A
67 *> \verbatim
68 *> A is COMPLEX*16 array, dimension (LDA,N)
69 *> On entry, the triangular matrix A. If UPLO = 'U', the
70 *> leading N-by-N upper triangular part of the array A contains
71 *> the upper triangular matrix, and the strictly lower
72 *> triangular part of A is not referenced. If UPLO = 'L', the
73 *> leading N-by-N lower triangular part of the array A contains
74 *> the lower triangular matrix, and the strictly upper
75 *> triangular part of A is not referenced. If DIAG = 'U', the
76 *> diagonal elements of A are also not referenced and are
77 *> assumed to be 1.
78 *> On exit, the (triangular) inverse of the original matrix, in
79 *> the same storage format.
80 *> \endverbatim
81 *>
82 *> \param[in] LDA
83 *> \verbatim
84 *> LDA is INTEGER
85 *> The leading dimension of the array A. LDA >= max(1,N).
86 *> \endverbatim
87 *>
88 *> \param[out] INFO
89 *> \verbatim
90 *> INFO is INTEGER
91 *> = 0: successful exit
92 *> < 0: if INFO = -i, the i-th argument had an illegal value
93 *> > 0: if INFO = i, A(i,i) is exactly zero. The triangular
94 *> matrix is singular and its inverse can not be computed.
95 *> \endverbatim
96 *
97 * Authors:
98 * ========
99 *
100 *> \author Univ. of Tennessee
101 *> \author Univ. of California Berkeley
102 *> \author Univ. of Colorado Denver
103 *> \author NAG Ltd.
104 *
105 *> \date November 2011
106 *
107 *> \ingroup complex16OTHERcomputational
108 *
109 * =====================================================================
110  SUBROUTINE ztrtri( UPLO, DIAG, N, A, LDA, INFO )
111 *
112 * -- LAPACK computational routine (version 3.4.0) --
113 * -- LAPACK is a software package provided by Univ. of Tennessee, --
114 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
115 * November 2011
116 *
117 * .. Scalar Arguments ..
118  CHARACTER DIAG, UPLO
119  INTEGER INFO, LDA, N
120 * ..
121 * .. Array Arguments ..
122  COMPLEX*16 A( lda, * )
123 * ..
124 *
125 * =====================================================================
126 *
127 * .. Parameters ..
128  COMPLEX*16 ONE, ZERO
129  parameter ( one = ( 1.0d+0, 0.0d+0 ),
130  \$ zero = ( 0.0d+0, 0.0d+0 ) )
131 * ..
132 * .. Local Scalars ..
133  LOGICAL NOUNIT, UPPER
134  INTEGER J, JB, NB, NN
135 * ..
136 * .. External Functions ..
137  LOGICAL LSAME
138  INTEGER ILAENV
139  EXTERNAL lsame, ilaenv
140 * ..
141 * .. External Subroutines ..
142  EXTERNAL xerbla, ztrmm, ztrsm, ztrti2
143 * ..
144 * .. Intrinsic Functions ..
145  INTRINSIC max, min
146 * ..
147 * .. Executable Statements ..
148 *
149 * Test the input parameters.
150 *
151  info = 0
152  upper = lsame( uplo, 'U' )
153  nounit = lsame( diag, 'N' )
154  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
155  info = -1
156  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
157  info = -2
158  ELSE IF( n.LT.0 ) THEN
159  info = -3
160  ELSE IF( lda.LT.max( 1, n ) ) THEN
161  info = -5
162  END IF
163  IF( info.NE.0 ) THEN
164  CALL xerbla( 'ZTRTRI', -info )
165  RETURN
166  END IF
167 *
168 * Quick return if possible
169 *
170  IF( n.EQ.0 )
171  \$ RETURN
172 *
173 * Check for singularity if non-unit.
174 *
175  IF( nounit ) THEN
176  DO 10 info = 1, n
177  IF( a( info, info ).EQ.zero )
178  \$ RETURN
179  10 CONTINUE
180  info = 0
181  END IF
182 *
183 * Determine the block size for this environment.
184 *
185  nb = ilaenv( 1, 'ZTRTRI', uplo // diag, n, -1, -1, -1 )
186  IF( nb.LE.1 .OR. nb.GE.n ) THEN
187 *
188 * Use unblocked code
189 *
190  CALL ztrti2( uplo, diag, n, a, lda, info )
191  ELSE
192 *
193 * Use blocked code
194 *
195  IF( upper ) THEN
196 *
197 * Compute inverse of upper triangular matrix
198 *
199  DO 20 j = 1, n, nb
200  jb = min( nb, n-j+1 )
201 *
202 * Compute rows 1:j-1 of current block column
203 *
204  CALL ztrmm( 'Left', 'Upper', 'No transpose', diag, j-1,
205  \$ jb, one, a, lda, a( 1, j ), lda )
206  CALL ztrsm( 'Right', 'Upper', 'No transpose', diag, j-1,
207  \$ jb, -one, a( j, j ), lda, a( 1, j ), lda )
208 *
209 * Compute inverse of current diagonal block
210 *
211  CALL ztrti2( 'Upper', diag, jb, a( j, j ), lda, info )
212  20 CONTINUE
213  ELSE
214 *
215 * Compute inverse of lower triangular matrix
216 *
217  nn = ( ( n-1 ) / nb )*nb + 1
218  DO 30 j = nn, 1, -nb
219  jb = min( nb, n-j+1 )
220  IF( j+jb.LE.n ) THEN
221 *
222 * Compute rows j+jb:n of current block column
223 *
224  CALL ztrmm( 'Left', 'Lower', 'No transpose', diag,
225  \$ n-j-jb+1, jb, one, a( j+jb, j+jb ), lda,
226  \$ a( j+jb, j ), lda )
227  CALL ztrsm( 'Right', 'Lower', 'No transpose', diag,
228  \$ n-j-jb+1, jb, -one, a( j, j ), lda,
229  \$ a( j+jb, j ), lda )
230  END IF
231 *
232 * Compute inverse of current diagonal block
233 *
234  CALL ztrti2( 'Lower', diag, jb, a( j, j ), lda, info )
235  30 CONTINUE
236  END IF
237  END IF
238 *
239  RETURN
240 *
241 * End of ZTRTRI
242 *
243  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine ztrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRMM
Definition: ztrmm.f:179
subroutine ztrtri(UPLO, DIAG, N, A, LDA, INFO)
ZTRTRI
Definition: ztrtri.f:111
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:182
subroutine ztrti2(UPLO, DIAG, N, A, LDA, INFO)
ZTRTI2 computes the inverse of a triangular matrix (unblocked algorithm).
Definition: ztrti2.f:112