LAPACK  3.7.1
LAPACK: Linear Algebra PACKage
cla_gbrfsx_extended.f
Go to the documentation of this file.
1 *> \brief \b CLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CLA_GBRFSX_EXTENDED + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_gbrfsx_extended.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_gbrfsx_extended.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_gbrfsx_extended.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CLA_GBRFSX_EXTENDED ( PREC_TYPE, TRANS_TYPE, N, KL, KU,
22 * NRHS, AB, LDAB, AFB, LDAFB, IPIV,
23 * COLEQU, C, B, LDB, Y, LDY,
24 * BERR_OUT, N_NORMS, ERR_BNDS_NORM,
25 * ERR_BNDS_COMP, RES, AYB, DY,
26 * Y_TAIL, RCOND, ITHRESH, RTHRESH,
27 * DZ_UB, IGNORE_CWISE, INFO )
28 *
29 * .. Scalar Arguments ..
30 * INTEGER INFO, LDAB, LDAFB, LDB, LDY, N, KL, KU, NRHS,
31 * $ PREC_TYPE, TRANS_TYPE, N_NORMS, ITHRESH
32 * LOGICAL COLEQU, IGNORE_CWISE
33 * REAL RTHRESH, DZ_UB
34 * ..
35 * .. Array Arguments ..
36 * INTEGER IPIV( * )
37 * COMPLEX AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
38 * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
39 * REAL C( * ), AYB(*), RCOND, BERR_OUT( * ),
40 * $ ERR_BNDS_NORM( NRHS, * ),
41 * $ ERR_BNDS_COMP( NRHS, * )
42 * ..
43 *
44 *
45 *> \par Purpose:
46 * =============
47 *>
48 *> \verbatim
49 *>
50 *> CLA_GBRFSX_EXTENDED improves the computed solution to a system of
51 *> linear equations by performing extra-precise iterative refinement
52 *> and provides error bounds and backward error estimates for the solution.
53 *> This subroutine is called by CGBRFSX to perform iterative refinement.
54 *> In addition to normwise error bound, the code provides maximum
55 *> componentwise error bound if possible. See comments for ERR_BNDS_NORM
56 *> and ERR_BNDS_COMP for details of the error bounds. Note that this
57 *> subroutine is only resonsible for setting the second fields of
58 *> ERR_BNDS_NORM and ERR_BNDS_COMP.
59 *> \endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] PREC_TYPE
65 *> \verbatim
66 *> PREC_TYPE is INTEGER
67 *> Specifies the intermediate precision to be used in refinement.
68 *> The value is defined by ILAPREC(P) where P is a CHARACTER and
69 *> P = 'S': Single
70 *> = 'D': Double
71 *> = 'I': Indigenous
72 *> = 'X', 'E': Extra
73 *> \endverbatim
74 *>
75 *> \param[in] TRANS_TYPE
76 *> \verbatim
77 *> TRANS_TYPE is INTEGER
78 *> Specifies the transposition operation on A.
79 *> The value is defined by ILATRANS(T) where T is a CHARACTER and
80 *> T = 'N': No transpose
81 *> = 'T': Transpose
82 *> = 'C': Conjugate transpose
83 *> \endverbatim
84 *>
85 *> \param[in] N
86 *> \verbatim
87 *> N is INTEGER
88 *> The number of linear equations, i.e., the order of the
89 *> matrix A. N >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] KL
93 *> \verbatim
94 *> KL is INTEGER
95 *> The number of subdiagonals within the band of A. KL >= 0.
96 *> \endverbatim
97 *>
98 *> \param[in] KU
99 *> \verbatim
100 *> KU is INTEGER
101 *> The number of superdiagonals within the band of A. KU >= 0
102 *> \endverbatim
103 *>
104 *> \param[in] NRHS
105 *> \verbatim
106 *> NRHS is INTEGER
107 *> The number of right-hand-sides, i.e., the number of columns of the
108 *> matrix B.
109 *> \endverbatim
110 *>
111 *> \param[in] AB
112 *> \verbatim
113 *> AB is COMPLEX array, dimension (LDAB,N)
114 *> On entry, the N-by-N matrix AB.
115 *> \endverbatim
116 *>
117 *> \param[in] LDAB
118 *> \verbatim
119 *> LDAB is INTEGER
120 *> The leading dimension of the array AB. LDAB >= max(1,N).
121 *> \endverbatim
122 *>
123 *> \param[in] AFB
124 *> \verbatim
125 *> AFB is COMPLEX array, dimension (LDAF,N)
126 *> The factors L and U from the factorization
127 *> A = P*L*U as computed by CGBTRF.
128 *> \endverbatim
129 *>
130 *> \param[in] LDAFB
131 *> \verbatim
132 *> LDAFB is INTEGER
133 *> The leading dimension of the array AF. LDAF >= max(1,N).
134 *> \endverbatim
135 *>
136 *> \param[in] IPIV
137 *> \verbatim
138 *> IPIV is INTEGER array, dimension (N)
139 *> The pivot indices from the factorization A = P*L*U
140 *> as computed by CGBTRF; row i of the matrix was interchanged
141 *> with row IPIV(i).
142 *> \endverbatim
143 *>
144 *> \param[in] COLEQU
145 *> \verbatim
146 *> COLEQU is LOGICAL
147 *> If .TRUE. then column equilibration was done to A before calling
148 *> this routine. This is needed to compute the solution and error
149 *> bounds correctly.
150 *> \endverbatim
151 *>
152 *> \param[in] C
153 *> \verbatim
154 *> C is REAL array, dimension (N)
155 *> The column scale factors for A. If COLEQU = .FALSE., C
156 *> is not accessed. If C is input, each element of C should be a power
157 *> of the radix to ensure a reliable solution and error estimates.
158 *> Scaling by powers of the radix does not cause rounding errors unless
159 *> the result underflows or overflows. Rounding errors during scaling
160 *> lead to refining with a matrix that is not equivalent to the
161 *> input matrix, producing error estimates that may not be
162 *> reliable.
163 *> \endverbatim
164 *>
165 *> \param[in] B
166 *> \verbatim
167 *> B is COMPLEX array, dimension (LDB,NRHS)
168 *> The right-hand-side matrix B.
169 *> \endverbatim
170 *>
171 *> \param[in] LDB
172 *> \verbatim
173 *> LDB is INTEGER
174 *> The leading dimension of the array B. LDB >= max(1,N).
175 *> \endverbatim
176 *>
177 *> \param[in,out] Y
178 *> \verbatim
179 *> Y is COMPLEX array, dimension (LDY,NRHS)
180 *> On entry, the solution matrix X, as computed by CGBTRS.
181 *> On exit, the improved solution matrix Y.
182 *> \endverbatim
183 *>
184 *> \param[in] LDY
185 *> \verbatim
186 *> LDY is INTEGER
187 *> The leading dimension of the array Y. LDY >= max(1,N).
188 *> \endverbatim
189 *>
190 *> \param[out] BERR_OUT
191 *> \verbatim
192 *> BERR_OUT is REAL array, dimension (NRHS)
193 *> On exit, BERR_OUT(j) contains the componentwise relative backward
194 *> error for right-hand-side j from the formula
195 *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
196 *> where abs(Z) is the componentwise absolute value of the matrix
197 *> or vector Z. This is computed by CLA_LIN_BERR.
198 *> \endverbatim
199 *>
200 *> \param[in] N_NORMS
201 *> \verbatim
202 *> N_NORMS is INTEGER
203 *> Determines which error bounds to return (see ERR_BNDS_NORM
204 *> and ERR_BNDS_COMP).
205 *> If N_NORMS >= 1 return normwise error bounds.
206 *> If N_NORMS >= 2 return componentwise error bounds.
207 *> \endverbatim
208 *>
209 *> \param[in,out] ERR_BNDS_NORM
210 *> \verbatim
211 *> ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
212 *> For each right-hand side, this array contains information about
213 *> various error bounds and condition numbers corresponding to the
214 *> normwise relative error, which is defined as follows:
215 *>
216 *> Normwise relative error in the ith solution vector:
217 *> max_j (abs(XTRUE(j,i) - X(j,i)))
218 *> ------------------------------
219 *> max_j abs(X(j,i))
220 *>
221 *> The array is indexed by the type of error information as described
222 *> below. There currently are up to three pieces of information
223 *> returned.
224 *>
225 *> The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
226 *> right-hand side.
227 *>
228 *> The second index in ERR_BNDS_NORM(:,err) contains the following
229 *> three fields:
230 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
231 *> reciprocal condition number is less than the threshold
232 *> sqrt(n) * slamch('Epsilon').
233 *>
234 *> err = 2 "Guaranteed" error bound: The estimated forward error,
235 *> almost certainly within a factor of 10 of the true error
236 *> so long as the next entry is greater than the threshold
237 *> sqrt(n) * slamch('Epsilon'). This error bound should only
238 *> be trusted if the previous boolean is true.
239 *>
240 *> err = 3 Reciprocal condition number: Estimated normwise
241 *> reciprocal condition number. Compared with the threshold
242 *> sqrt(n) * slamch('Epsilon') to determine if the error
243 *> estimate is "guaranteed". These reciprocal condition
244 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
245 *> appropriately scaled matrix Z.
246 *> Let Z = S*A, where S scales each row by a power of the
247 *> radix so all absolute row sums of Z are approximately 1.
248 *>
249 *> This subroutine is only responsible for setting the second field
250 *> above.
251 *> See Lapack Working Note 165 for further details and extra
252 *> cautions.
253 *> \endverbatim
254 *>
255 *> \param[in,out] ERR_BNDS_COMP
256 *> \verbatim
257 *> ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
258 *> For each right-hand side, this array contains information about
259 *> various error bounds and condition numbers corresponding to the
260 *> componentwise relative error, which is defined as follows:
261 *>
262 *> Componentwise relative error in the ith solution vector:
263 *> abs(XTRUE(j,i) - X(j,i))
264 *> max_j ----------------------
265 *> abs(X(j,i))
266 *>
267 *> The array is indexed by the right-hand side i (on which the
268 *> componentwise relative error depends), and the type of error
269 *> information as described below. There currently are up to three
270 *> pieces of information returned for each right-hand side. If
271 *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
272 *> ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
273 *> the first (:,N_ERR_BNDS) entries are returned.
274 *>
275 *> The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
276 *> right-hand side.
277 *>
278 *> The second index in ERR_BNDS_COMP(:,err) contains the following
279 *> three fields:
280 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
281 *> reciprocal condition number is less than the threshold
282 *> sqrt(n) * slamch('Epsilon').
283 *>
284 *> err = 2 "Guaranteed" error bound: The estimated forward error,
285 *> almost certainly within a factor of 10 of the true error
286 *> so long as the next entry is greater than the threshold
287 *> sqrt(n) * slamch('Epsilon'). This error bound should only
288 *> be trusted if the previous boolean is true.
289 *>
290 *> err = 3 Reciprocal condition number: Estimated componentwise
291 *> reciprocal condition number. Compared with the threshold
292 *> sqrt(n) * slamch('Epsilon') to determine if the error
293 *> estimate is "guaranteed". These reciprocal condition
294 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
295 *> appropriately scaled matrix Z.
296 *> Let Z = S*(A*diag(x)), where x is the solution for the
297 *> current right-hand side and S scales each row of
298 *> A*diag(x) by a power of the radix so all absolute row
299 *> sums of Z are approximately 1.
300 *>
301 *> This subroutine is only responsible for setting the second field
302 *> above.
303 *> See Lapack Working Note 165 for further details and extra
304 *> cautions.
305 *> \endverbatim
306 *>
307 *> \param[in] RES
308 *> \verbatim
309 *> RES is COMPLEX array, dimension (N)
310 *> Workspace to hold the intermediate residual.
311 *> \endverbatim
312 *>
313 *> \param[in] AYB
314 *> \verbatim
315 *> AYB is REAL array, dimension (N)
316 *> Workspace.
317 *> \endverbatim
318 *>
319 *> \param[in] DY
320 *> \verbatim
321 *> DY is COMPLEX array, dimension (N)
322 *> Workspace to hold the intermediate solution.
323 *> \endverbatim
324 *>
325 *> \param[in] Y_TAIL
326 *> \verbatim
327 *> Y_TAIL is COMPLEX array, dimension (N)
328 *> Workspace to hold the trailing bits of the intermediate solution.
329 *> \endverbatim
330 *>
331 *> \param[in] RCOND
332 *> \verbatim
333 *> RCOND is REAL
334 *> Reciprocal scaled condition number. This is an estimate of the
335 *> reciprocal Skeel condition number of the matrix A after
336 *> equilibration (if done). If this is less than the machine
337 *> precision (in particular, if it is zero), the matrix is singular
338 *> to working precision. Note that the error may still be small even
339 *> if this number is very small and the matrix appears ill-
340 *> conditioned.
341 *> \endverbatim
342 *>
343 *> \param[in] ITHRESH
344 *> \verbatim
345 *> ITHRESH is INTEGER
346 *> The maximum number of residual computations allowed for
347 *> refinement. The default is 10. For 'aggressive' set to 100 to
348 *> permit convergence using approximate factorizations or
349 *> factorizations other than LU. If the factorization uses a
350 *> technique other than Gaussian elimination, the guarantees in
351 *> ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
352 *> \endverbatim
353 *>
354 *> \param[in] RTHRESH
355 *> \verbatim
356 *> RTHRESH is REAL
357 *> Determines when to stop refinement if the error estimate stops
358 *> decreasing. Refinement will stop when the next solution no longer
359 *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
360 *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
361 *> default value is 0.5. For 'aggressive' set to 0.9 to permit
362 *> convergence on extremely ill-conditioned matrices. See LAWN 165
363 *> for more details.
364 *> \endverbatim
365 *>
366 *> \param[in] DZ_UB
367 *> \verbatim
368 *> DZ_UB is REAL
369 *> Determines when to start considering componentwise convergence.
370 *> Componentwise convergence is only considered after each component
371 *> of the solution Y is stable, which we definte as the relative
372 *> change in each component being less than DZ_UB. The default value
373 *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
374 *> more details.
375 *> \endverbatim
376 *>
377 *> \param[in] IGNORE_CWISE
378 *> \verbatim
379 *> IGNORE_CWISE is LOGICAL
380 *> If .TRUE. then ignore componentwise convergence. Default value
381 *> is .FALSE..
382 *> \endverbatim
383 *>
384 *> \param[out] INFO
385 *> \verbatim
386 *> INFO is INTEGER
387 *> = 0: Successful exit.
388 *> < 0: if INFO = -i, the ith argument to CGBTRS had an illegal
389 *> value
390 *> \endverbatim
391 *
392 * Authors:
393 * ========
394 *
395 *> \author Univ. of Tennessee
396 *> \author Univ. of California Berkeley
397 *> \author Univ. of Colorado Denver
398 *> \author NAG Ltd.
399 *
400 *> \date June 2017
401 *
402 *> \ingroup complexGBcomputational
403 *
404 * =====================================================================
405  SUBROUTINE cla_gbrfsx_extended ( PREC_TYPE, TRANS_TYPE, N, KL, KU,
406  $ NRHS, AB, LDAB, AFB, LDAFB, IPIV,
407  $ COLEQU, C, B, LDB, Y, LDY,
408  $ BERR_OUT, N_NORMS, ERR_BNDS_NORM,
409  $ ERR_BNDS_COMP, RES, AYB, DY,
410  $ Y_TAIL, RCOND, ITHRESH, RTHRESH,
411  $ DZ_UB, IGNORE_CWISE, INFO )
412 *
413 * -- LAPACK computational routine (version 3.7.1) --
414 * -- LAPACK is a software package provided by Univ. of Tennessee, --
415 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
416 * June 2017
417 *
418 * .. Scalar Arguments ..
419  INTEGER INFO, LDAB, LDAFB, LDB, LDY, N, KL, KU, NRHS,
420  $ prec_type, trans_type, n_norms, ithresh
421  LOGICAL COLEQU, IGNORE_CWISE
422  REAL RTHRESH, DZ_UB
423 * ..
424 * .. Array Arguments ..
425  INTEGER IPIV( * )
426  COMPLEX AB( ldab, * ), AFB( ldafb, * ), B( ldb, * ),
427  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
428  REAL C( * ), AYB(*), RCOND, BERR_OUT( * ),
429  $ err_bnds_norm( nrhs, * ),
430  $ err_bnds_comp( nrhs, * )
431 * ..
432 *
433 * =====================================================================
434 *
435 * .. Local Scalars ..
436  CHARACTER TRANS
437  INTEGER CNT, I, J, M, X_STATE, Z_STATE, Y_PREC_STATE
438  REAL YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
439  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
440  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
441  $ eps, hugeval, incr_thresh
442  LOGICAL INCR_PREC
443  COMPLEX ZDUM
444 * ..
445 * .. Parameters ..
446  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
447  $ noprog_state, base_residual, extra_residual,
448  $ extra_y
449  parameter( unstable_state = 0, working_state = 1,
450  $ conv_state = 2, noprog_state = 3 )
451  parameter( base_residual = 0, extra_residual = 1,
452  $ extra_y = 2 )
453  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
454  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
455  INTEGER CMP_ERR_I, PIV_GROWTH_I
456  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
457  $ berr_i = 3 )
458  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
459  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
460  $ piv_growth_i = 9 )
461  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
462  $ la_linrx_cwise_i
463  parameter( la_linrx_itref_i = 1,
464  $ la_linrx_ithresh_i = 2 )
465  parameter( la_linrx_cwise_i = 3 )
466  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
467  $ la_linrx_rcond_i
468  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
469  parameter( la_linrx_rcond_i = 3 )
470 * ..
471 * .. External Subroutines ..
472  EXTERNAL caxpy, ccopy, cgbtrs, cgbmv, blas_cgbmv_x,
473  $ blas_cgbmv2_x, cla_gbamv, cla_wwaddw, slamch,
475  REAL SLAMCH
476  CHARACTER CHLA_TRANSTYPE
477 * ..
478 * .. Intrinsic Functions..
479  INTRINSIC abs, max, min
480 * ..
481 * .. Statement Functions ..
482  REAL CABS1
483 * ..
484 * .. Statement Function Definitions ..
485  cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( AIMAG( zdum ) )
486 * ..
487 * .. Executable Statements ..
488 *
489  IF (info.NE.0) RETURN
490  trans = chla_transtype(trans_type)
491  eps = slamch( 'Epsilon' )
492  hugeval = slamch( 'Overflow' )
493 * Force HUGEVAL to Inf
494  hugeval = hugeval * hugeval
495 * Using HUGEVAL may lead to spurious underflows.
496  incr_thresh = REAL( N ) * EPS
497  m = kl+ku+1
498 
499  DO j = 1, nrhs
500  y_prec_state = extra_residual
501  IF ( y_prec_state .EQ. extra_y ) then
502  DO i = 1, n
503  y_tail( i ) = 0.0
504  END DO
505  END IF
506 
507  dxrat = 0.0e+0
508  dxratmax = 0.0e+0
509  dzrat = 0.0e+0
510  dzratmax = 0.0e+0
511  final_dx_x = hugeval
512  final_dz_z = hugeval
513  prevnormdx = hugeval
514  prev_dz_z = hugeval
515  dz_z = hugeval
516  dx_x = hugeval
517 
518  x_state = working_state
519  z_state = unstable_state
520  incr_prec = .false.
521 
522  DO cnt = 1, ithresh
523 *
524 * Compute residual RES = B_s - op(A_s) * Y,
525 * op(A) = A, A**T, or A**H depending on TRANS (and type).
526 *
527  CALL ccopy( n, b( 1, j ), 1, res, 1 )
528  IF ( y_prec_state .EQ. base_residual ) THEN
529  CALL cgbmv( trans, m, n, kl, ku, (-1.0e+0,0.0e+0), ab,
530  $ ldab, y( 1, j ), 1, (1.0e+0,0.0e+0), res, 1 )
531  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
532  CALL blas_cgbmv_x( trans_type, n, n, kl, ku,
533  $ (-1.0e+0,0.0e+0), ab, ldab, y( 1, j ), 1,
534  $ (1.0e+0,0.0e+0), res, 1, prec_type )
535  ELSE
536  CALL blas_cgbmv2_x( trans_type, n, n, kl, ku,
537  $ (-1.0e+0,0.0e+0), ab, ldab, y( 1, j ), y_tail, 1,
538  $ (1.0e+0,0.0e+0), res, 1, prec_type )
539  END IF
540 
541 ! XXX: RES is no longer needed.
542  CALL ccopy( n, res, 1, dy, 1 )
543  CALL cgbtrs( trans, n, kl, ku, 1, afb, ldafb, ipiv, dy, n,
544  $ info )
545 *
546 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
547 *
548  normx = 0.0e+0
549  normy = 0.0e+0
550  normdx = 0.0e+0
551  dz_z = 0.0e+0
552  ymin = hugeval
553 
554  DO i = 1, n
555  yk = cabs1( y( i, j ) )
556  dyk = cabs1( dy( i ) )
557 
558  IF (yk .NE. 0.0) THEN
559  dz_z = max( dz_z, dyk / yk )
560  ELSE IF ( dyk .NE. 0.0 ) THEN
561  dz_z = hugeval
562  END IF
563 
564  ymin = min( ymin, yk )
565 
566  normy = max( normy, yk )
567 
568  IF ( colequ ) THEN
569  normx = max( normx, yk * c( i ) )
570  normdx = max(normdx, dyk * c(i))
571  ELSE
572  normx = normy
573  normdx = max( normdx, dyk )
574  END IF
575  END DO
576 
577  IF ( normx .NE. 0.0 ) THEN
578  dx_x = normdx / normx
579  ELSE IF ( normdx .EQ. 0.0 ) THEN
580  dx_x = 0.0
581  ELSE
582  dx_x = hugeval
583  END IF
584 
585  dxrat = normdx / prevnormdx
586  dzrat = dz_z / prev_dz_z
587 *
588 * Check termination criteria.
589 *
590  IF (.NOT.ignore_cwise
591  $ .AND. ymin*rcond .LT. incr_thresh*normy
592  $ .AND. y_prec_state .LT. extra_y )
593  $ incr_prec = .true.
594 
595  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
596  $ x_state = working_state
597  IF ( x_state .EQ. working_state ) THEN
598  IF ( dx_x .LE. eps ) THEN
599  x_state = conv_state
600  ELSE IF ( dxrat .GT. rthresh ) THEN
601  IF ( y_prec_state .NE. extra_y ) THEN
602  incr_prec = .true.
603  ELSE
604  x_state = noprog_state
605  END IF
606  ELSE
607  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
608  END IF
609  IF ( x_state .GT. working_state ) final_dx_x = dx_x
610  END IF
611 
612  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
613  $ z_state = working_state
614  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
615  $ z_state = working_state
616  IF ( z_state .EQ. working_state ) THEN
617  IF ( dz_z .LE. eps ) THEN
618  z_state = conv_state
619  ELSE IF ( dz_z .GT. dz_ub ) THEN
620  z_state = unstable_state
621  dzratmax = 0.0
622  final_dz_z = hugeval
623  ELSE IF ( dzrat .GT. rthresh ) THEN
624  IF ( y_prec_state .NE. extra_y ) THEN
625  incr_prec = .true.
626  ELSE
627  z_state = noprog_state
628  END IF
629  ELSE
630  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
631  END IF
632  IF ( z_state .GT. working_state ) final_dz_z = dz_z
633  END IF
634 *
635 * Exit if both normwise and componentwise stopped working,
636 * but if componentwise is unstable, let it go at least two
637 * iterations.
638 *
639  IF ( x_state.NE.working_state ) THEN
640  IF ( ignore_cwise ) GOTO 666
641  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
642  $ GOTO 666
643  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
644  END IF
645 
646  IF ( incr_prec ) THEN
647  incr_prec = .false.
648  y_prec_state = y_prec_state + 1
649  DO i = 1, n
650  y_tail( i ) = 0.0
651  END DO
652  END IF
653 
654  prevnormdx = normdx
655  prev_dz_z = dz_z
656 *
657 * Update soluton.
658 *
659  IF ( y_prec_state .LT. extra_y ) THEN
660  CALL caxpy( n, (1.0e+0,0.0e+0), dy, 1, y(1,j), 1 )
661  ELSE
662  CALL cla_wwaddw( n, y(1,j), y_tail, dy )
663  END IF
664 
665  END DO
666 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
667  666 CONTINUE
668 *
669 * Set final_* when cnt hits ithresh.
670 *
671  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
672  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
673 *
674 * Compute error bounds.
675 *
676  IF ( n_norms .GE. 1 ) THEN
677  err_bnds_norm( j, la_linrx_err_i ) =
678  $ final_dx_x / (1 - dxratmax)
679  END IF
680  IF ( n_norms .GE. 2 ) THEN
681  err_bnds_comp( j, la_linrx_err_i ) =
682  $ final_dz_z / (1 - dzratmax)
683  END IF
684 *
685 * Compute componentwise relative backward error from formula
686 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
687 * where abs(Z) is the componentwise absolute value of the matrix
688 * or vector Z.
689 *
690 * Compute residual RES = B_s - op(A_s) * Y,
691 * op(A) = A, A**T, or A**H depending on TRANS (and type).
692 *
693  CALL ccopy( n, b( 1, j ), 1, res, 1 )
694  CALL cgbmv( trans, n, n, kl, ku, (-1.0e+0,0.0e+0), ab, ldab,
695  $ y(1,j), 1, (1.0e+0,0.0e+0), res, 1 )
696 
697  DO i = 1, n
698  ayb( i ) = cabs1( b( i, j ) )
699  END DO
700 *
701 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
702 *
703  CALL cla_gbamv( trans_type, n, n, kl, ku, 1.0e+0,
704  $ ab, ldab, y(1, j), 1, 1.0e+0, ayb, 1 )
705 
706  CALL cla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
707 *
708 * End of loop for each RHS.
709 *
710  END DO
711 *
712  RETURN
713  END
subroutine cla_wwaddw(N, X, Y, W)
CLA_WWADDW adds a vector into a doubled-single vector.
Definition: cla_wwaddw.f:83
subroutine cla_gbrfsx_extended(PREC_TYPE, TRANS_TYPE, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
CLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded...
subroutine cgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
CGBTRS
Definition: cgbtrs.f:140
subroutine cgbmv(TRANS, M, N, KL, KU, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGBMV
Definition: cgbmv.f:189
subroutine cla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
CLA_LIN_BERR computes a component-wise relative backward error.
Definition: cla_lin_berr.f:103
subroutine cla_gbamv(TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X, INCX, BETA, Y, INCY)
CLA_GBAMV performs a matrix-vector operation to calculate error bounds.
Definition: cla_gbamv.f:188
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:83
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:90
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE