LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
cggsvd3.f
Go to the documentation of this file.
1*> \brief <b> CGGSVD3 computes the singular value decomposition (SVD) for OTHER matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CGGSVD3 + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cggsvd3.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cggsvd3.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cggsvd3.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CGGSVD3( JOBU, JOBV, JOBQ, M, N, P, K, L, A, LDA, B,
22* LDB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ, WORK,
23* LWORK, RWORK, IWORK, INFO )
24*
25* .. Scalar Arguments ..
26* CHARACTER JOBQ, JOBU, JOBV
27* INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P, LWORK
28* ..
29* .. Array Arguments ..
30* INTEGER IWORK( * )
31* REAL ALPHA( * ), BETA( * ), RWORK( * )
32* COMPLEX A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
33* $ U( LDU, * ), V( LDV, * ), WORK( * )
34* ..
35*
36*
37*> \par Purpose:
38* =============
39*>
40*> \verbatim
41*>
42*> CGGSVD3 computes the generalized singular value decomposition (GSVD)
43*> of an M-by-N complex matrix A and P-by-N complex matrix B:
44*>
45*> U**H*A*Q = D1*( 0 R ), V**H*B*Q = D2*( 0 R )
46*>
47*> where U, V and Q are unitary matrices.
48*> Let K+L = the effective numerical rank of the
49*> matrix (A**H,B**H)**H, then R is a (K+L)-by-(K+L) nonsingular upper
50*> triangular matrix, D1 and D2 are M-by-(K+L) and P-by-(K+L) "diagonal"
51*> matrices and of the following structures, respectively:
52*>
53*> If M-K-L >= 0,
54*>
55*> K L
56*> D1 = K ( I 0 )
57*> L ( 0 C )
58*> M-K-L ( 0 0 )
59*>
60*> K L
61*> D2 = L ( 0 S )
62*> P-L ( 0 0 )
63*>
64*> N-K-L K L
65*> ( 0 R ) = K ( 0 R11 R12 )
66*> L ( 0 0 R22 )
67*>
68*> where
69*>
70*> C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
71*> S = diag( BETA(K+1), ... , BETA(K+L) ),
72*> C**2 + S**2 = I.
73*>
74*> R is stored in A(1:K+L,N-K-L+1:N) on exit.
75*>
76*> If M-K-L < 0,
77*>
78*> K M-K K+L-M
79*> D1 = K ( I 0 0 )
80*> M-K ( 0 C 0 )
81*>
82*> K M-K K+L-M
83*> D2 = M-K ( 0 S 0 )
84*> K+L-M ( 0 0 I )
85*> P-L ( 0 0 0 )
86*>
87*> N-K-L K M-K K+L-M
88*> ( 0 R ) = K ( 0 R11 R12 R13 )
89*> M-K ( 0 0 R22 R23 )
90*> K+L-M ( 0 0 0 R33 )
91*>
92*> where
93*>
94*> C = diag( ALPHA(K+1), ... , ALPHA(M) ),
95*> S = diag( BETA(K+1), ... , BETA(M) ),
96*> C**2 + S**2 = I.
97*>
98*> (R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N), and R33 is stored
99*> ( 0 R22 R23 )
100*> in B(M-K+1:L,N+M-K-L+1:N) on exit.
101*>
102*> The routine computes C, S, R, and optionally the unitary
103*> transformation matrices U, V and Q.
104*>
105*> In particular, if B is an N-by-N nonsingular matrix, then the GSVD of
106*> A and B implicitly gives the SVD of A*inv(B):
107*> A*inv(B) = U*(D1*inv(D2))*V**H.
108*> If ( A**H,B**H)**H has orthonormal columns, then the GSVD of A and B is also
109*> equal to the CS decomposition of A and B. Furthermore, the GSVD can
110*> be used to derive the solution of the eigenvalue problem:
111*> A**H*A x = lambda* B**H*B x.
112*> In some literature, the GSVD of A and B is presented in the form
113*> U**H*A*X = ( 0 D1 ), V**H*B*X = ( 0 D2 )
114*> where U and V are orthogonal and X is nonsingular, and D1 and D2 are
115*> ``diagonal''. The former GSVD form can be converted to the latter
116*> form by taking the nonsingular matrix X as
117*>
118*> X = Q*( I 0 )
119*> ( 0 inv(R) )
120*> \endverbatim
121*
122* Arguments:
123* ==========
124*
125*> \param[in] JOBU
126*> \verbatim
127*> JOBU is CHARACTER*1
128*> = 'U': Unitary matrix U is computed;
129*> = 'N': U is not computed.
130*> \endverbatim
131*>
132*> \param[in] JOBV
133*> \verbatim
134*> JOBV is CHARACTER*1
135*> = 'V': Unitary matrix V is computed;
136*> = 'N': V is not computed.
137*> \endverbatim
138*>
139*> \param[in] JOBQ
140*> \verbatim
141*> JOBQ is CHARACTER*1
142*> = 'Q': Unitary matrix Q is computed;
143*> = 'N': Q is not computed.
144*> \endverbatim
145*>
146*> \param[in] M
147*> \verbatim
148*> M is INTEGER
149*> The number of rows of the matrix A. M >= 0.
150*> \endverbatim
151*>
152*> \param[in] N
153*> \verbatim
154*> N is INTEGER
155*> The number of columns of the matrices A and B. N >= 0.
156*> \endverbatim
157*>
158*> \param[in] P
159*> \verbatim
160*> P is INTEGER
161*> The number of rows of the matrix B. P >= 0.
162*> \endverbatim
163*>
164*> \param[out] K
165*> \verbatim
166*> K is INTEGER
167*> \endverbatim
168*>
169*> \param[out] L
170*> \verbatim
171*> L is INTEGER
172*>
173*> On exit, K and L specify the dimension of the subblocks
174*> described in Purpose.
175*> K + L = effective numerical rank of (A**H,B**H)**H.
176*> \endverbatim
177*>
178*> \param[in,out] A
179*> \verbatim
180*> A is COMPLEX array, dimension (LDA,N)
181*> On entry, the M-by-N matrix A.
182*> On exit, A contains the triangular matrix R, or part of R.
183*> See Purpose for details.
184*> \endverbatim
185*>
186*> \param[in] LDA
187*> \verbatim
188*> LDA is INTEGER
189*> The leading dimension of the array A. LDA >= max(1,M).
190*> \endverbatim
191*>
192*> \param[in,out] B
193*> \verbatim
194*> B is COMPLEX array, dimension (LDB,N)
195*> On entry, the P-by-N matrix B.
196*> On exit, B contains part of the triangular matrix R if
197*> M-K-L < 0. See Purpose for details.
198*> \endverbatim
199*>
200*> \param[in] LDB
201*> \verbatim
202*> LDB is INTEGER
203*> The leading dimension of the array B. LDB >= max(1,P).
204*> \endverbatim
205*>
206*> \param[out] ALPHA
207*> \verbatim
208*> ALPHA is REAL array, dimension (N)
209*> \endverbatim
210*>
211*> \param[out] BETA
212*> \verbatim
213*> BETA is REAL array, dimension (N)
214*>
215*> On exit, ALPHA and BETA contain the generalized singular
216*> value pairs of A and B;
217*> ALPHA(1:K) = 1,
218*> BETA(1:K) = 0,
219*> and if M-K-L >= 0,
220*> ALPHA(K+1:K+L) = C,
221*> BETA(K+1:K+L) = S,
222*> or if M-K-L < 0,
223*> ALPHA(K+1:M)=C, ALPHA(M+1:K+L)=0
224*> BETA(K+1:M) =S, BETA(M+1:K+L) =1
225*> and
226*> ALPHA(K+L+1:N) = 0
227*> BETA(K+L+1:N) = 0
228*> \endverbatim
229*>
230*> \param[out] U
231*> \verbatim
232*> U is COMPLEX array, dimension (LDU,M)
233*> If JOBU = 'U', U contains the M-by-M unitary matrix U.
234*> If JOBU = 'N', U is not referenced.
235*> \endverbatim
236*>
237*> \param[in] LDU
238*> \verbatim
239*> LDU is INTEGER
240*> The leading dimension of the array U. LDU >= max(1,M) if
241*> JOBU = 'U'; LDU >= 1 otherwise.
242*> \endverbatim
243*>
244*> \param[out] V
245*> \verbatim
246*> V is COMPLEX array, dimension (LDV,P)
247*> If JOBV = 'V', V contains the P-by-P unitary matrix V.
248*> If JOBV = 'N', V is not referenced.
249*> \endverbatim
250*>
251*> \param[in] LDV
252*> \verbatim
253*> LDV is INTEGER
254*> The leading dimension of the array V. LDV >= max(1,P) if
255*> JOBV = 'V'; LDV >= 1 otherwise.
256*> \endverbatim
257*>
258*> \param[out] Q
259*> \verbatim
260*> Q is COMPLEX array, dimension (LDQ,N)
261*> If JOBQ = 'Q', Q contains the N-by-N unitary matrix Q.
262*> If JOBQ = 'N', Q is not referenced.
263*> \endverbatim
264*>
265*> \param[in] LDQ
266*> \verbatim
267*> LDQ is INTEGER
268*> The leading dimension of the array Q. LDQ >= max(1,N) if
269*> JOBQ = 'Q'; LDQ >= 1 otherwise.
270*> \endverbatim
271*>
272*> \param[out] WORK
273*> \verbatim
274*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
275*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
276*> \endverbatim
277*>
278*> \param[in] LWORK
279*> \verbatim
280*> LWORK is INTEGER
281*> The dimension of the array WORK.
282*>
283*> If LWORK = -1, then a workspace query is assumed; the routine
284*> only calculates the optimal size of the WORK array, returns
285*> this value as the first entry of the WORK array, and no error
286*> message related to LWORK is issued by XERBLA.
287*> \endverbatim
288*>
289*> \param[out] RWORK
290*> \verbatim
291*> RWORK is REAL array, dimension (2*N)
292*> \endverbatim
293*>
294*> \param[out] IWORK
295*> \verbatim
296*> IWORK is INTEGER array, dimension (N)
297*> On exit, IWORK stores the sorting information. More
298*> precisely, the following loop will sort ALPHA
299*> for I = K+1, min(M,K+L)
300*> swap ALPHA(I) and ALPHA(IWORK(I))
301*> endfor
302*> such that ALPHA(1) >= ALPHA(2) >= ... >= ALPHA(N).
303*> \endverbatim
304*>
305*> \param[out] INFO
306*> \verbatim
307*> INFO is INTEGER
308*> = 0: successful exit.
309*> < 0: if INFO = -i, the i-th argument had an illegal value.
310*> > 0: if INFO = 1, the Jacobi-type procedure failed to
311*> converge. For further details, see subroutine CTGSJA.
312*> \endverbatim
313*
314*> \par Internal Parameters:
315* =========================
316*>
317*> \verbatim
318*> TOLA REAL
319*> TOLB REAL
320*> TOLA and TOLB are the thresholds to determine the effective
321*> rank of (A**H,B**H)**H. Generally, they are set to
322*> TOLA = MAX(M,N)*norm(A)*MACHEPS,
323*> TOLB = MAX(P,N)*norm(B)*MACHEPS.
324*> The size of TOLA and TOLB may affect the size of backward
325*> errors of the decomposition.
326*> \endverbatim
327*
328* Authors:
329* ========
330*
331*> \author Univ. of Tennessee
332*> \author Univ. of California Berkeley
333*> \author Univ. of Colorado Denver
334*> \author NAG Ltd.
335*
336*> \ingroup ggsvd3
337*
338*> \par Contributors:
339* ==================
340*>
341*> Ming Gu and Huan Ren, Computer Science Division, University of
342*> California at Berkeley, USA
343*>
344*
345*> \par Further Details:
346* =====================
347*>
348*> CGGSVD3 replaces the deprecated subroutine CGGSVD.
349*>
350* =====================================================================
351 SUBROUTINE cggsvd3( JOBU, JOBV, JOBQ, M, N, P, K, L, A, LDA, B,
352 $ LDB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ,
353 $ WORK, LWORK, RWORK, IWORK, INFO )
354*
355* -- LAPACK driver routine --
356* -- LAPACK is a software package provided by Univ. of Tennessee, --
357* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
358*
359* .. Scalar Arguments ..
360 CHARACTER JOBQ, JOBU, JOBV
361 INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P,
362 $ lwork
363* ..
364* .. Array Arguments ..
365 INTEGER IWORK( * )
366 REAL ALPHA( * ), BETA( * ), RWORK( * )
367 COMPLEX A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
368 $ u( ldu, * ), v( ldv, * ), work( * )
369* ..
370*
371* =====================================================================
372*
373* .. Local Scalars ..
374 LOGICAL WANTQ, WANTU, WANTV, LQUERY
375 INTEGER I, IBND, ISUB, J, NCYCLE, LWKOPT
376 REAL ANORM, BNORM, SMAX, TEMP, TOLA, TOLB, ULP, UNFL
377* ..
378* .. External Functions ..
379 LOGICAL LSAME
380 REAL CLANGE, SLAMCH
381 EXTERNAL lsame, clange, slamch
382* ..
383* .. External Subroutines ..
384 EXTERNAL cggsvp3, ctgsja, scopy, xerbla
385* ..
386* .. Intrinsic Functions ..
387 INTRINSIC max, min
388* ..
389* .. Executable Statements ..
390*
391* Decode and test the input parameters
392*
393 wantu = lsame( jobu, 'U' )
394 wantv = lsame( jobv, 'V' )
395 wantq = lsame( jobq, 'Q' )
396 lquery = ( lwork.EQ.-1 )
397 lwkopt = 1
398*
399* Test the input arguments
400*
401 info = 0
402 IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
403 info = -1
404 ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
405 info = -2
406 ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
407 info = -3
408 ELSE IF( m.LT.0 ) THEN
409 info = -4
410 ELSE IF( n.LT.0 ) THEN
411 info = -5
412 ELSE IF( p.LT.0 ) THEN
413 info = -6
414 ELSE IF( lda.LT.max( 1, m ) ) THEN
415 info = -10
416 ELSE IF( ldb.LT.max( 1, p ) ) THEN
417 info = -12
418 ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
419 info = -16
420 ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
421 info = -18
422 ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
423 info = -20
424 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
425 info = -24
426 END IF
427*
428* Compute workspace
429*
430 IF( info.EQ.0 ) THEN
431 CALL cggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola,
432 $ tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, rwork,
433 $ work, work, -1, info )
434 lwkopt = n + int( work( 1 ) )
435 lwkopt = max( 2*n, lwkopt )
436 lwkopt = max( 1, lwkopt )
437 work( 1 ) = cmplx( lwkopt )
438 END IF
439*
440 IF( info.NE.0 ) THEN
441 CALL xerbla( 'CGGSVD3', -info )
442 RETURN
443 END IF
444 IF( lquery ) THEN
445 RETURN
446 ENDIF
447*
448* Compute the Frobenius norm of matrices A and B
449*
450 anorm = clange( '1', m, n, a, lda, rwork )
451 bnorm = clange( '1', p, n, b, ldb, rwork )
452*
453* Get machine precision and set up threshold for determining
454* the effective numerical rank of the matrices A and B.
455*
456 ulp = slamch( 'Precision' )
457 unfl = slamch( 'Safe Minimum' )
458 tola = max( m, n )*max( anorm, unfl )*ulp
459 tolb = max( p, n )*max( bnorm, unfl )*ulp
460*
461 CALL cggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola,
462 $ tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, rwork,
463 $ work, work( n+1 ), lwork-n, info )
464*
465* Compute the GSVD of two upper "triangular" matrices
466*
467 CALL ctgsja( jobu, jobv, jobq, m, p, n, k, l, a, lda, b, ldb,
468 $ tola, tolb, alpha, beta, u, ldu, v, ldv, q, ldq,
469 $ work, ncycle, info )
470*
471* Sort the singular values and store the pivot indices in IWORK
472* Copy ALPHA to RWORK, then sort ALPHA in RWORK
473*
474 CALL scopy( n, alpha, 1, rwork, 1 )
475 ibnd = min( l, m-k )
476 DO 20 i = 1, ibnd
477*
478* Scan for largest ALPHA(K+I)
479*
480 isub = i
481 smax = rwork( k+i )
482 DO 10 j = i + 1, ibnd
483 temp = rwork( k+j )
484 IF( temp.GT.smax ) THEN
485 isub = j
486 smax = temp
487 END IF
488 10 CONTINUE
489 IF( isub.NE.i ) THEN
490 rwork( k+isub ) = rwork( k+i )
491 rwork( k+i ) = smax
492 iwork( k+i ) = k + isub
493 ELSE
494 iwork( k+i ) = k + i
495 END IF
496 20 CONTINUE
497*
498 work( 1 ) = cmplx( lwkopt )
499 RETURN
500*
501* End of CGGSVD3
502*
503 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine scopy(n, sx, incx, sy, incy)
SCOPY
Definition scopy.f:82
subroutine cggsvd3(jobu, jobv, jobq, m, n, p, k, l, a, lda, b, ldb, alpha, beta, u, ldu, v, ldv, q, ldq, work, lwork, rwork, iwork, info)
CGGSVD3 computes the singular value decomposition (SVD) for OTHER matrices
Definition cggsvd3.f:354
subroutine cggsvp3(jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola, tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, rwork, tau, work, lwork, info)
CGGSVP3
Definition cggsvp3.f:278
subroutine ctgsja(jobu, jobv, jobq, m, p, n, k, l, a, lda, b, ldb, tola, tolb, alpha, beta, u, ldu, v, ldv, q, ldq, work, ncycle, info)
CTGSJA
Definition ctgsja.f:379