001:       SUBROUTINE CUNMBR( VECT, SIDE, TRANS, M, N, K, A, LDA, TAU, C,
002:      $                   LDC, WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS, VECT
011:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  If VECT = 'Q', CUNMBR overwrites the general complex M-by-N matrix C
022: *  with
023: *                  SIDE = 'L'     SIDE = 'R'
024: *  TRANS = 'N':      Q * C          C * Q
025: *  TRANS = 'C':      Q**H * C       C * Q**H
026: *
027: *  If VECT = 'P', CUNMBR overwrites the general complex M-by-N matrix C
028: *  with
029: *                  SIDE = 'L'     SIDE = 'R'
030: *  TRANS = 'N':      P * C          C * P
031: *  TRANS = 'C':      P**H * C       C * P**H
032: *
033: *  Here Q and P**H are the unitary matrices determined by CGEBRD when
034: *  reducing a complex matrix A to bidiagonal form: A = Q * B * P**H. Q
035: *  and P**H are defined as products of elementary reflectors H(i) and
036: *  G(i) respectively.
037: *
038: *  Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
039: *  order of the unitary matrix Q or P**H that is applied.
040: *
041: *  If VECT = 'Q', A is assumed to have been an NQ-by-K matrix:
042: *  if nq >= k, Q = H(1) H(2) . . . H(k);
043: *  if nq < k, Q = H(1) H(2) . . . H(nq-1).
044: *
045: *  If VECT = 'P', A is assumed to have been a K-by-NQ matrix:
046: *  if k < nq, P = G(1) G(2) . . . G(k);
047: *  if k >= nq, P = G(1) G(2) . . . G(nq-1).
048: *
049: *  Arguments
050: *  =========
051: *
052: *  VECT    (input) CHARACTER*1
053: *          = 'Q': apply Q or Q**H;
054: *          = 'P': apply P or P**H.
055: *
056: *  SIDE    (input) CHARACTER*1
057: *          = 'L': apply Q, Q**H, P or P**H from the Left;
058: *          = 'R': apply Q, Q**H, P or P**H from the Right.
059: *
060: *  TRANS   (input) CHARACTER*1
061: *          = 'N':  No transpose, apply Q or P;
062: *          = 'C':  Conjugate transpose, apply Q**H or P**H.
063: *
064: *  M       (input) INTEGER
065: *          The number of rows of the matrix C. M >= 0.
066: *
067: *  N       (input) INTEGER
068: *          The number of columns of the matrix C. N >= 0.
069: *
070: *  K       (input) INTEGER
071: *          If VECT = 'Q', the number of columns in the original
072: *          matrix reduced by CGEBRD.
073: *          If VECT = 'P', the number of rows in the original
074: *          matrix reduced by CGEBRD.
075: *          K >= 0.
076: *
077: *  A       (input) COMPLEX array, dimension
078: *                                (LDA,min(nq,K)) if VECT = 'Q'
079: *                                (LDA,nq)        if VECT = 'P'
080: *          The vectors which define the elementary reflectors H(i) and
081: *          G(i), whose products determine the matrices Q and P, as
082: *          returned by CGEBRD.
083: *
084: *  LDA     (input) INTEGER
085: *          The leading dimension of the array A.
086: *          If VECT = 'Q', LDA >= max(1,nq);
087: *          if VECT = 'P', LDA >= max(1,min(nq,K)).
088: *
089: *  TAU     (input) COMPLEX array, dimension (min(nq,K))
090: *          TAU(i) must contain the scalar factor of the elementary
091: *          reflector H(i) or G(i) which determines Q or P, as returned
092: *          by CGEBRD in the array argument TAUQ or TAUP.
093: *
094: *  C       (input/output) COMPLEX array, dimension (LDC,N)
095: *          On entry, the M-by-N matrix C.
096: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q
097: *          or P*C or P**H*C or C*P or C*P**H.
098: *
099: *  LDC     (input) INTEGER
100: *          The leading dimension of the array C. LDC >= max(1,M).
101: *
102: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
103: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
104: *
105: *  LWORK   (input) INTEGER
106: *          The dimension of the array WORK.
107: *          If SIDE = 'L', LWORK >= max(1,N);
108: *          if SIDE = 'R', LWORK >= max(1,M);
109: *          if N = 0 or M = 0, LWORK >= 1.
110: *          For optimum performance LWORK >= max(1,N*NB) if SIDE = 'L',
111: *          and LWORK >= max(1,M*NB) if SIDE = 'R', where NB is the
112: *          optimal blocksize. (NB = 0 if M = 0 or N = 0.)
113: *
114: *          If LWORK = -1, then a workspace query is assumed; the routine
115: *          only calculates the optimal size of the WORK array, returns
116: *          this value as the first entry of the WORK array, and no error
117: *          message related to LWORK is issued by XERBLA.
118: *
119: *  INFO    (output) INTEGER
120: *          = 0:  successful exit
121: *          < 0:  if INFO = -i, the i-th argument had an illegal value
122: *
123: *  =====================================================================
124: *
125: *     .. Local Scalars ..
126:       LOGICAL            APPLYQ, LEFT, LQUERY, NOTRAN
127:       CHARACTER          TRANST
128:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
129: *     ..
130: *     .. External Functions ..
131:       LOGICAL            LSAME
132:       INTEGER            ILAENV
133:       EXTERNAL           ILAENV, LSAME
134: *     ..
135: *     .. External Subroutines ..
136:       EXTERNAL           CUNMLQ, CUNMQR, XERBLA
137: *     ..
138: *     .. Intrinsic Functions ..
139:       INTRINSIC          MAX, MIN
140: *     ..
141: *     .. Executable Statements ..
142: *
143: *     Test the input arguments
144: *
145:       INFO = 0
146:       APPLYQ = LSAME( VECT, 'Q' )
147:       LEFT = LSAME( SIDE, 'L' )
148:       NOTRAN = LSAME( TRANS, 'N' )
149:       LQUERY = ( LWORK.EQ.-1 )
150: *
151: *     NQ is the order of Q or P and NW is the minimum dimension of WORK
152: *
153:       IF( LEFT ) THEN
154:          NQ = M
155:          NW = N
156:       ELSE
157:          NQ = N
158:          NW = M
159:       END IF
160:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
161:          NW = 0
162:       END IF
163:       IF( .NOT.APPLYQ .AND. .NOT.LSAME( VECT, 'P' ) ) THEN
164:          INFO = -1
165:       ELSE IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
166:          INFO = -2
167:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
168:          INFO = -3
169:       ELSE IF( M.LT.0 ) THEN
170:          INFO = -4
171:       ELSE IF( N.LT.0 ) THEN
172:          INFO = -5
173:       ELSE IF( K.LT.0 ) THEN
174:          INFO = -6
175:       ELSE IF( ( APPLYQ .AND. LDA.LT.MAX( 1, NQ ) ) .OR.
176:      $         ( .NOT.APPLYQ .AND. LDA.LT.MAX( 1, MIN( NQ, K ) ) ) )
177:      $          THEN
178:          INFO = -8
179:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
180:          INFO = -11
181:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
182:          INFO = -13
183:       END IF
184: *
185:       IF( INFO.EQ.0 ) THEN
186:          IF( NW.GT.0 ) THEN
187:             IF( APPLYQ ) THEN
188:                IF( LEFT ) THEN
189:                   NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, M-1, N, M-1,
190:      $                         -1 )
191:                ELSE
192:                   NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, M, N-1, N-1,
193:      $                         -1 )
194:                END IF
195:             ELSE
196:                IF( LEFT ) THEN
197:                   NB = ILAENV( 1, 'CUNMLQ', SIDE // TRANS, M-1, N, M-1,
198:      $                         -1 )
199:                ELSE
200:                   NB = ILAENV( 1, 'CUNMLQ', SIDE // TRANS, M, N-1, N-1,
201:      $                         -1 )
202:                END IF
203:             END IF
204:             LWKOPT = MAX( 1, NW*NB )
205:          ELSE
206:             LWKOPT = 1
207:          END IF
208:          WORK( 1 ) = LWKOPT
209:       END IF
210: *
211:       IF( INFO.NE.0 ) THEN
212:          CALL XERBLA( 'CUNMBR', -INFO )
213:          RETURN
214:       ELSE IF( LQUERY ) THEN
215:          RETURN
216:       END IF
217: *
218: *     Quick return if possible
219: *
220:       IF( M.EQ.0 .OR. N.EQ.0 )
221:      $   RETURN
222: *
223:       IF( APPLYQ ) THEN
224: *
225: *        Apply Q
226: *
227:          IF( NQ.GE.K ) THEN
228: *
229: *           Q was determined by a call to CGEBRD with nq >= k
230: *
231:             CALL CUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
232:      $                   WORK, LWORK, IINFO )
233:          ELSE IF( NQ.GT.1 ) THEN
234: *
235: *           Q was determined by a call to CGEBRD with nq < k
236: *
237:             IF( LEFT ) THEN
238:                MI = M - 1
239:                NI = N
240:                I1 = 2
241:                I2 = 1
242:             ELSE
243:                MI = M
244:                NI = N - 1
245:                I1 = 1
246:                I2 = 2
247:             END IF
248:             CALL CUNMQR( SIDE, TRANS, MI, NI, NQ-1, A( 2, 1 ), LDA, TAU,
249:      $                   C( I1, I2 ), LDC, WORK, LWORK, IINFO )
250:          END IF
251:       ELSE
252: *
253: *        Apply P
254: *
255:          IF( NOTRAN ) THEN
256:             TRANST = 'C'
257:          ELSE
258:             TRANST = 'N'
259:          END IF
260:          IF( NQ.GT.K ) THEN
261: *
262: *           P was determined by a call to CGEBRD with nq > k
263: *
264:             CALL CUNMLQ( SIDE, TRANST, M, N, K, A, LDA, TAU, C, LDC,
265:      $                   WORK, LWORK, IINFO )
266:          ELSE IF( NQ.GT.1 ) THEN
267: *
268: *           P was determined by a call to CGEBRD with nq <= k
269: *
270:             IF( LEFT ) THEN
271:                MI = M - 1
272:                NI = N
273:                I1 = 2
274:                I2 = 1
275:             ELSE
276:                MI = M
277:                NI = N - 1
278:                I1 = 1
279:                I2 = 2
280:             END IF
281:             CALL CUNMLQ( SIDE, TRANST, MI, NI, NQ-1, A( 1, 2 ), LDA,
282:      $                   TAU, C( I1, I2 ), LDC, WORK, LWORK, IINFO )
283:          END IF
284:       END IF
285:       WORK( 1 ) = LWKOPT
286:       RETURN
287: *
288: *     End of CUNMBR
289: *
290:       END
291: