001:       REAL FUNCTION SLA_PORCOND( UPLO, N, A, LDA, AF, LDAF, CMODE, C,
002:      $                           INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       INTEGER            N, LDA, LDAF, INFO, CMODE
017:       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ),
018:      $                   C( * )
019: *     ..
020: *     .. Array Arguments ..
021:       INTEGER            IWORK( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *     SLA_PORCOND Estimates the Skeel condition number of  op(A) * op2(C)
028: *     where op2 is determined by CMODE as follows
029: *     CMODE =  1    op2(C) = C
030: *     CMODE =  0    op2(C) = I
031: *     CMODE = -1    op2(C) = inv(C)
032: *     The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
033: *     is computed by computing scaling factors R such that
034: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
035: *     infinity-norm condition number.
036: *
037: *  Arguments
038: *  ==========
039: *
040: *     UPLO    (input) CHARACTER*1
041: *       = 'U':  Upper triangle of A is stored;
042: *       = 'L':  Lower triangle of A is stored.
043: *
044: *     N       (input) INTEGER
045: *     The number of linear equations, i.e., the order of the
046: *     matrix A.  N >= 0.
047: *
048: *     A       (input) REAL array, dimension (LDA,N)
049: *     On entry, the N-by-N matrix A.
050: *
051: *     LDA     (input) INTEGER
052: *     The leading dimension of the array A.  LDA >= max(1,N).
053: *
054: *     AF      (input) REAL array, dimension (LDAF,N)
055: *     The triangular factor U or L from the Cholesky factorization
056: *     A = U**T*U or A = L*L**T, as computed by SPOTRF.
057: *
058: *     LDAF    (input) INTEGER
059: *     The leading dimension of the array AF.  LDAF >= max(1,N).
060: *
061: *     CMODE   (input) INTEGER
062: *     Determines op2(C) in the formula op(A) * op2(C) as follows:
063: *     CMODE =  1    op2(C) = C
064: *     CMODE =  0    op2(C) = I
065: *     CMODE = -1    op2(C) = inv(C)
066: *
067: *     C       (input) REAL array, dimension (N)
068: *     The vector C in the formula op(A) * op2(C).
069: *
070: *     INFO    (output) INTEGER
071: *       = 0:  Successful exit.
072: *     i > 0:  The ith argument is invalid.
073: *
074: *     WORK    (input) REAL array, dimension (3*N).
075: *     Workspace.
076: *
077: *     IWORK   (input) INTEGER array, dimension (N).
078: *     Workspace.
079: *
080: *  =====================================================================
081: *
082: *     .. Local Scalars ..
083:       INTEGER            KASE, I, J
084:       REAL               AINVNM, TMP
085:       LOGICAL            UP
086: *     ..
087: *     .. Array Arguments ..
088:       INTEGER            ISAVE( 3 )
089: *     ..
090: *     .. External Functions ..
091:       LOGICAL            LSAME
092:       INTEGER            ISAMAX
093:       EXTERNAL           LSAME, ISAMAX
094: *     ..
095: *     .. External Subroutines ..
096:       EXTERNAL           SLACN2, SPOTRS, XERBLA
097: *     ..
098: *     .. Intrinsic Functions ..
099:       INTRINSIC          ABS, MAX
100: *     ..
101: *     .. Executable Statements ..
102: *
103:       SLA_PORCOND = 0.0
104: *
105:       INFO = 0
106:       IF( N.LT.0 ) THEN
107:          INFO = -2
108:       END IF
109:       IF( INFO.NE.0 ) THEN
110:          CALL XERBLA( 'SLA_PORCOND', -INFO )
111:          RETURN
112:       END IF
113: 
114:       IF( N.EQ.0 ) THEN
115:          SLA_PORCOND = 1.0
116:          RETURN
117:       END IF
118:       UP = .FALSE.
119:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
120: *
121: *     Compute the equilibration matrix R such that
122: *     inv(R)*A*C has unit 1-norm.
123: *
124:       IF ( UP ) THEN
125:          DO I = 1, N
126:             TMP = 0.0
127:             IF ( CMODE .EQ. 1 ) THEN
128:                DO J = 1, I
129:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
130:                END DO
131:                DO J = I+1, N
132:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
133:                END DO
134:             ELSE IF ( CMODE .EQ. 0 ) THEN
135:                DO J = 1, I
136:                   TMP = TMP + ABS( A( J, I ) )
137:                END DO
138:                DO J = I+1, N
139:                   TMP = TMP + ABS( A( I, J ) )
140:                END DO
141:             ELSE
142:                DO J = 1, I
143:                   TMP = TMP + ABS( A( J ,I ) / C( J ) )
144:                END DO
145:                DO J = I+1, N
146:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
147:                END DO
148:             END IF
149:             WORK( 2*N+I ) = TMP
150:          END DO
151:       ELSE
152:          DO I = 1, N
153:             TMP = 0.0
154:             IF ( CMODE .EQ. 1 ) THEN
155:                DO J = 1, I
156:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
157:                END DO
158:                DO J = I+1, N
159:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
160:                END DO
161:             ELSE IF ( CMODE .EQ. 0 ) THEN
162:                DO J = 1, I
163:                   TMP = TMP + ABS( A( I, J ) )
164:                END DO
165:                DO J = I+1, N
166:                   TMP = TMP + ABS( A( J, I ) )
167:                END DO
168:             ELSE
169:                DO J = 1, I
170:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
171:                END DO
172:                DO J = I+1, N
173:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
174:                END DO
175:             END IF
176:             WORK( 2*N+I ) = TMP
177:          END DO
178:       ENDIF
179: *
180: *     Estimate the norm of inv(op(A)).
181: *
182:       AINVNM = 0.0
183: 
184:       KASE = 0
185:    10 CONTINUE
186:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
187:       IF( KASE.NE.0 ) THEN
188:          IF( KASE.EQ.2 ) THEN
189: *
190: *           Multiply by R.
191: *
192:             DO I = 1, N
193:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
194:             END DO
195: 
196:             IF (UP) THEN
197:                CALL SPOTRS( 'Upper', N, 1, AF, LDAF, WORK, N, INFO )
198:             ELSE
199:                CALL SPOTRS( 'Lower', N, 1, AF, LDAF, WORK, N, INFO )
200:             ENDIF
201: *
202: *           Multiply by inv(C).
203: *
204:             IF ( CMODE .EQ. 1 ) THEN
205:                DO I = 1, N
206:                   WORK( I ) = WORK( I ) / C( I )
207:                END DO
208:             ELSE IF ( CMODE .EQ. -1 ) THEN
209:                DO I = 1, N
210:                   WORK( I ) = WORK( I ) * C( I )
211:                END DO
212:             END IF
213:          ELSE
214: *
215: *           Multiply by inv(C').
216: *
217:             IF ( CMODE .EQ. 1 ) THEN
218:                DO I = 1, N
219:                   WORK( I ) = WORK( I ) / C( I )
220:                END DO
221:             ELSE IF ( CMODE .EQ. -1 ) THEN
222:                DO I = 1, N
223:                   WORK( I ) = WORK( I ) * C( I )
224:                END DO
225:             END IF
226: 
227:             IF ( UP ) THEN
228:                CALL SPOTRS( 'Upper', N, 1, AF, LDAF, WORK, N, INFO )
229:             ELSE
230:                CALL SPOTRS( 'Lower', N, 1, AF, LDAF, WORK, N, INFO )
231:             ENDIF
232: *
233: *           Multiply by R.
234: *
235:             DO I = 1, N
236:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
237:             END DO
238:          END IF
239:          GO TO 10
240:       END IF
241: *
242: *     Compute the estimate of the reciprocal condition number.
243: *
244:       IF( AINVNM .NE. 0.0 )
245:      $   SLA_PORCOND = ( 1.0 / AINVNM )
246: *
247:       RETURN
248: *
249:       END
250: