001:       DOUBLE PRECISION FUNCTION DLANGB( NORM, N, KL, KU, AB, LDAB,
002:      $                 WORK )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          NORM
010:       INTEGER            KL, KU, LDAB, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DLANGB  returns the value of the one norm,  or the Frobenius norm, or
020: *  the  infinity norm,  or the element of  largest absolute value  of an
021: *  n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
022: *
023: *  Description
024: *  ===========
025: *
026: *  DLANGB returns the value
027: *
028: *     DLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
029: *              (
030: *              ( norm1(A),         NORM = '1', 'O' or 'o'
031: *              (
032: *              ( normI(A),         NORM = 'I' or 'i'
033: *              (
034: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
035: *
036: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
037: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
038: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
039: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
040: *
041: *  Arguments
042: *  =========
043: *
044: *  NORM    (input) CHARACTER*1
045: *          Specifies the value to be returned in DLANGB as described
046: *          above.
047: *
048: *  N       (input) INTEGER
049: *          The order of the matrix A.  N >= 0.  When N = 0, DLANGB is
050: *          set to zero.
051: *
052: *  KL      (input) INTEGER
053: *          The number of sub-diagonals of the matrix A.  KL >= 0.
054: *
055: *  KU      (input) INTEGER
056: *          The number of super-diagonals of the matrix A.  KU >= 0.
057: *
058: *  AB      (input) DOUBLE PRECISION array, dimension (LDAB,N)
059: *          The band matrix A, stored in rows 1 to KL+KU+1.  The j-th
060: *          column of A is stored in the j-th column of the array AB as
061: *          follows:
062: *          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
063: *
064: *  LDAB    (input) INTEGER
065: *          The leading dimension of the array AB.  LDAB >= KL+KU+1.
066: *
067: *  WORK    (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
068: *          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
069: *          referenced.
070: *
071: * =====================================================================
072: *
073: *
074: *     .. Parameters ..
075:       DOUBLE PRECISION   ONE, ZERO
076:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
077: *     ..
078: *     .. Local Scalars ..
079:       INTEGER            I, J, K, L
080:       DOUBLE PRECISION   SCALE, SUM, VALUE
081: *     ..
082: *     .. External Subroutines ..
083:       EXTERNAL           DLASSQ
084: *     ..
085: *     .. External Functions ..
086:       LOGICAL            LSAME
087:       EXTERNAL           LSAME
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          ABS, MAX, MIN, SQRT
091: *     ..
092: *     .. Executable Statements ..
093: *
094:       IF( N.EQ.0 ) THEN
095:          VALUE = ZERO
096:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
097: *
098: *        Find max(abs(A(i,j))).
099: *
100:          VALUE = ZERO
101:          DO 20 J = 1, N
102:             DO 10 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
103:                VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
104:    10       CONTINUE
105:    20    CONTINUE
106:       ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
107: *
108: *        Find norm1(A).
109: *
110:          VALUE = ZERO
111:          DO 40 J = 1, N
112:             SUM = ZERO
113:             DO 30 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
114:                SUM = SUM + ABS( AB( I, J ) )
115:    30       CONTINUE
116:             VALUE = MAX( VALUE, SUM )
117:    40    CONTINUE
118:       ELSE IF( LSAME( NORM, 'I' ) ) THEN
119: *
120: *        Find normI(A).
121: *
122:          DO 50 I = 1, N
123:             WORK( I ) = ZERO
124:    50    CONTINUE
125:          DO 70 J = 1, N
126:             K = KU + 1 - J
127:             DO 60 I = MAX( 1, J-KU ), MIN( N, J+KL )
128:                WORK( I ) = WORK( I ) + ABS( AB( K+I, J ) )
129:    60       CONTINUE
130:    70    CONTINUE
131:          VALUE = ZERO
132:          DO 80 I = 1, N
133:             VALUE = MAX( VALUE, WORK( I ) )
134:    80    CONTINUE
135:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
136: *
137: *        Find normF(A).
138: *
139:          SCALE = ZERO
140:          SUM = ONE
141:          DO 90 J = 1, N
142:             L = MAX( 1, J-KU )
143:             K = KU + 1 - J + L
144:             CALL DLASSQ( MIN( N, J+KL )-L+1, AB( K, J ), 1, SCALE, SUM )
145:    90    CONTINUE
146:          VALUE = SCALE*SQRT( SUM )
147:       END IF
148: *
149:       DLANGB = VALUE
150:       RETURN
151: *
152: *     End of DLANGB
153: *
154:       END
155: