double precision function dlarnd	(	integer	IDIST,
		integer, dimension( 4 )	ISEED
	)

DLARND

Purpose:

 DLARND returns a random real number from a uniform or normal
 distribution.

Parameters

[in]

IDIST

          IDIST is INTEGER
          Specifies the distribution of the random numbers:
          = 1:  uniform (0,1)
          = 2:  uniform (-1,1)
          = 3:  normal (0,1)

[in,out]

ISEED

          ISEED is INTEGER array, dimension (4)
          On entry, the seed of the random number generator; the array
          elements must be between 0 and 4095, and ISEED(4) must be
          odd.
          On exit, the seed is updated.

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Date: November 2011

Further Details:

  This routine calls the auxiliary routine DLARAN to generate a random
  real number from a uniform (0,1) distribution. The Box-Muller method
  is used to transform numbers from a uniform to a normal distribution.

Definition at line 75 of file dlarnd.f.

 *
 *  -- LAPACK auxiliary routine (version 3.4.0) --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *     November 2011
 *
 *     .. Scalar Arguments ..
       INTEGER            idist
 *     ..
 *     .. Array Arguments ..
       INTEGER            iseed( 4 )
 *     ..
 *
 *  =====================================================================
 *
 *     .. Parameters ..
       DOUBLE PRECISION   one, two
       parameter                ( one = 1.0d+0, two = 2.0d+0 )
       DOUBLE PRECISION   twopi
       parameter                ( twopi = 6.2831853071795864769252867663d+0 )
 *     ..
 *     .. Local Scalars ..
       DOUBLE PRECISION   t1, t2
 *     ..
 *     .. External Functions ..
       DOUBLE PRECISION   dlaran
       EXTERNAL           dlaran
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          cos, log, sqrt
 *     ..
 *     .. Executable Statements ..
 *
 *     Generate a real random number from a uniform (0,1) distribution
 *
       t1 = dlaran( iseed )
 *
       IF( idist.EQ.1 ) THEN
 *
 *        uniform (0,1)
 *
          dlarnd = t1
       ELSE IF( idist.EQ.2 ) THEN
 *
 *        uniform (-1,1)
 *
          dlarnd = two*t1 - one
       ELSE IF( idist.EQ.3 ) THEN
 *
 *        normal (0,1)
 *
          t2 = dlaran( iseed )
          dlarnd = sqrt( -two*log( t1 ) )*cos( twopi*t2 )
       END IF
       RETURN
 *
 *     End of DLARND
 *