izmax1()

integer function izmax1	(	integer	n,
		complex*16, dimension(*)	zx,
		integer	incx
	)

IZMAX1 finds the index of the first vector element of maximum absolute value.

Download IZMAX1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 IZMAX1 finds the index of the first vector element of maximum absolute value.

 Based on IZAMAX from Level 1 BLAS.
 The change is to use the 'genuine' absolute value.

Parameters

[in]	N	N is INTEGER The number of elements in the vector ZX.
[in]	ZX	ZX is COMPLEX*16 array, dimension (N) The vector ZX. The IZMAX1 function returns the index of its first element of maximum absolute value.
[in]	INCX	INCX is INTEGER The spacing between successive values of ZX. INCX >= 1.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Nick Higham for use with ZLACON.

Definition at line 80 of file izmax1.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         ZX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION   DMAX
      INTEGER            I, IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
      izmax1 = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      izmax1 = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         dmax = abs(zx(1))
         DO i = 2,n
            IF (abs(zx(i)).GT.dmax) THEN
               izmax1 = i
               dmax = abs(zx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         dmax = abs(zx(1))
         ix = ix + incx
         DO i = 2,n
            IF (abs(zx(ix)).GT.dmax) THEN
               izmax1 = i
               dmax = abs(zx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of IZMAX1
*

Here is the call graph for this function:

Here is the caller graph for this function: