rdbtin()

subroutine rdbtin	(	logical	testsdrv,
		logical	testbsbr,
		logical	testcomb,
		logical	testaux,
		integer	nprec,
		character*1, dimension(*)	prec,
		integer	verb,
		integer	outnum
	)

Definition at line 1143 of file blacstest.f.

*
*  -- BLACS tester (version 1.0) --
*  University of Tennessee
*  December 15, 1994
*
*
*     .. Scalar Arguments ..
      LOGICAL TESTSDRV, TESTBSBR, TESTCOMB, TESTAUX
      INTEGER NPREC, OUTNUM, VERB
*     ..
*     .. Array Arguments ..
      CHARACTER*1 PREC(*)
*     ..
*
*  Purpose
*  =======
*  RDBTIN:  Read and process the top-level input file BT.dat.
*
*  Arguments
*  =========
*  TESTSDRV (output) LOGICAL
*           Run any point-to-point tests?
*
*  TESTBSBR (output) LOGICAL
*           Run any broadcast tests?
*
*  TESTCOMB (output) LOGICAL
*           Run any combine-operation tests (e.g. MAX)
*
*  TESTAUX  (output) LOGICAL
*           Run any auxiliary tests?
*
*  NPREC    (output) INTEGER
*           Number of different precisions to test. (up to 5, as determined
*           by the parameter PRECMAX down in the code.)
*
*  PREC     (output) CHARACTER*1 array, dimension 5
*           Prefix letter of each precision to test, from the set
*           {'C', 'D', 'I', 'S', 'Z'}
*
*  VERB     (output) INTEGER
*           Output verbosity for this test run.
*            0 = Print only "BEGIN [SDRV/BSBR/COMB]", followed by PASSED
*                or FAILED message
*            1 = Same as 0, but also prints out header explaining all tests
*                to be run.
*            2 = Prints out info before and after every individual test.
*
*  OUTNUM   (output) INTEGER
*           Unit number for output file.
*  ======================================================================
*
*
*     .. Parameters ..
      INTEGER PRECMAX, VERBMAX, IN
      parameter( precmax = 5, verbmax = 2, in = 11 )
*     ..
*     .. Local Scalars ..
      INTEGER I
      CHARACTER*1 CH
      LOGICAL READERROR
*     ..
*     .. Local Arrays ..
      CHARACTER*80 HEADER, OUTNAME
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. Executable Statements
*
*     Open and read the file blacstest.dat.  Expected format is
*     -----
*     'One line of free text intended as a comment for each test run'
*     integer             Unit number of output file
*     string              Name of output file (ignored if unit = 6)
*     {'T'|'F'}           Run any point to point tests?
*     {'T'|'F'}           Run any broadcast tests?
*     {'T'|'F'}           Run any combine-operator tests?
*     {'T'|'F'}           Run the auxiliary tests?
*     integer             Number of precisions to test - up to 99
*     array of CHAR*1's   Specific precisions to test
*     integer             Output verb (1-n, n=most verbose)
*     integer             Number of nodes required by largest test case
*     -----
*     Note that the comments to the right of each line are present
*     in the sample blacstest.dat file included with this
*     distribution, but they are not required.
*
*     The array of CHAR*1's is expected to have length equal to the
*     integer in the previous line - if it is shorter, problems may
*     occur later; if it is longer, the trailing elements will just
*     be ignored.  The verb is expected to be an integer
*     between 1 and n inclusive and will be set to 1 if outside
*     this range.
*
*     Only process 0 should be calling this routine
*
      readerror = .false.
      OPEN( unit = in, file = 'bt.dat', status = 'OLD' )
      READ(in, *) header
      READ(in, *) outnum
      READ(in, *) outname
*
*     Open and prepare output file
*
      IF( outnum.NE.6 .AND. outnum.NE.0 )
     $  OPEN( unit = outnum, file = outname, status = 'UNKNOWN' )
      WRITE(outnum, *) header
