001:       SUBROUTINE CUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  CUNMQR overwrites the general complex M-by-N matrix C with
022: *
023: *                  SIDE = 'L'     SIDE = 'R'
024: *  TRANS = 'N':      Q * C          C * Q
025: *  TRANS = 'C':      Q**H * C       C * Q**H
026: *
027: *  where Q is a complex unitary matrix defined as the product of k
028: *  elementary reflectors
029: *
030: *        Q = H(1) H(2) . . . H(k)
031: *
032: *  as returned by CGEQRF. Q is of order M if SIDE = 'L' and of order N
033: *  if SIDE = 'R'.
034: *
035: *  Arguments
036: *  =========
037: *
038: *  SIDE    (input) CHARACTER*1
039: *          = 'L': apply Q or Q**H from the Left;
040: *          = 'R': apply Q or Q**H from the Right.
041: *
042: *  TRANS   (input) CHARACTER*1
043: *          = 'N':  No transpose, apply Q;
044: *          = 'C':  Conjugate transpose, apply Q**H.
045: *
046: *  M       (input) INTEGER
047: *          The number of rows of the matrix C. M >= 0.
048: *
049: *  N       (input) INTEGER
050: *          The number of columns of the matrix C. N >= 0.
051: *
052: *  K       (input) INTEGER
053: *          The number of elementary reflectors whose product defines
054: *          the matrix Q.
055: *          If SIDE = 'L', M >= K >= 0;
056: *          if SIDE = 'R', N >= K >= 0.
057: *
058: *  A       (input) COMPLEX array, dimension (LDA,K)
059: *          The i-th column must contain the vector which defines the
060: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
061: *          CGEQRF in the first k columns of its array argument A.
062: *          A is modified by the routine but restored on exit.
063: *
064: *  LDA     (input) INTEGER
065: *          The leading dimension of the array A.
066: *          If SIDE = 'L', LDA >= max(1,M);
067: *          if SIDE = 'R', LDA >= max(1,N).
068: *
069: *  TAU     (input) COMPLEX array, dimension (K)
070: *          TAU(i) must contain the scalar factor of the elementary
071: *          reflector H(i), as returned by CGEQRF.
072: *
073: *  C       (input/output) COMPLEX array, dimension (LDC,N)
074: *          On entry, the M-by-N matrix C.
075: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
076: *
077: *  LDC     (input) INTEGER
078: *          The leading dimension of the array C. LDC >= max(1,M).
079: *
080: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
081: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
082: *
083: *  LWORK   (input) INTEGER
084: *          The dimension of the array WORK.
085: *          If SIDE = 'L', LWORK >= max(1,N);
086: *          if SIDE = 'R', LWORK >= max(1,M).
087: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
088: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
089: *          blocksize.
090: *
091: *          If LWORK = -1, then a workspace query is assumed; the routine
092: *          only calculates the optimal size of the WORK array, returns
093: *          this value as the first entry of the WORK array, and no error
094: *          message related to LWORK is issued by XERBLA.
095: *
096: *  INFO    (output) INTEGER
097: *          = 0:  successful exit
098: *          < 0:  if INFO = -i, the i-th argument had an illegal value
099: *
100: *  =====================================================================
101: *
102: *     .. Parameters ..
103:       INTEGER            NBMAX, LDT
104:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
105: *     ..
106: *     .. Local Scalars ..
107:       LOGICAL            LEFT, LQUERY, NOTRAN
108:       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK,
109:      $                   LWKOPT, MI, NB, NBMIN, NI, NQ, NW
110: *     ..
111: *     .. Local Arrays ..
112:       COMPLEX            T( LDT, NBMAX )
113: *     ..
114: *     .. External Functions ..
115:       LOGICAL            LSAME
116:       INTEGER            ILAENV
117:       EXTERNAL           LSAME, ILAENV
118: *     ..
119: *     .. External Subroutines ..
120:       EXTERNAL           CLARFB, CLARFT, CUNM2R, XERBLA
121: *     ..
122: *     .. Intrinsic Functions ..
123:       INTRINSIC          MAX, MIN
124: *     ..
125: *     .. Executable Statements ..
126: *
127: *     Test the input arguments
128: *
129:       INFO = 0
130:       LEFT = LSAME( SIDE, 'L' )
131:       NOTRAN = LSAME( TRANS, 'N' )
132:       LQUERY = ( LWORK.EQ.-1 )
133: *
134: *     NQ is the order of Q and NW is the minimum dimension of WORK
135: *
136:       IF( LEFT ) THEN
137:          NQ = M
138:          NW = N
139:       ELSE
140:          NQ = N
141:          NW = M
142:       END IF
143:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
144:          INFO = -1
145:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
146:          INFO = -2
147:       ELSE IF( M.LT.0 ) THEN
148:          INFO = -3
149:       ELSE IF( N.LT.0 ) THEN
150:          INFO = -4
151:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
152:          INFO = -5
153:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
154:          INFO = -7
155:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
156:          INFO = -10
157:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
158:          INFO = -12
159:       END IF
160: *
161:       IF( INFO.EQ.0 ) THEN
162: *
163: *        Determine the block size.  NB may be at most NBMAX, where NBMAX
164: *        is used to define the local array T.
165: *
166:          NB = MIN( NBMAX, ILAENV( 1, 'CUNMQR', SIDE // TRANS, M, N, K,
167:      $        -1 ) )
168:          LWKOPT = MAX( 1, NW )*NB
169:          WORK( 1 ) = LWKOPT
170:       END IF
171: *
172:       IF( INFO.NE.0 ) THEN
173:          CALL XERBLA( 'CUNMQR', -INFO )
174:          RETURN
175:       ELSE IF( LQUERY ) THEN
176:          RETURN
177:       END IF
178: *
179: *     Quick return if possible
180: *
181:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
182:          WORK( 1 ) = 1
183:          RETURN
184:       END IF
185: *
186:       NBMIN = 2
187:       LDWORK = NW
188:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
189:          IWS = NW*NB
190:          IF( LWORK.LT.IWS ) THEN
191:             NB = LWORK / LDWORK
192:             NBMIN = MAX( 2, ILAENV( 2, 'CUNMQR', SIDE // TRANS, M, N, K,
193:      $              -1 ) )
194:          END IF
195:       ELSE
196:          IWS = NW
197:       END IF
198: *
199:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
200: *
201: *        Use unblocked code
202: *
203:          CALL CUNM2R( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
204:      $                IINFO )
205:       ELSE
206: *
207: *        Use blocked code
208: *
209:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
210:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
211:             I1 = 1
212:             I2 = K
213:             I3 = NB
214:          ELSE
215:             I1 = ( ( K-1 ) / NB )*NB + 1
216:             I2 = 1
217:             I3 = -NB
218:          END IF
219: *
220:          IF( LEFT ) THEN
221:             NI = N
222:             JC = 1
223:          ELSE
224:             MI = M
225:             IC = 1
226:          END IF
227: *
228:          DO 10 I = I1, I2, I3
229:             IB = MIN( NB, K-I+1 )
230: *
231: *           Form the triangular factor of the block reflector
232: *           H = H(i) H(i+1) . . . H(i+ib-1)
233: *
234:             CALL CLARFT( 'Forward', 'Columnwise', NQ-I+1, IB, A( I, I ),
235:      $                   LDA, TAU( I ), T, LDT )
236:             IF( LEFT ) THEN
237: *
238: *              H or H' is applied to C(i:m,1:n)
239: *
240:                MI = M - I + 1
241:                IC = I
242:             ELSE
243: *
244: *              H or H' is applied to C(1:m,i:n)
245: *
246:                NI = N - I + 1
247:                JC = I
248:             END IF
249: *
250: *           Apply H or H'
251: *
252:             CALL CLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI,
253:      $                   IB, A( I, I ), LDA, T, LDT, C( IC, JC ), LDC,
254:      $                   WORK, LDWORK )
255:    10    CONTINUE
256:       END IF
257:       WORK( 1 ) = LWKOPT
258:       RETURN
259: *
260: *     End of CUNMQR
261: *
262:       END
263: