001:       DOUBLE PRECISION FUNCTION DLA_GERCOND ( TRANS, N, A, LDA, AF,
002:      $                                        LDAF, IPIV, CMODE, C,
003:      $                                        INFO, WORK, IWORK )
004: *
005: *     -- LAPACK routine (version 3.2.1)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- April 2009                                                   --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          TRANS
017:       INTEGER            N, LDA, LDAF, INFO, CMODE
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * ), IWORK( * )
021:       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * ),
022:      $                   C( * )
023: *     ..
024: *
025: *  Purpose
026: *  =======
027: *
028: *     DLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
029: *     where op2 is determined by CMODE as follows
030: *     CMODE =  1    op2(C) = C
031: *     CMODE =  0    op2(C) = I
032: *     CMODE = -1    op2(C) = inv(C)
033: *     The Skeel condition number cond(A) = norminf( |inv(A)||A| )
034: *     is computed by computing scaling factors R such that
035: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
036: *     infinity-norm condition number.
037: *
038: *  Arguments
039: *  ==========
040: *
041: *     TRANS   (input) CHARACTER*1
042: *     Specifies the form of the system of equations:
043: *       = 'N':  A * X = B     (No transpose)
044: *       = 'T':  A**T * X = B  (Transpose)
045: *       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
046: *
047: *     N       (input) INTEGER
048: *     The number of linear equations, i.e., the order of the
049: *     matrix A.  N >= 0.
050: *
051: *     A       (input) DOUBLE PRECISION array, dimension (LDA,N)
052: *     On entry, the N-by-N matrix A.
053: *
054: *     LDA     (input) INTEGER
055: *     The leading dimension of the array A.  LDA >= max(1,N).
056: *
057: *     AF      (input) DOUBLE PRECISION array, dimension (LDAF,N)
058: *     The factors L and U from the factorization
059: *     A = P*L*U as computed by DGETRF.
060: *
061: *     LDAF    (input) INTEGER
062: *     The leading dimension of the array AF.  LDAF >= max(1,N).
063: *
064: *     IPIV    (input) INTEGER array, dimension (N)
065: *     The pivot indices from the factorization A = P*L*U
066: *     as computed by DGETRF; row i of the matrix was interchanged
067: *     with row IPIV(i).
068: *
069: *     CMODE   (input) INTEGER
070: *     Determines op2(C) in the formula op(A) * op2(C) as follows:
071: *     CMODE =  1    op2(C) = C
072: *     CMODE =  0    op2(C) = I
073: *     CMODE = -1    op2(C) = inv(C)
074: *
075: *     C       (input) DOUBLE PRECISION array, dimension (N)
076: *     The vector C in the formula op(A) * op2(C).
077: *
078: *     INFO    (output) INTEGER
079: *       = 0:  Successful exit.
080: *     i > 0:  The ith argument is invalid.
081: *
082: *     WORK    (input) DOUBLE PRECISION array, dimension (3*N).
083: *     Workspace.
084: *
085: *     IWORK   (input) INTEGER array, dimension (N).
086: *     Workspace.
087: *
088: *  =====================================================================
089: *
090: *     .. Local Scalars ..
091:       LOGICAL            NOTRANS
092:       INTEGER            KASE, I, J
093:       DOUBLE PRECISION   AINVNM, TMP
094: *     ..
095: *     .. Local Arrays ..
096:       INTEGER            ISAVE( 3 )
097: *     ..
098: *     .. External Functions ..
099:       LOGICAL            LSAME
100:       EXTERNAL           LSAME
101: *     ..
102: *     .. External Subroutines ..
103:       EXTERNAL           DLACN2, DGETRS, XERBLA
104: *     ..
105: *     .. Intrinsic Functions ..
106:       INTRINSIC          ABS, MAX
107: *     ..
108: *     .. Executable Statements ..
109: *
110:       DLA_GERCOND = 0.0D+0
111: *
112:       INFO = 0
113:       NOTRANS = LSAME( TRANS, 'N' )
114:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
115:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
116:          INFO = -1
117:       ELSE IF( N.LT.0 ) THEN
118:          INFO = -2
119:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
120:          INFO = -4
121:       ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
122:          INFO = -6
123:       END IF
124:       IF( INFO.NE.0 ) THEN
125:          CALL XERBLA( 'DLA_GERCOND', -INFO )
126:          RETURN
127:       END IF
128:       IF( N.EQ.0 ) THEN
129:          DLA_GERCOND = 1.0D+0
130:          RETURN
131:       END IF
132: *
133: *     Compute the equilibration matrix R such that
134: *     inv(R)*A*C has unit 1-norm.
135: *
136:       IF (NOTRANS) THEN
137:          DO I = 1, N
138:             TMP = 0.0D+0
139:             IF ( CMODE .EQ. 1 ) THEN
140:                DO J = 1, N
141:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
142:                END DO
143:             ELSE IF ( CMODE .EQ. 0 ) THEN
144:                DO J = 1, N
145:                   TMP = TMP + ABS( A( I, J ) )
146:                END DO
147:             ELSE
148:                DO J = 1, N
149:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
150:                END DO
151:             END IF
152:             WORK( 2*N+I ) = TMP
153:          END DO
154:       ELSE
155:          DO I = 1, N
156:             TMP = 0.0D+0
157:             IF ( CMODE .EQ. 1 ) THEN
158:                DO J = 1, N
159:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
160:                END DO
161:             ELSE IF ( CMODE .EQ. 0 ) THEN
162:                DO J = 1, N
163:                   TMP = TMP + ABS( A( J, I ) )
164:                END DO
165:             ELSE
166:                DO J = 1, N
167:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
168:                END DO
169:             END IF
170:             WORK( 2*N+I ) = TMP
171:          END DO
172:       END IF
173: *
174: *     Estimate the norm of inv(op(A)).
175: *
176:       AINVNM = 0.0D+0
177: 
178:       KASE = 0
179:    10 CONTINUE
180:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
181:       IF( KASE.NE.0 ) THEN
182:          IF( KASE.EQ.2 ) THEN
183: *
184: *           Multiply by R.
185: *
186:             DO I = 1, N
187:                WORK(I) = WORK(I) * WORK(2*N+I)
188:             END DO
189: 
190:             IF (NOTRANS) THEN
191:                CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
192:      $            WORK, N, INFO )
193:             ELSE
194:                CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
195:      $            WORK, N, INFO )
196:             END IF
197: *
198: *           Multiply by inv(C).
199: *
200:             IF ( CMODE .EQ. 1 ) THEN
201:                DO I = 1, N
202:                   WORK( I ) = WORK( I ) / C( I )
203:                END DO
204:             ELSE IF ( CMODE .EQ. -1 ) THEN
205:                DO I = 1, N
206:                   WORK( I ) = WORK( I ) * C( I )
207:                END DO
208:             END IF
209:          ELSE
210: *
211: *           Multiply by inv(C').
212: *
213:             IF ( CMODE .EQ. 1 ) THEN
214:                DO I = 1, N
215:                   WORK( I ) = WORK( I ) / C( I )
216:                END DO
217:             ELSE IF ( CMODE .EQ. -1 ) THEN
218:                DO I = 1, N
219:                   WORK( I ) = WORK( I ) * C( I )
220:                END DO
221:             END IF
222: 
223:             IF (NOTRANS) THEN
224:                CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
225:      $            WORK, N, INFO )
226:             ELSE
227:                CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
228:      $            WORK, N, INFO )
229:             END IF
230: *
231: *           Multiply by R.
232: *
233:             DO I = 1, N
234:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
235:             END DO
236:          END IF
237:          GO TO 10
238:       END IF
239: *
240: *     Compute the estimate of the reciprocal condition number.
241: *
242:       IF( AINVNM .NE. 0.0D+0 )
243:      $   DLA_GERCOND = ( 1.0D+0 / AINVNM )
244: *
245:       RETURN
246: *
247:       END
248: