LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
stbmv.f
Go to the documentation of this file.
1 *> \brief \b STBMV
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE STBMV(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
12 *
13 * .. Scalar Arguments ..
14 * INTEGER INCX,K,LDA,N
15 * CHARACTER DIAG,TRANS,UPLO
16 * ..
17 * .. Array Arguments ..
18 * REAL A(LDA,*),X(*)
19 * ..
20 *
21 *
22 *> \par Purpose:
23 * =============
24 *>
25 *> \verbatim
26 *>
27 *> STBMV performs one of the matrix-vector operations
28 *>
29 *> x := A*x, or x := A**T*x,
30 *>
31 *> where x is an n element vector and A is an n by n unit, or non-unit,
32 *> upper or lower triangular band matrix, with ( k + 1 ) diagonals.
33 *> \endverbatim
34 *
35 * Arguments:
36 * ==========
37 *
38 *> \param[in] UPLO
39 *> \verbatim
40 *> UPLO is CHARACTER*1
41 *> On entry, UPLO specifies whether the matrix is an upper or
42 *> lower triangular matrix as follows:
43 *>
44 *> UPLO = 'U' or 'u' A is an upper triangular matrix.
45 *>
46 *> UPLO = 'L' or 'l' A is a lower triangular matrix.
47 *> \endverbatim
48 *>
49 *> \param[in] TRANS
50 *> \verbatim
51 *> TRANS is CHARACTER*1
52 *> On entry, TRANS specifies the operation to be performed as
53 *> follows:
54 *>
55 *> TRANS = 'N' or 'n' x := A*x.
56 *>
57 *> TRANS = 'T' or 't' x := A**T*x.
58 *>
59 *> TRANS = 'C' or 'c' x := A**T*x.
60 *> \endverbatim
61 *>
62 *> \param[in] DIAG
63 *> \verbatim
64 *> DIAG is CHARACTER*1
65 *> On entry, DIAG specifies whether or not A is unit
66 *> triangular as follows:
67 *>
68 *> DIAG = 'U' or 'u' A is assumed to be unit triangular.
69 *>
70 *> DIAG = 'N' or 'n' A is not assumed to be unit
71 *> triangular.
72 *> \endverbatim
73 *>
74 *> \param[in] N
75 *> \verbatim
76 *> N is INTEGER
77 *> On entry, N specifies the order of the matrix A.
78 *> N must be at least zero.
79 *> \endverbatim
80 *>
81 *> \param[in] K
82 *> \verbatim
83 *> K is INTEGER
84 *> On entry with UPLO = 'U' or 'u', K specifies the number of
85 *> super-diagonals of the matrix A.
86 *> On entry with UPLO = 'L' or 'l', K specifies the number of
87 *> sub-diagonals of the matrix A.
88 *> K must satisfy 0 .le. K.
89 *> \endverbatim
90 *>
91 *> \param[in] A
92 *> \verbatim
93 *> A is REAL array, dimension ( LDA, N )
94 *> Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
95 *> by n part of the array A must contain the upper triangular
96 *> band part of the matrix of coefficients, supplied column by
97 *> column, with the leading diagonal of the matrix in row
98 *> ( k + 1 ) of the array, the first super-diagonal starting at
99 *> position 2 in row k, and so on. The top left k by k triangle
100 *> of the array A is not referenced.
101 *> The following program segment will transfer an upper
102 *> triangular band matrix from conventional full matrix storage
103 *> to band storage:
104 *>
105 *> DO 20, J = 1, N
106 *> M = K + 1 - J
107 *> DO 10, I = MAX( 1, J - K ), J
108 *> A( M + I, J ) = matrix( I, J )
109 *> 10 CONTINUE
110 *> 20 CONTINUE
111 *>
112 *> Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
113 *> by n part of the array A must contain the lower triangular
114 *> band part of the matrix of coefficients, supplied column by
115 *> column, with the leading diagonal of the matrix in row 1 of
116 *> the array, the first sub-diagonal starting at position 1 in
117 *> row 2, and so on. The bottom right k by k triangle of the
118 *> array A is not referenced.
119 *> The following program segment will transfer a lower
120 *> triangular band matrix from conventional full matrix storage
121 *> to band storage:
122 *>
123 *> DO 20, J = 1, N
124 *> M = 1 - J
125 *> DO 10, I = J, MIN( N, J + K )
126 *> A( M + I, J ) = matrix( I, J )
127 *> 10 CONTINUE
128 *> 20 CONTINUE
129 *>
130 *> Note that when DIAG = 'U' or 'u' the elements of the array A
131 *> corresponding to the diagonal elements of the matrix are not
132 *> referenced, but are assumed to be unity.
133 *> \endverbatim
134 *>
135 *> \param[in] LDA
136 *> \verbatim
137 *> LDA is INTEGER
138 *> On entry, LDA specifies the first dimension of A as declared
139 *> in the calling (sub) program. LDA must be at least
140 *> ( k + 1 ).
141 *> \endverbatim
142 *>
143 *> \param[in,out] X
144 *> \verbatim
145 *> X is REAL array, dimension at least
146 *> ( 1 + ( n - 1 )*abs( INCX ) ).
147 *> Before entry, the incremented array X must contain the n
148 *> element vector x. On exit, X is overwritten with the
149 *> transformed vector x.
150 *> \endverbatim
151 *>
152 *> \param[in] INCX
153 *> \verbatim
154 *> INCX is INTEGER
155 *> On entry, INCX specifies the increment for the elements of
156 *> X. INCX must not be zero.
157 *> \endverbatim
158 *
159 * Authors:
160 * ========
161 *
162 *> \author Univ. of Tennessee
163 *> \author Univ. of California Berkeley
164 *> \author Univ. of Colorado Denver
165 *> \author NAG Ltd.
166 *
167 *> \ingroup single_blas_level2
168 *
169 *> \par Further Details:
170 * =====================
171 *>
172 *> \verbatim
173 *>
174 *> Level 2 Blas routine.
175 *> The vector and matrix arguments are not referenced when N = 0, or M = 0
176 *>
177 *> -- Written on 22-October-1986.
178 *> Jack Dongarra, Argonne National Lab.
179 *> Jeremy Du Croz, Nag Central Office.
180 *> Sven Hammarling, Nag Central Office.
181 *> Richard Hanson, Sandia National Labs.
182 *> \endverbatim
183 *>
184 * =====================================================================
185  SUBROUTINE stbmv(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
186 *
187 * -- Reference BLAS level2 routine --
188 * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
189 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
190 *
191 * .. Scalar Arguments ..
192  INTEGER INCX,K,LDA,N
193  CHARACTER DIAG,TRANS,UPLO
194 * ..
195 * .. Array Arguments ..
196  REAL A(LDA,*),X(*)
197 * ..
198 *
199 * =====================================================================
200 *
201 * .. Parameters ..
202  REAL ZERO
203  parameter(zero=0.0e+0)
204 * ..
205 * .. Local Scalars ..
206  REAL TEMP
207  INTEGER I,INFO,IX,J,JX,KPLUS1,KX,L
208  LOGICAL NOUNIT
209 * ..
210 * .. External Functions ..
211  LOGICAL LSAME
212  EXTERNAL lsame
213 * ..
214 * .. External Subroutines ..
215  EXTERNAL xerbla
216 * ..
217 * .. Intrinsic Functions ..
218  INTRINSIC max,min
219 * ..
220 *
221 * Test the input parameters.
222 *
223  info = 0
224  IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
225  info = 1
226  ELSE IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
227  + .NOT.lsame(trans,'C')) THEN
228  info = 2
229  ELSE IF (.NOT.lsame(diag,'U') .AND. .NOT.lsame(diag,'N')) THEN
230  info = 3
231  ELSE IF (n.LT.0) THEN
232  info = 4
233  ELSE IF (k.LT.0) THEN
234  info = 5
235  ELSE IF (lda.LT. (k+1)) THEN
236  info = 7
237  ELSE IF (incx.EQ.0) THEN
238  info = 9
239  END IF
240  IF (info.NE.0) THEN
241  CALL xerbla('STBMV ',info)
242  RETURN
243  END IF
244 *
245 * Quick return if possible.
246 *
247  IF (n.EQ.0) RETURN
248 *
249  nounit = lsame(diag,'N')
250 *
251 * Set up the start point in X if the increment is not unity. This
252 * will be ( N - 1 )*INCX too small for descending loops.
253 *
254  IF (incx.LE.0) THEN
255  kx = 1 - (n-1)*incx
256  ELSE IF (incx.NE.1) THEN
257  kx = 1
258  END IF
259 *
260 * Start the operations. In this version the elements of A are
261 * accessed sequentially with one pass through A.
262 *
263  IF (lsame(trans,'N')) THEN
264 *
265 * Form x := A*x.
266 *
267  IF (lsame(uplo,'U')) THEN
268  kplus1 = k + 1
269  IF (incx.EQ.1) THEN
270  DO 20 j = 1,n
271  IF (x(j).NE.zero) THEN
272  temp = x(j)
273  l = kplus1 - j
274  DO 10 i = max(1,j-k),j - 1
275  x(i) = x(i) + temp*a(l+i,j)
276  10 CONTINUE
277  IF (nounit) x(j) = x(j)*a(kplus1,j)
278  END IF
279  20 CONTINUE
280  ELSE
281  jx = kx
282  DO 40 j = 1,n
283  IF (x(jx).NE.zero) THEN
284  temp = x(jx)
285  ix = kx
286  l = kplus1 - j
287  DO 30 i = max(1,j-k),j - 1
288  x(ix) = x(ix) + temp*a(l+i,j)
289  ix = ix + incx
290  30 CONTINUE
291  IF (nounit) x(jx) = x(jx)*a(kplus1,j)
292  END IF
293  jx = jx + incx
294  IF (j.GT.k) kx = kx + incx
295  40 CONTINUE
296  END IF
297  ELSE
298  IF (incx.EQ.1) THEN
299  DO 60 j = n,1,-1
300  IF (x(j).NE.zero) THEN
301  temp = x(j)
302  l = 1 - j
303  DO 50 i = min(n,j+k),j + 1,-1
304  x(i) = x(i) + temp*a(l+i,j)
305  50 CONTINUE
306  IF (nounit) x(j) = x(j)*a(1,j)
307  END IF
308  60 CONTINUE
309  ELSE
310  kx = kx + (n-1)*incx
311  jx = kx
312  DO 80 j = n,1,-1
313  IF (x(jx).NE.zero) THEN
314  temp = x(jx)
315  ix = kx
316  l = 1 - j
317  DO 70 i = min(n,j+k),j + 1,-1
318  x(ix) = x(ix) + temp*a(l+i,j)
319  ix = ix - incx
320  70 CONTINUE
321  IF (nounit) x(jx) = x(jx)*a(1,j)
322  END IF
323  jx = jx - incx
324  IF ((n-j).GE.k) kx = kx - incx
325  80 CONTINUE
326  END IF
327  END IF
328  ELSE
329 *
330 * Form x := A**T*x.
331 *
332  IF (lsame(uplo,'U')) THEN
333  kplus1 = k + 1
334  IF (incx.EQ.1) THEN
335  DO 100 j = n,1,-1
336  temp = x(j)
337  l = kplus1 - j
338  IF (nounit) temp = temp*a(kplus1,j)
339  DO 90 i = j - 1,max(1,j-k),-1
340  temp = temp + a(l+i,j)*x(i)
341  90 CONTINUE
342  x(j) = temp
343  100 CONTINUE
344  ELSE
345  kx = kx + (n-1)*incx
346  jx = kx
347  DO 120 j = n,1,-1
348  temp = x(jx)
349  kx = kx - incx
350  ix = kx
351  l = kplus1 - j
352  IF (nounit) temp = temp*a(kplus1,j)
353  DO 110 i = j - 1,max(1,j-k),-1
354  temp = temp + a(l+i,j)*x(ix)
355  ix = ix - incx
356  110 CONTINUE
357  x(jx) = temp
358  jx = jx - incx
359  120 CONTINUE
360  END IF
361  ELSE
362  IF (incx.EQ.1) THEN
363  DO 140 j = 1,n
364  temp = x(j)
365  l = 1 - j
366  IF (nounit) temp = temp*a(1,j)
367  DO 130 i = j + 1,min(n,j+k)
368  temp = temp + a(l+i,j)*x(i)
369  130 CONTINUE
370  x(j) = temp
371  140 CONTINUE
372  ELSE
373  jx = kx
374  DO 160 j = 1,n
375  temp = x(jx)
376  kx = kx + incx
377  ix = kx
378  l = 1 - j
379  IF (nounit) temp = temp*a(1,j)
380  DO 150 i = j + 1,min(n,j+k)
381  temp = temp + a(l+i,j)*x(ix)
382  ix = ix + incx
383  150 CONTINUE
384  x(jx) = temp
385  jx = jx + incx
386  160 CONTINUE
387  END IF
388  END IF
389  END IF
390 *
391  RETURN
392 *
393 * End of STBMV
394 *
395  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine stbmv(UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX)
STBMV
Definition: stbmv.f:186