LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
dorg2r.f
Go to the documentation of this file.
1 *> \brief \b DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf (unblocked algorithm).
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DORG2R + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorg2r.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorg2r.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorg2r.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DORG2R( M, N, K, A, LDA, TAU, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, K, LDA, M, N
25 * ..
26 * .. Array Arguments ..
27 * DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
28 * ..
29 *
30 *
31 *> \par Purpose:
32 * =============
33 *>
34 *> \verbatim
35 *>
36 *> DORG2R generates an m by n real matrix Q with orthonormal columns,
37 *> which is defined as the first n columns of a product of k elementary
38 *> reflectors of order m
39 *>
40 *> Q = H(1) H(2) . . . H(k)
41 *>
42 *> as returned by DGEQRF.
43 *> \endverbatim
44 *
45 * Arguments:
46 * ==========
47 *
48 *> \param[in] M
49 *> \verbatim
50 *> M is INTEGER
51 *> The number of rows of the matrix Q. M >= 0.
52 *> \endverbatim
53 *>
54 *> \param[in] N
55 *> \verbatim
56 *> N is INTEGER
57 *> The number of columns of the matrix Q. M >= N >= 0.
58 *> \endverbatim
59 *>
60 *> \param[in] K
61 *> \verbatim
62 *> K is INTEGER
63 *> The number of elementary reflectors whose product defines the
64 *> matrix Q. N >= K >= 0.
65 *> \endverbatim
66 *>
67 *> \param[in,out] A
68 *> \verbatim
69 *> A is DOUBLE PRECISION array, dimension (LDA,N)
70 *> On entry, the i-th column must contain the vector which
71 *> defines the elementary reflector H(i), for i = 1,2,...,k, as
72 *> returned by DGEQRF in the first k columns of its array
73 *> argument A.
74 *> On exit, the m-by-n matrix Q.
75 *> \endverbatim
76 *>
77 *> \param[in] LDA
78 *> \verbatim
79 *> LDA is INTEGER
80 *> The first dimension of the array A. LDA >= max(1,M).
81 *> \endverbatim
82 *>
83 *> \param[in] TAU
84 *> \verbatim
85 *> TAU is DOUBLE PRECISION array, dimension (K)
86 *> TAU(i) must contain the scalar factor of the elementary
87 *> reflector H(i), as returned by DGEQRF.
88 *> \endverbatim
89 *>
90 *> \param[out] WORK
91 *> \verbatim
92 *> WORK is DOUBLE PRECISION array, dimension (N)
93 *> \endverbatim
94 *>
95 *> \param[out] INFO
96 *> \verbatim
97 *> INFO is INTEGER
98 *> = 0: successful exit
99 *> < 0: if INFO = -i, the i-th argument has an illegal value
100 *> \endverbatim
101 *
102 * Authors:
103 * ========
104 *
105 *> \author Univ. of Tennessee
106 *> \author Univ. of California Berkeley
107 *> \author Univ. of Colorado Denver
108 *> \author NAG Ltd.
109 *
110 *> \date December 2016
111 *
112 *> \ingroup doubleOTHERcomputational
113 *
114 * =====================================================================
115  SUBROUTINE dorg2r( M, N, K, A, LDA, TAU, WORK, INFO )
116 *
117 * -- LAPACK computational routine (version 3.7.0) --
118 * -- LAPACK is a software package provided by Univ. of Tennessee, --
119 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120 * December 2016
121 *
122 * .. Scalar Arguments ..
123  INTEGER INFO, K, LDA, M, N
124 * ..
125 * .. Array Arguments ..
126  DOUBLE PRECISION A( lda, * ), TAU( * ), WORK( * )
127 * ..
128 *
129 * =====================================================================
130 *
131 * .. Parameters ..
132  DOUBLE PRECISION ONE, ZERO
133  parameter( one = 1.0d+0, zero = 0.0d+0 )
134 * ..
135 * .. Local Scalars ..
136  INTEGER I, J, L
137 * ..
138 * .. External Subroutines ..
139  EXTERNAL dlarf, dscal, xerbla
140 * ..
141 * .. Intrinsic Functions ..
142  INTRINSIC max
143 * ..
144 * .. Executable Statements ..
145 *
146 * Test the input arguments
147 *
148  info = 0
149  IF( m.LT.0 ) THEN
150  info = -1
151  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
152  info = -2
153  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
154  info = -3
155  ELSE IF( lda.LT.max( 1, m ) ) THEN
156  info = -5
157  END IF
158  IF( info.NE.0 ) THEN
159  CALL xerbla( 'DORG2R', -info )
160  RETURN
161  END IF
162 *
163 * Quick return if possible
164 *
165  IF( n.LE.0 )
166  $ RETURN
167 *
168 * Initialise columns k+1:n to columns of the unit matrix
169 *
170  DO 20 j = k + 1, n
171  DO 10 l = 1, m
172  a( l, j ) = zero
173  10 CONTINUE
174  a( j, j ) = one
175  20 CONTINUE
176 *
177  DO 40 i = k, 1, -1
178 *
179 * Apply H(i) to A(i:m,i:n) from the left
180 *
181  IF( i.LT.n ) THEN
182  a( i, i ) = one
183  CALL dlarf( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
184  $ a( i, i+1 ), lda, work )
185  END IF
186  IF( i.LT.m )
187  $ CALL dscal( m-i, -tau( i ), a( i+1, i ), 1 )
188  a( i, i ) = one - tau( i )
189 *
190 * Set A(1:i-1,i) to zero
191 *
192  DO 30 l = 1, i - 1
193  a( l, i ) = zero
194  30 CONTINUE
195  40 CONTINUE
196  RETURN
197 *
198 * End of DORG2R
199 *
200  END
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
subroutine dorg2r(M, N, K, A, LDA, TAU, WORK, INFO)
DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf ...
Definition: dorg2r.f:116
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:81