LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
sgeqp3.f
Go to the documentation of this file.
1*> \brief \b SGEQP3
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SGEQP3 + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgeqp3.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgeqp3.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgeqp3.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SGEQP3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* INTEGER INFO, LDA, LWORK, M, N
25* ..
26* .. Array Arguments ..
27* INTEGER JPVT( * )
28* REAL A( LDA, * ), TAU( * ), WORK( * )
29* ..
30*
31*
32*> \par Purpose:
33* =============
34*>
35*> \verbatim
36*>
37*> SGEQP3 computes a QR factorization with column pivoting of a
38*> matrix A: A*P = Q*R using Level 3 BLAS.
39*> \endverbatim
40*
41* Arguments:
42* ==========
43*
44*> \param[in] M
45*> \verbatim
46*> M is INTEGER
47*> The number of rows of the matrix A. M >= 0.
48*> \endverbatim
49*>
50*> \param[in] N
51*> \verbatim
52*> N is INTEGER
53*> The number of columns of the matrix A. N >= 0.
54*> \endverbatim
55*>
56*> \param[in,out] A
57*> \verbatim
58*> A is REAL array, dimension (LDA,N)
59*> On entry, the M-by-N matrix A.
60*> On exit, the upper triangle of the array contains the
61*> min(M,N)-by-N upper trapezoidal matrix R; the elements below
62*> the diagonal, together with the array TAU, represent the
63*> orthogonal matrix Q as a product of min(M,N) elementary
64*> reflectors.
65*> \endverbatim
66*>
67*> \param[in] LDA
68*> \verbatim
69*> LDA is INTEGER
70*> The leading dimension of the array A. LDA >= max(1,M).
71*> \endverbatim
72*>
73*> \param[in,out] JPVT
74*> \verbatim
75*> JPVT is INTEGER array, dimension (N)
76*> On entry, if JPVT(J).ne.0, the J-th column of A is permuted
77*> to the front of A*P (a leading column); if JPVT(J)=0,
78*> the J-th column of A is a free column.
79*> On exit, if JPVT(J)=K, then the J-th column of A*P was the
80*> the K-th column of A.
81*> \endverbatim
82*>
83*> \param[out] TAU
84*> \verbatim
85*> TAU is REAL array, dimension (min(M,N))
86*> The scalar factors of the elementary reflectors.
87*> \endverbatim
88*>
89*> \param[out] WORK
90*> \verbatim
91*> WORK is REAL array, dimension (MAX(1,LWORK))
92*> On exit, if INFO=0, WORK(1) returns the optimal LWORK.
93*> \endverbatim
94*>
95*> \param[in] LWORK
96*> \verbatim
97*> LWORK is INTEGER
98*> The dimension of the array WORK. LWORK >= 3*N+1.
99*> For optimal performance LWORK >= 2*N+( N+1 )*NB, where NB
100*> is the optimal blocksize.
101*>
102*> If LWORK = -1, then a workspace query is assumed; the routine
103*> only calculates the optimal size of the WORK array, returns
104*> this value as the first entry of the WORK array, and no error
105*> message related to LWORK is issued by XERBLA.
106*> \endverbatim
107*>
108*> \param[out] INFO
109*> \verbatim
110*> INFO is INTEGER
111*> = 0: successful exit.
112*> < 0: if INFO = -i, the i-th argument had an illegal value.
113*> \endverbatim
114*
115* Authors:
116* ========
117*
118*> \author Univ. of Tennessee
119*> \author Univ. of California Berkeley
120*> \author Univ. of Colorado Denver
121*> \author NAG Ltd.
122*
123*> \ingroup geqp3
124*
125*> \par Further Details:
126* =====================
127*>
128*> \verbatim
129*>
130*> The matrix Q is represented as a product of elementary reflectors
131*>
132*> Q = H(1) H(2) . . . H(k), where k = min(m,n).
133*>
134*> Each H(i) has the form
135*>
136*> H(i) = I - tau * v * v**T
137*>
138*> where tau is a real scalar, and v is a real/complex vector
139*> with v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in
140*> A(i+1:m,i), and tau in TAU(i).
141*> \endverbatim
142*
143*> \par Contributors:
144* ==================
145*>
146*> G. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain
147*> X. Sun, Computer Science Dept., Duke University, USA
148*>
149* =====================================================================
150 SUBROUTINE sgeqp3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, INFO )
151*
152* -- LAPACK computational routine --
153* -- LAPACK is a software package provided by Univ. of Tennessee, --
154* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
155*
156* .. Scalar Arguments ..
157 INTEGER INFO, LDA, LWORK, M, N
158* ..
159* .. Array Arguments ..
160 INTEGER JPVT( * )
161 REAL A( LDA, * ), TAU( * ), WORK( * )
162* ..
163*
164* =====================================================================
165*
166* .. Parameters ..
167 INTEGER INB, INBMIN, IXOVER
168 parameter( inb = 1, inbmin = 2, ixover = 3 )
169* ..
170* .. Local Scalars ..
171 LOGICAL LQUERY
172 INTEGER FJB, IWS, J, JB, LWKOPT, MINMN, MINWS, NA, NB,
173 $ NBMIN, NFXD, NX, SM, SMINMN, SN, TOPBMN
174* ..
175* .. External Subroutines ..
176 EXTERNAL sgeqrf, slaqp2, slaqps, sormqr, sswap, xerbla
177* ..
178* .. External Functions ..
179 INTEGER ILAENV
180 REAL SNRM2, SROUNDUP_LWORK
181 EXTERNAL ilaenv, snrm2, sroundup_lwork
182* ..
183* .. Intrinsic Functions ..
184 INTRINSIC int, max, min
185* Test input arguments
186* ====================
187*
188 info = 0
189 lquery = ( lwork.EQ.-1 )
190 IF( m.LT.0 ) THEN
191 info = -1
192 ELSE IF( n.LT.0 ) THEN
193 info = -2
194 ELSE IF( lda.LT.max( 1, m ) ) THEN
195 info = -4
196 END IF
197*
198 IF( info.EQ.0 ) THEN
199 minmn = min( m, n )
200 IF( minmn.EQ.0 ) THEN
201 iws = 1
202 lwkopt = 1
203 ELSE
204 iws = 3*n + 1
205 nb = ilaenv( inb, 'SGEQRF', ' ', m, n, -1, -1 )
206 lwkopt = 2*n + ( n + 1 )*nb
207 END IF
208 work( 1 ) = sroundup_lwork(lwkopt)
209*
210 IF( ( lwork.LT.iws ) .AND. .NOT.lquery ) THEN
211 info = -8
212 END IF
213 END IF
214*
215 IF( info.NE.0 ) THEN
216 CALL xerbla( 'SGEQP3', -info )
217 RETURN
218 ELSE IF( lquery ) THEN
219 RETURN
220 END IF
221*
222* Move initial columns up front.
223*
224 nfxd = 1
225 DO 10 j = 1, n
226 IF( jpvt( j ).NE.0 ) THEN
227 IF( j.NE.nfxd ) THEN
228 CALL sswap( m, a( 1, j ), 1, a( 1, nfxd ), 1 )
229 jpvt( j ) = jpvt( nfxd )
230 jpvt( nfxd ) = j
231 ELSE
232 jpvt( j ) = j
233 END IF
234 nfxd = nfxd + 1
235 ELSE
236 jpvt( j ) = j
237 END IF
238 10 CONTINUE
239 nfxd = nfxd - 1
240*
241* Factorize fixed columns
242* =======================
243*
244* Compute the QR factorization of fixed columns and update
245* remaining columns.
246*
247 IF( nfxd.GT.0 ) THEN
248 na = min( m, nfxd )
249*CC CALL SGEQR2( M, NA, A, LDA, TAU, WORK, INFO )
250 CALL sgeqrf( m, na, a, lda, tau, work, lwork, info )
251 iws = max( iws, int( work( 1 ) ) )
252 IF( na.LT.n ) THEN
253*CC CALL SORM2R( 'Left', 'Transpose', M, N-NA, NA, A, LDA,
254*CC $ TAU, A( 1, NA+1 ), LDA, WORK, INFO )
255 CALL sormqr( 'Left', 'Transpose', m, n-na, na, a, lda, tau,
256 $ a( 1, na+1 ), lda, work, lwork, info )
257 iws = max( iws, int( work( 1 ) ) )
258 END IF
259 END IF
260*
261* Factorize free columns
262* ======================
263*
264 IF( nfxd.LT.minmn ) THEN
265*
266 sm = m - nfxd
267 sn = n - nfxd
268 sminmn = minmn - nfxd
269*
270* Determine the block size.
271*
272 nb = ilaenv( inb, 'SGEQRF', ' ', sm, sn, -1, -1 )
273 nbmin = 2
274 nx = 0
275*
276 IF( ( nb.GT.1 ) .AND. ( nb.LT.sminmn ) ) THEN
277*
278* Determine when to cross over from blocked to unblocked code.
279*
280 nx = max( 0, ilaenv( ixover, 'SGEQRF', ' ', sm, sn, -1,
281 $ -1 ) )
282*
283*
284 IF( nx.LT.sminmn ) THEN
285*
286* Determine if workspace is large enough for blocked code.
287*
288 minws = 2*sn + ( sn+1 )*nb
289 iws = max( iws, minws )
290 IF( lwork.LT.minws ) THEN
291*
292* Not enough workspace to use optimal NB: Reduce NB and
293* determine the minimum value of NB.
294*
295 nb = ( lwork-2*sn ) / ( sn+1 )
296 nbmin = max( 2, ilaenv( inbmin, 'SGEQRF', ' ', sm, sn,
297 $ -1, -1 ) )
298*
299*
300 END IF
301 END IF
302 END IF
303*
304* Initialize partial column norms. The first N elements of work
305* store the exact column norms.
306*
307 DO 20 j = nfxd + 1, n
308 work( j ) = snrm2( sm, a( nfxd+1, j ), 1 )
309 work( n+j ) = work( j )
310 20 CONTINUE
311*
312 IF( ( nb.GE.nbmin ) .AND. ( nb.LT.sminmn ) .AND.
313 $ ( nx.LT.sminmn ) ) THEN
314*
315* Use blocked code initially.
316*
317 j = nfxd + 1
318*
319* Compute factorization: while loop.
320*
321*
322 topbmn = minmn - nx
323 30 CONTINUE
324 IF( j.LE.topbmn ) THEN
325 jb = min( nb, topbmn-j+1 )
326*
327* Factorize JB columns among columns J:N.
328*
329 CALL slaqps( m, n-j+1, j-1, jb, fjb, a( 1, j ), lda,
330 $ jpvt( j ), tau( j ), work( j ), work( n+j ),
331 $ work( 2*n+1 ), work( 2*n+jb+1 ), n-j+1 )
332*
333 j = j + fjb
334 GO TO 30
335 END IF
336 ELSE
337 j = nfxd + 1
338 END IF
339*
340* Use unblocked code to factor the last or only block.
341*
342*
343 IF( j.LE.minmn )
344 $ CALL slaqp2( m, n-j+1, j-1, a( 1, j ), lda, jpvt( j ),
345 $ tau( j ), work( j ), work( n+j ),
346 $ work( 2*n+1 ) )
347*
348 END IF
349*
350 work( 1 ) = sroundup_lwork(iws)
351 RETURN
352*
353* End of SGEQP3
354*
355 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine sgeqp3(m, n, a, lda, jpvt, tau, work, lwork, info)
SGEQP3
Definition sgeqp3.f:151
subroutine sgeqrf(m, n, a, lda, tau, work, lwork, info)
SGEQRF
Definition sgeqrf.f:146
subroutine slaqp2(m, n, offset, a, lda, jpvt, tau, vn1, vn2, work)
SLAQP2 computes a QR factorization with column pivoting of the matrix block.
Definition slaqp2.f:149
subroutine slaqps(m, n, offset, nb, kb, a, lda, jpvt, tau, vn1, vn2, auxv, f, ldf)
SLAQPS computes a step of QR factorization with column pivoting of a real m-by-n matrix A by using BL...
Definition slaqps.f:178
subroutine sswap(n, sx, incx, sy, incy)
SSWAP
Definition sswap.f:82
subroutine sormqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
SORMQR
Definition sormqr.f:168