*
*     Determine which tests to run
*
      READ(in, *) ch
      IF( lsame(ch, 'T') ) THEN
         testsdrv = .true.
      ELSE IF( lsame(ch, 'F') ) THEN
         testsdrv = .false.
      ELSE
         WRITE(outnum, 1000) 'SDRV', ch
         readerror = .true.
      END IF
*
      READ(in, *) ch
      IF( lsame(ch, 'T') ) THEN
         testbsbr = .true.
      ELSE IF(lsame( ch, 'F') ) THEN
         testbsbr = .false.
      ELSE
         WRITE(outnum, 1000) 'BSBR', ch
         readerror = .true.
      END IF
*
      READ(in, *) ch
      IF( lsame(ch, 'T') ) THEN
         testcomb = .true.
      ELSE IF( lsame(ch, 'F') ) THEN
         testcomb = .false.
      ELSE
         WRITE(outnum, 1000) 'COMB', ch
         readerror = .true.
      END IF
*
      READ(in, *) ch
      IF( lsame(ch, 'T') ) THEN
         testaux = .true.
      ELSE IF( lsame(ch, 'F') ) THEN
         testaux = .false.
      ELSE
         WRITE(outnum, 1000) 'AUX ', ch
         readerror = .true.
      END IF
*
*     Get # of precisions, and precisions to test
*
      READ(in, *) nprec
      IF( nprec .LT. 0 ) THEN
         nprec = 0
      ELSE IF( nprec. gt. precmax ) THEN
         WRITE(outnum, 2000) nprec, precmax, precmax
         nprec = precmax
      END IF
*
      READ(in, *) ( prec(i), i = 1, nprec )
      DO 100 i = 1, nprec
         IF( lsame(prec(i), 'C') ) THEN
            prec(i) = 'C'
         ELSE IF( lsame(prec(i), 'D') ) THEN
            prec(i) = 'D'
         ELSE IF( lsame(prec(i), 'I') ) THEN
            prec(i) = 'I'
         ELSE IF( lsame(prec(i), 'S') ) THEN
            prec(i) = 'S'
         ELSE IF( lsame(prec(i), 'Z') ) THEN
            prec(i) = 'Z'
         ELSE
            WRITE(outnum, 3000) prec(i)
            readerror = .true.
         END IF
  100 CONTINUE
*
      READ(in, *) verb
*
      IF( verb .GT. verbmax ) THEN
         WRITE(outnum, 4000) verb, verbmax, verbmax
         verb = verbmax
      ELSE IF( verb .LT. 0 ) THEN
         WRITE(outnum, 5000) verb
         verb = 0
      END IF
*
*     Abort if there was a fatal error
*
      IF( readerror ) THEN
         WRITE(outnum, 6000)
         IF( outnum .NE. 6 .AND. outnum .NE. 0 ) CLOSE( outnum )
         stop
      END IF
*
 1000 FORMAT( 'INVALID CHARACTER FOR ',a4,' TESTS ''', a1,
     $        ''' (EXPECTED T/F)' )
 2000 FORMAT( 'NUMBER OF PRECISIONS ', i6, ' GREATER THAN ', i6,
     $        ' - SETTING TO ', i6, '.')
 3000 FORMAT( 'UNRECOGNIZABLE PRECISION ENTRY ''', a1,
     $        ''' - EXPECTED ''C'', ''D'', ''I'', ''S'', OR ''Z''.')
 4000 FORMAT( 'VERBOSITY ', i4, ' GREATER THAN ',i4,
     $        ' - SETTING TO ',i4,'.')
 5000 FORMAT( 'VERBOSITY ', i4, ' LESS THAN 0 - SETTING TO 0' )
 6000 FORMAT( 'FATAL INPUT FILE ERROR - ABORTING RUN.' )
*
      RETURN
*
*     End of RDBTIN
*

Here is the caller graph for this function: