001:       REAL FUNCTION CLA_HERCOND_X( UPLO, N, A, LDA, AF, LDAF, IPIV, X,
002:      $                             INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       INTEGER            N, LDA, LDAF, INFO
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IPIV( * )
020:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
021:       REAL               RWORK( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *     CLA_HERCOND_X computes the infinity norm condition number of
028: *     op(A) * diag(X) where X is a COMPLEX vector.
029: *
030: *  Arguments
031: *  =========
032: *
033: *     UPLO    (input) CHARACTER*1
034: *       = 'U':  Upper triangle of A is stored;
035: *       = 'L':  Lower triangle of A is stored.
036: *
037: *     N       (input) INTEGER
038: *     The number of linear equations, i.e., the order of the
039: *     matrix A.  N >= 0.
040: *
041: *     A       (input) COMPLEX array, dimension (LDA,N)
042: *     On entry, the N-by-N matrix A.
043: *
044: *     LDA     (input) INTEGER
045: *     The leading dimension of the array A.  LDA >= max(1,N).
046: *
047: *     AF      (input) COMPLEX array, dimension (LDAF,N)
048: *     The block diagonal matrix D and the multipliers used to
049: *     obtain the factor U or L as computed by CHETRF.
050: *
051: *     LDAF    (input) INTEGER
052: *     The leading dimension of the array AF.  LDAF >= max(1,N).
053: *
054: *     IPIV    (input) INTEGER array, dimension (N)
055: *     Details of the interchanges and the block structure of D
056: *     as determined by CHETRF.
057: *
058: *     X       (input) COMPLEX array, dimension (N)
059: *     The vector X in the formula op(A) * diag(X).
060: *
061: *     INFO    (output) INTEGER
062: *       = 0:  Successful exit.
063: *     i > 0:  The ith argument is invalid.
064: *
065: *     WORK    (input) COMPLEX array, dimension (2*N).
066: *     Workspace.
067: *
068: *     RWORK   (input) REAL array, dimension (N).
069: *     Workspace.
070: *
071: *  =====================================================================
072: *
073: *     .. Local Scalars ..
074:       INTEGER            KASE, I, J
075:       REAL               AINVNM, ANORM, TMP
076:       LOGICAL            UP
077:       COMPLEX            ZDUM
078: *     ..
079: *     .. Local Arrays ..
080:       INTEGER            ISAVE( 3 )
081: *     ..
082: *     .. External Functions ..
083:       LOGICAL            LSAME
084:       EXTERNAL           LSAME
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           CLACN2, CHETRS, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          ABS, MAX
091: *     ..
092: *     .. Statement Functions ..
093:       REAL CABS1
094: *     ..
095: *     .. Statement Function Definitions ..
096:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
097: *     ..
098: *     .. Executable Statements ..
099: *
100:       CLA_HERCOND_X = 0.0E+0
101: *
102:       INFO = 0
103:       IF( N.LT.0 ) THEN
104:          INFO = -2
105:       END IF
106:       IF( INFO.NE.0 ) THEN
107:          CALL XERBLA( 'CLA_HERCOND_X', -INFO )
108:          RETURN
109:       END IF
110:       UP = .FALSE.
111:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
112: *
113: *     Compute norm of op(A)*op2(C).
114: *
115:       ANORM = 0.0
116:       IF ( UP ) THEN
117:          DO I = 1, N
118:             TMP = 0.0E+0
119:             DO J = 1, I
120:                TMP = TMP + CABS1( A( J, I ) * X( J ) )
121:             END DO
122:             DO J = I+1, N
123:                TMP = TMP + CABS1( A( I, J ) * X( J ) )
124:             END DO
125:             RWORK( I ) = TMP
126:             ANORM = MAX( ANORM, TMP )
127:          END DO
128:       ELSE
129:          DO I = 1, N
130:             TMP = 0.0E+0
131:             DO J = 1, I
132:                TMP = TMP + CABS1( A( I, J ) * X( J ) )
133:             END DO
134:             DO J = I+1, N
135:                TMP = TMP + CABS1( A( J, I ) * X( J ) )
136:             END DO
137:             RWORK( I ) = TMP
138:             ANORM = MAX( ANORM, TMP )
139:          END DO
140:       END IF
141: *
142: *     Quick return if possible.
143: *
144:       IF( N.EQ.0 ) THEN
145:          CLA_HERCOND_X = 1.0E+0
146:          RETURN
147:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
148:          RETURN
149:       END IF
150: *
151: *     Estimate the norm of inv(op(A)).
152: *
153:       AINVNM = 0.0E+0
154: *
155:       KASE = 0
156:    10 CONTINUE
157:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
158:       IF( KASE.NE.0 ) THEN
159:          IF( KASE.EQ.2 ) THEN
160: *
161: *           Multiply by R.
162: *
163:             DO I = 1, N
164:                WORK( I ) = WORK( I ) * RWORK( I )
165:             END DO
166: *
167:             IF ( UP ) THEN
168:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
169:      $            WORK, N, INFO )
170:             ELSE
171:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
172:      $            WORK, N, INFO )
173:             ENDIF
174: *
175: *           Multiply by inv(X).
176: *
177:             DO I = 1, N
178:                WORK( I ) = WORK( I ) / X( I )
179:             END DO
180:          ELSE
181: *
182: *           Multiply by inv(X').
183: *
184:             DO I = 1, N
185:                WORK( I ) = WORK( I ) / X( I )
186:             END DO
187: *
188:             IF ( UP ) THEN
189:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
190:      $            WORK, N, INFO )
191:             ELSE
192:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
193:      $            WORK, N, INFO )
194:             END IF
195: *
196: *           Multiply by R.
197: *
198:             DO I = 1, N
199:                WORK( I ) = WORK( I ) * RWORK( I )
200:             END DO
201:          END IF
202:          GO TO 10
203:       END IF
204: *
205: *     Compute the estimate of the reciprocal condition number.
206: *
207:       IF( AINVNM .NE. 0.0E+0 )
208:      $   CLA_HERCOND_X = 1.0E+0 / AINVNM
209: *
210:       RETURN
211: *
212:       END
213: