LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zchkhe_aa.f
Go to the documentation of this file.
1*> \brief \b ZCHKHE_AA
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZCHKHE_AA( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
12* THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
13* XACT, WORK, RWORK, IWORK, NOUT )
14*
15* .. Scalar Arguments ..
16* LOGICAL TSTERR
17* INTEGER NN, NNB, NNS, NOUT
18* DOUBLE PRECISION THRESH
19* ..
20* .. Array Arguments ..
21* LOGICAL DOTYPE( * )
22* INTEGER IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
23* DOUBLE PRECISION RWORK( * )
24* COMPLEX*16 A( * ), AFAC( * ), AINV( * ), B( * ),
25* $ WORK( * ), X( * ), XACT( * )
26* ..
27*
28*
29*> \par Purpose:
30* =============
31*>
32*> \verbatim
33*>
34*> ZCHKHE_AA tests ZHETRF_AA, -TRS_AA.
35*> \endverbatim
36*
37* Arguments:
38* ==========
39*
40*> \param[in] DOTYPE
41*> \verbatim
42*> DOTYPE is LOGICAL array, dimension (NTYPES)
43*> The matrix types to be used for testing. Matrices of type j
44*> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
45*> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
46*> \endverbatim
47*>
48*> \param[in] NN
49*> \verbatim
50*> NN is INTEGER
51*> The number of values of N contained in the vector NVAL.
52*> \endverbatim
53*>
54*> \param[in] NVAL
55*> \verbatim
56*> NVAL is INTEGER array, dimension (NN)
57*> The values of the matrix dimension N.
58*> \endverbatim
59*>
60*> \param[in] NNB
61*> \verbatim
62*> NNB is INTEGER
63*> The number of values of NB contained in the vector NBVAL.
64*> \endverbatim
65*>
66*> \param[in] NBVAL
67*> \verbatim
68*> NBVAL is INTEGER array, dimension (NNB)
69*> The values of the blocksize NB.
70*> \endverbatim
71*>
72*> \param[in] NNS
73*> \verbatim
74*> NNS is INTEGER
75*> The number of values of NRHS contained in the vector NSVAL.
76*> \endverbatim
77*>
78*> \param[in] NSVAL
79*> \verbatim
80*> NSVAL is INTEGER array, dimension (NNS)
81*> The values of the number of right hand sides NRHS.
82*> \endverbatim
83*>
84*> \param[in] THRESH
85*> \verbatim
86*> THRESH is DOUBLE PRECISION
87*> The threshold value for the test ratios. A result is
88*> included in the output file if RESULT >= THRESH. To have
89*> every test ratio printed, use THRESH = 0.
90*> \endverbatim
91*>
92*> \param[in] TSTERR
93*> \verbatim
94*> TSTERR is LOGICAL
95*> Flag that indicates whether error exits are to be tested.
96*> \endverbatim
97*>
98*> \param[in] NMAX
99*> \verbatim
100*> NMAX is INTEGER
101*> The maximum value permitted for N, used in dimensioning the
102*> work arrays.
103*> \endverbatim
104*>
105*> \param[out] A
106*> \verbatim
107*> A is COMPLEX*16 array, dimension (NMAX*NMAX)
108*> \endverbatim
109*>
110*> \param[out] AFAC
111*> \verbatim
112*> AFAC is COMPLEX*16 array, dimension (NMAX*NMAX)
113*> \endverbatim
114*>
115*> \param[out] AINV
116*> \verbatim
117*> AINV is COMPLEX*16 array, dimension (NMAX*NMAX)
118*> \endverbatim
119*>
120*> \param[out] B
121*> \verbatim
122*> B is COMPLEX*16 array, dimension (NMAX*NSMAX)
123*> where NSMAX is the largest entry in NSVAL.
124*> \endverbatim
125*>
126*> \param[out] X
127*> \verbatim
128*> X is COMPLEX*16 array, dimension (NMAX*NSMAX)
129*> \endverbatim
130*>
131*> \param[out] XACT
132*> \verbatim
133*> XACT is COMPLEX*16 array, dimension (NMAX*NSMAX)
134*> \endverbatim
135*>
136*> \param[out] WORK
137*> \verbatim
138*> WORK is COMPLEX*16 array, dimension (NMAX*max(3,NSMAX))
139*> \endverbatim
140*>
141*> \param[out] RWORK
142*> \verbatim
143*> RWORK is DOUBLE PRECISION array, dimension (max(NMAX,2*NSMAX))
144*> \endverbatim
145*>
146*> \param[out] IWORK
147*> \verbatim
148*> IWORK is INTEGER array, dimension (NMAX)
149*> \endverbatim
150*>
151*> \param[in] NOUT
152*> \verbatim
153*> NOUT is INTEGER
154*> The unit number for output.
155*> \endverbatim
156*
157* Authors:
158* ========
159*
160*> \author Univ. of Tennessee
161*> \author Univ. of California Berkeley
162*> \author Univ. of Colorado Denver
163*> \author NAG Ltd.
164*
165*> \ingroup complex16_lin
166*
167* =====================================================================
168 SUBROUTINE zchkhe_aa( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
169 $ THRESH, TSTERR, NMAX, A, AFAC, AINV, B,
170 $ X, XACT, WORK, RWORK, IWORK, NOUT )
171*
172* -- LAPACK test routine --
173* -- LAPACK is a software package provided by Univ. of Tennessee, --
174* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
175*
176 IMPLICIT NONE
177*
178* .. Scalar Arguments ..
179 LOGICAL TSTERR
180 INTEGER NMAX, NN, NNB, NNS, NOUT
181 DOUBLE PRECISION THRESH
182* ..
183* .. Array Arguments ..
184 LOGICAL DOTYPE( * )
185 INTEGER IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
186 DOUBLE PRECISION RWORK( * )
187 COMPLEX*16 A( * ), AFAC( * ), AINV( * ), B( * ),
188 $ work( * ), x( * ), xact( * )
189* ..
190*
191* =====================================================================
192*
193* .. Parameters ..
194 DOUBLE PRECISION ZERO
195 PARAMETER ( ZERO = 0.0d+0 )
196 COMPLEX*16 CZERO
197 parameter( czero = ( 0.0d+0, 0.0d+0 ) )
198 INTEGER NTYPES
199 parameter( ntypes = 10 )
200 INTEGER NTESTS
201 parameter( ntests = 9 )
202* ..
203* .. Local Scalars ..
204 LOGICAL ZEROT
205 CHARACTER DIST, TYPE, UPLO, XTYPE
206 CHARACTER*3 PATH, MATPATH
207 INTEGER I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
208 $ iuplo, izero, j, k, kl, ku, lda, lwork, mode,
209 $ n, nb, nerrs, nfail, nimat, nrhs, nrun, nt
210 DOUBLE PRECISION ANORM, CNDNUM
211* ..
212* .. Local Arrays ..
213 CHARACTER UPLOS( 2 )
214 INTEGER ISEED( 4 ), ISEEDY( 4 )
215 DOUBLE PRECISION RESULT( NTESTS )
216* ..
217* .. External Subroutines ..
218 EXTERNAL alaerh, alahd, alasum, xlaenv, zerrhe,
219 $ zhet01_aa, zhetrf_aa, zhetrs_aa, zlacpy,
220 $ zlaipd, zlarhs, zlatb4, zlatms, zpot02
221* ..
222* .. Intrinsic Functions ..
223 INTRINSIC max, min
224* ..
225* .. Scalars in Common ..
226 LOGICAL LERR, OK
227 CHARACTER*32 SRNAMT
228 INTEGER INFOT, NUNIT
229* ..
230* .. Common blocks ..
231 COMMON / infoc / infot, nunit, ok, lerr
232 COMMON / srnamc / srnamt
233* ..
234* .. Data statements ..
235 DATA iseedy / 1988, 1989, 1990, 1991 /
236 DATA uplos / 'U', 'L' /
237* ..
238* .. Executable Statements ..
239*
240* Initialize constants and the random number seed.
241*
242* Test path
243*
244 path( 1: 1 ) = 'Zomplex precision'
245 path( 2: 3 ) = 'HA'
246*
247* Path to generate matrices
248*
249 matpath( 1: 1 ) = 'Zomplex precision'
250 matpath( 2: 3 ) = 'HE'
251 nrun = 0
252 nfail = 0
253 nerrs = 0
254 DO 10 i = 1, 4
255 iseed( i ) = iseedy( i )
256 10 CONTINUE
257*
258* Test the error exits
259*
260 IF( tsterr )
261 $ CALL zerrhe( path, nout )
262 infot = 0
263*
264* Set the minimum block size for which the block routine should
265* be used, which will be later returned by ILAENV
266*
267 CALL xlaenv( 2, 2 )
268*
269* Do for each value of N in NVAL
270*
271 DO 180 in = 1, nn
272 n = nval( in )
273 IF( n .GT. nmax ) THEN
274 nfail = nfail + 1
275 WRITE(nout, 9995) 'M ', n, nmax
276 GO TO 180
277 END IF
278 lda = max( n, 1 )
279 xtype = 'N'
280 nimat = ntypes
281 IF( n.LE.0 )
282 $ nimat = 1
283*
284 izero = 0
285 DO 170 imat = 1, nimat
286*
287* Do the tests only if DOTYPE( IMAT ) is true.
288*
289 IF( .NOT.dotype( imat ) )
290 $ GO TO 170
291*
292* Skip types 3, 4, 5, or 6 if the matrix size is too small.
293*
294 zerot = imat.GE.3 .AND. imat.LE.6
295 IF( zerot .AND. n.LT.imat-2 )
296 $ GO TO 170
297*
298* Do first for UPLO = 'U', then for UPLO = 'L'
299*
300 DO 160 iuplo = 1, 2
301 uplo = uplos( iuplo )
302*
303* Set up parameters with ZLATB4 for the matrix generator
304* based on the type of matrix to be generated.
305*
306 CALL zlatb4( matpath, imat, n, n, TYPE, kl, ku,
307 $ anorm, mode, cndnum, dist )
308*
309* Generate a matrix with ZLATMS.
310*
311 srnamt = 'ZLATMS'
312 CALL zlatms( n, n, dist, iseed, TYPE, rwork, mode,
313 $ cndnum, anorm, kl, ku, uplo, a, lda, work,
314 $ info )
315*
316* Check error code from ZLATMS and handle error.
317*
318 IF( info.NE.0 ) THEN
319 CALL alaerh( path, 'ZLATMS', info, 0, uplo, n, n, -1,
320 $ -1, -1, imat, nfail, nerrs, nout )
321*
322* Skip all tests for this generated matrix
323*
324 GO TO 160
325 END IF
326*
327* For types 3-6, zero one or more rows and columns of
328* the matrix to test that INFO is returned correctly.
329*
330 IF( zerot ) THEN
331 IF( imat.EQ.3 ) THEN
332 izero = 1
333 ELSE IF( imat.EQ.4 ) THEN
334 izero = n
335 ELSE
336 izero = n / 2 + 1
337 END IF
338*
339 IF( imat.LT.6 ) THEN
340*
341* Set row and column IZERO to zero.
342*
343 IF( iuplo.EQ.1 ) THEN
344 ioff = ( izero-1 )*lda
345 DO 20 i = 1, izero - 1
346 a( ioff+i ) = czero
347 20 CONTINUE
348 ioff = ioff + izero
349 DO 30 i = izero, n
350 a( ioff ) = czero
351 ioff = ioff + lda
352 30 CONTINUE
353 ELSE
354 ioff = izero
355 DO 40 i = 1, izero - 1
356 a( ioff ) = czero
357 ioff = ioff + lda
358 40 CONTINUE
359 ioff = ioff - izero
360 DO 50 i = izero, n
361 a( ioff+i ) = czero
362 50 CONTINUE
363 END IF
364 ELSE
365 IF( iuplo.EQ.1 ) THEN
366*
367* Set the first IZERO rows and columns to zero.
368*
369 ioff = 0
370 DO 70 j = 1, n
371 i2 = min( j, izero )
372 DO 60 i = 1, i2
373 a( ioff+i ) = czero
374 60 CONTINUE
375 ioff = ioff + lda
376 70 CONTINUE
377 izero = 1
378 ELSE
379*
380* Set the last IZERO rows and columns to zero.
381*
382 ioff = 0
383 DO 90 j = 1, n
384 i1 = max( j, izero )
385 DO 80 i = i1, n
386 a( ioff+i ) = czero
387 80 CONTINUE
388 ioff = ioff + lda
389 90 CONTINUE
390 END IF
391 END IF
392 ELSE
393 izero = 0
394 END IF
395*
396* End generate test matrix A.
397*
398*
399* Set the imaginary part of the diagonals.
400*
401 CALL zlaipd( n, a, lda+1, 0 )
402*
403* Do for each value of NB in NBVAL
404*
405 DO 150 inb = 1, nnb
406*
407* Set the optimal blocksize, which will be later
408* returned by ILAENV.
409*
410 nb = nbval( inb )
411 CALL xlaenv( 1, nb )
412*
413* Copy the test matrix A into matrix AFAC which
414* will be factorized in place. This is needed to
415* preserve the test matrix A for subsequent tests.
416*
417 CALL zlacpy( uplo, n, n, a, lda, afac, lda )
418*
419* Compute the L*D*L**T or U*D*U**T factorization of the
420* matrix. IWORK stores details of the interchanges and
421* the block structure of D. AINV is a work array for
422* block factorization, LWORK is the length of AINV.
423*
424 lwork = max( 1, ( nb+1 )*lda )
425 srnamt = 'ZHETRF_AA'
426 CALL zhetrf_aa( uplo, n, afac, lda, iwork, ainv,
427 $ lwork, info )
428*
429* Adjust the expected value of INFO to account for
430* pivoting.
431*
432c IF( IZERO.GT.0 ) THEN
433c J = 1
434c K = IZERO
435c 100 CONTINUE
436c IF( J.EQ.K ) THEN
437c K = IWORK( J )
438c ELSE IF( IWORK( J ).EQ.K ) THEN
439c K = J
440c END IF
441c IF( J.LT.K ) THEN
442c J = J + 1
443c GO TO 100
444c END IF
445c ELSE
446 k = 0
447c END IF
448*
449* Check error code from ZHETRF and handle error.
450*
451 IF( info.NE.k ) THEN
452 CALL alaerh( path, 'ZHETRF_AA', info, k, uplo,
453 $ n, n, -1, -1, nb, imat, nfail, nerrs,
454 $ nout )
455 END IF
456*
457*+ TEST 1
458* Reconstruct matrix from factors and compute residual.
459*
460 CALL zhet01_aa( uplo, n, a, lda, afac, lda, iwork,
461 $ ainv, lda, rwork, result( 1 ) )
462 nt = 1
463*
464*
465* Print information about the tests that did not pass
466* the threshold.
467*
468 DO 110 k = 1, nt
469 IF( result( k ).GE.thresh ) THEN
470 IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
471 $ CALL alahd( nout, path )
472 WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
473 $ result( k )
474 nfail = nfail + 1
475 END IF
476 110 CONTINUE
477 nrun = nrun + nt
478*
479* Skip solver test if INFO is not 0.
480*
481 IF( info.NE.0 ) THEN
482 GO TO 140
483 END IF
484*
485* Do for each value of NRHS in NSVAL.
486*
487 DO 130 irhs = 1, nns
488 nrhs = nsval( irhs )
489*
490*+ TEST 2 (Using TRS)
491* Solve and compute residual for A * X = B.
492*
493* Choose a set of NRHS random solution vectors
494* stored in XACT and set up the right hand side B
495*
496 srnamt = 'ZLARHS'
497 CALL zlarhs( matpath, xtype, uplo, ' ', n, n,
498 $ kl, ku, nrhs, a, lda, xact, lda,
499 $ b, lda, iseed, info )
500 CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
501*
502 srnamt = 'ZHETRS_AA'
503 lwork = max( 1, 3*n-2 )
504 CALL zhetrs_aa( uplo, n, nrhs, afac, lda, iwork,
505 $ x, lda, work, lwork, info )
506*
507* Check error code from ZHETRS and handle error.
508*
509 IF( info.NE.0 ) THEN
510 IF( izero.EQ.0 ) THEN
511 CALL alaerh( path, 'ZHETRS_AA', info, 0,
512 $ uplo, n, n, -1, -1, nrhs, imat,
513 $ nfail, nerrs, nout )
514 END IF
515 ELSE
516*
517 CALL zlacpy( 'Full', n, nrhs, b, lda, work, lda
518 $ )
519*
520* Compute the residual for the solution
521*
522 CALL zpot02( uplo, n, nrhs, a, lda, x, lda,
523 $ work, lda, rwork, result( 2 ) )
524*
525* Print information about the tests that did not pass
526* the threshold.
527*
528 DO 120 k = 2, 2
529 IF( result( k ).GE.thresh ) THEN
530 IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
531 $ CALL alahd( nout, path )
532 WRITE( nout, fmt = 9998 )uplo, n, nrhs,
533 $ imat, k, result( k )
534 nfail = nfail + 1
535 END IF
536 120 CONTINUE
537 END IF
538 nrun = nrun + 1
539*
540* End do for each value of NRHS in NSVAL.
541*
542 130 CONTINUE
543 140 CONTINUE
544 150 CONTINUE
545 160 CONTINUE
546 170 CONTINUE
547 180 CONTINUE
548*
549* Print a summary of the results.
550*
551 CALL alasum( path, nout, nfail, nrun, nerrs )
552*
553 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
554 $ i2, ', test ', i2, ', ratio =', g12.5 )
555 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
556 $ i2, ', test(', i2, ') =', g12.5 )
557c 9997 FORMAT( ' UPLO = ''', A1, ''', N =', I5, ',', 10X, ' type ', I2,
558c $ ', test(', I2, ') =', G12.5 )
559 9995 FORMAT( ' Invalid input value: ', a4, '=', i6, '; must be <=',
560 $ i6 )
561 RETURN
562*
563* End of ZCHKHE_AA
564*
565 END
alasum
subroutine alasum(type, nout, nfail, nrun, nerrs)
ALASUM
Definition alasum.f:73
xlaenv
subroutine xlaenv(ispec, nvalue)
XLAENV
Definition xlaenv.f:81
zlarhs
subroutine zlarhs(path, xtype, uplo, trans, m, n, kl, ku, nrhs, a, lda, x, ldx, b, ldb, iseed, info)
ZLARHS
Definition zlarhs.f:208
alaerh
subroutine alaerh(path, subnam, info, infoe, opts, m, n, kl, ku, n5, imat, nfail, nerrs, nout)
ALAERH
Definition alaerh.f:147
alahd
subroutine alahd(iounit, path)
ALAHD
Definition alahd.f:107
zhetrf_aa
subroutine zhetrf_aa(uplo, n, a, lda, ipiv, work, lwork, info)
ZHETRF_AA
Definition zhetrf_aa.f:132
zhetrs_aa
subroutine zhetrs_aa(uplo, n, nrhs, a, lda, ipiv, b, ldb, work, lwork, info)
ZHETRS_AA
Definition zhetrs_aa.f:132
zlacpy
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:103
zchkhe_aa
subroutine zchkhe_aa(dotype, nn, nval, nnb, nbval, nns, nsval, thresh, tsterr, nmax, a, afac, ainv, b, x, xact, work, rwork, iwork, nout)
ZCHKHE_AA
Definition zchkhe_aa.f:171
zerrhe
subroutine zerrhe(path, nunit)
ZERRHE
Definition zerrhe.f:55
zhet01_aa
subroutine zhet01_aa(uplo, n, a, lda, afac, ldafac, ipiv, c, ldc, rwork, resid)
ZHET01_AA
Definition zhet01_aa.f:124
zlaipd
subroutine zlaipd(n, a, inda, vinda)
ZLAIPD
Definition zlaipd.f:83
zlatb4
subroutine zlatb4(path, imat, m, n, type, kl, ku, anorm, mode, cndnum, dist)
ZLATB4
Definition zlatb4.f:121
zlatms
subroutine zlatms(m, n, dist, iseed, sym, d, mode, cond, dmax, kl, ku, pack, a, lda, work, info)
ZLATMS
Definition zlatms.f:332
zpot02
subroutine zpot02(uplo, n, nrhs, a, lda, x, ldx, b, ldb, rwork, resid)
ZPOT02
Definition zpot02.f:127