LAPACK  3.9.0 LAPACK: Linear Algebra PACKage
clanhs.f
Go to the documentation of this file.
1 *> \brief \b CLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhs.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhs.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhs.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANHS( NORM, N, A, LDA, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM
25 * INTEGER LDA, N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX A( LDA, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANHS returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> Hessenberg matrix A.
41 *> \endverbatim
42 *>
43 *> \return CLANHS
44 *> \verbatim
45 *>
46 *> CLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANHS as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] N
71 *> \verbatim
72 *> N is INTEGER
73 *> The order of the matrix A. N >= 0. When N = 0, CLANHS is
74 *> set to zero.
75 *> \endverbatim
76 *>
77 *> \param[in] A
78 *> \verbatim
79 *> A is COMPLEX array, dimension (LDA,N)
80 *> The n by n upper Hessenberg matrix A; the part of A below the
81 *> first sub-diagonal is not referenced.
82 *> \endverbatim
83 *>
84 *> \param[in] LDA
85 *> \verbatim
86 *> LDA is INTEGER
87 *> The leading dimension of the array A. LDA >= max(N,1).
88 *> \endverbatim
89 *>
90 *> \param[out] WORK
91 *> \verbatim
92 *> WORK is REAL array, dimension (MAX(1,LWORK)),
93 *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
94 *> referenced.
95 *> \endverbatim
96 *
97 * Authors:
98 * ========
99 *
100 *> \author Univ. of Tennessee
101 *> \author Univ. of California Berkeley
102 *> \author Univ. of Colorado Denver
103 *> \author NAG Ltd.
104 *
105 *> \date December 2016
106 *
107 *> \ingroup complexOTHERauxiliary
108 *
109 * =====================================================================
110  REAL FUNCTION CLANHS( NORM, N, A, LDA, WORK )
111 *
112 * -- LAPACK auxiliary routine (version 3.7.0) --
113 * -- LAPACK is a software package provided by Univ. of Tennessee, --
114 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
115 * December 2016
116 *
117  IMPLICIT NONE
118 * .. Scalar Arguments ..
119  CHARACTER norm
120  INTEGER lda, n
121 * ..
122 * .. Array Arguments ..
123  REAL work( * )
124  COMPLEX a( lda, * )
125 * ..
126 *
127 * =====================================================================
128 *
129 * .. Parameters ..
130  REAL one, zero
131  parameter( one = 1.0e+0, zero = 0.0e+0 )
132 * ..
133 * .. Local Scalars ..
134  INTEGER i, j
135  REAL sum, value
136 * ..
137 * .. Local Arrays ..
138  REAL ssq( 2 ), colssq( 2 )
139 * ..
140 * .. External Functions ..
141  LOGICAL lsame, sisnan
142  EXTERNAL lsame, sisnan
143 * ..
144 * .. External Subroutines ..
145  EXTERNAL classq, scombssq
146 * ..
147 * .. Intrinsic Functions ..
148  INTRINSIC abs, min, sqrt
149 * ..
150 * .. Executable Statements ..
151 *
152  IF( n.EQ.0 ) THEN
153  VALUE = zero
154  ELSE IF( lsame( norm, 'M' ) ) THEN
155 *
156 * Find max(abs(A(i,j))).
157 *
158  VALUE = zero
159  DO 20 j = 1, n
160  DO 10 i = 1, min( n, j+1 )
161  sum = abs( a( i, j ) )
162  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
163  10 CONTINUE
164  20 CONTINUE
165  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
166 *
167 * Find norm1(A).
168 *
169  VALUE = zero
170  DO 40 j = 1, n
171  sum = zero
172  DO 30 i = 1, min( n, j+1 )
173  sum = sum + abs( a( i, j ) )
174  30 CONTINUE
175  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
176  40 CONTINUE
177  ELSE IF( lsame( norm, 'I' ) ) THEN
178 *
179 * Find normI(A).
180 *
181  DO 50 i = 1, n
182  work( i ) = zero
183  50 CONTINUE
184  DO 70 j = 1, n
185  DO 60 i = 1, min( n, j+1 )
186  work( i ) = work( i ) + abs( a( i, j ) )
187  60 CONTINUE
188  70 CONTINUE
189  VALUE = zero
190  DO 80 i = 1, n
191  sum = work( i )
192  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
193  80 CONTINUE
194  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
195 *
196 * Find normF(A).
197 * SSQ(1) is scale
198 * SSQ(2) is sum-of-squares
199 * For better accuracy, sum each column separately.
200 *
201  ssq( 1 ) = zero
202  ssq( 2 ) = one
203  DO 90 j = 1, n
204  colssq( 1 ) = zero
205  colssq( 2 ) = one
206  CALL classq( min( n, j+1 ), a( 1, j ), 1,
207  \$ colssq( 1 ), colssq( 2 ) )
208  CALL scombssq( ssq, colssq )
209  90 CONTINUE
210  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
211  END IF
212 *
213  clanhs = VALUE
214  RETURN
215 *
216 * End of CLANHS
217 *
218  END
clanhs
real function clanhs(NORM, N, A, LDA, WORK)
CLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clanhs.f:111
classq
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
sisnan
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:61
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
scombssq
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:62