psblas2tstchk()

subroutine psblas2tstchk	(	integer	ictxt,
		integer	nout,
		integer	nrout,
		character*1	uplo,
		character*1	trans,
		character*1	diag,
		integer	m,
		integer	n,
		real	alpha,
		real, dimension( * )	a,
		real, dimension( * )	pa,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	x,
		real, dimension( * )	px,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	incx,
		real	beta,
		real, dimension( * )	y,
		real, dimension( * )	py,
		integer	iy,
		integer	jy,
		integer, dimension( * )	descy,
		integer	incy,
		real	thresh,
		real	rogue,
		real, dimension( * )	work,
		integer	info
	)

Definition at line 2518 of file psblas2tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        DIAG, TRANS, UPLO
      INTEGER            IA, ICTXT, INCX, INCY, INFO, IX, IY, JA, JX,
     $                   JY, M, N, NOUT, NROUT
      REAL               ALPHA, BETA, ROGUE, THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCX( * ), DESCY( * )
      REAL               A( * ), PA( * ), PX( * ), PY( * ), WORK( * ),
     $                   X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PSBLAS2TSTCHK performs the computational tests of the Level 2 PBLAS.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  ICTXT   (local input) INTEGER
*          On entry,  ICTXT  specifies the BLACS context handle, indica-
*          ting the global  context of the operation. The context itself
*          is global, but the value of ICTXT is local.
*
*  NOUT    (global input) INTEGER
*          On entry, NOUT specifies the unit number for the output file.
*          When NOUT is 6, output to screen,  when  NOUT is 0, output to
*          stderr. NOUT is only defined for process 0.
*
*  NROUT   (global input) INTEGER
*          On entry,  NROUT  specifies  which  routine will be tested as
*          follows:
*             If NROUT = 1,      PSGEMV will be tested;
*             else if NROUT = 2, PSSYMV will be tested;
*             else if NROUT = 3, PSTRMV will be tested;
*             else if NROUT = 4, PSTRSV will be tested;
*             else if NROUT = 5, PSGER  will be tested;
*             else if NROUT = 6, PSSYR  will be tested;
*             else if NROUT = 7, PSSYR2 will be tested;
*
*  UPLO    (global input) CHARACTER*1
*          On entry,  UPLO  specifies  if the upper or lower part of the
*          matrix operand is to be referenced.
*
*  TRANS   (global input) CHARACTER*1
*          On entry, TRANS  specifies if the matrix  operand  A is to be
*          transposed.
*
*  DIAG    (global input) CHARACTER*1
*          On entry, DIAG specifies if the  triangular matrix operand is
*          unit or non-unit.
*
*  M       (global input) INTEGER
*          On entry, M specifies the number of rows of A.
*
*  N       (global input) INTEGER
*          On entry, N specifies the number of columns of A.
*
*  ALPHA   (global input) REAL
*          On entry, ALPHA specifies the scalar alpha.
*
*  A       (local input/local output) REAL array
*          On entry, A is an array of  dimension  (DESCA( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PA.
*
*  PA      (local input) REAL array
*          On entry, PA is an array of dimension (DESCA( LLD_ ),*). This
*          array contains the local entries of the matrix PA.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  X       (local input/local output) REAL array
*          On entry, X is an array of  dimension  (DESCX( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PX.
*
*  PX      (local input) REAL array
*          On entry, PX is an array of dimension (DESCX( LLD_ ),*). This
*          array contains the local entries of the matrix PX.
*
*  IX      (global input) INTEGER
*          On entry, IX  specifies X's global row index, which points to
*          the beginning of the submatrix sub( X ).
*
*  JX      (global input) INTEGER
*          On entry, JX  specifies X's global column index, which points
*          to the beginning of the submatrix sub( X ).
*
*  DESCX   (global and local input) INTEGER array
*          On entry, DESCX  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix X.
*
*  INCX    (global input) INTEGER
*          On entry,  INCX   specifies  the  global  increment  for  the
*          elements of  X.  Only two values of  INCX   are  supported in
*          this version, namely 1 and M_X. INCX  must not be zero.
*
*  BETA    (global input) REAL
*          On entry, BETA specifies the scalar beta.
*
*  Y       (local input/local output) REAL array
*          On entry, Y is an array of  dimension  (DESCY( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PY.
*
*  PY      (local input) REAL array
*          On entry, PY is an array of dimension (DESCY( LLD_ ),*). This
*          array contains the local entries of the matrix PY.
*
*  IY      (global input) INTEGER
*          On entry, IY  specifies Y's global row index, which points to
*          the beginning of the submatrix sub( Y ).
*
*  JY      (global input) INTEGER
*          On entry, JY  specifies Y's global column index, which points
*          to the beginning of the submatrix sub( Y ).
*
*  DESCY   (global and local input) INTEGER array
*          On entry, DESCY  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix Y.
*
*  INCY    (global input) INTEGER
*          On entry,  INCY   specifies  the  global  increment  for  the
*          elements of  Y.  Only two values of  INCY   are  supported in
*          this version, namely 1 and M_Y. INCY  must not be zero.
*
*  THRESH  (global input) REAL
*          On entry, THRESH is the threshold value for the test ratio.
*
*  ROGUE   (global input) REAL
*          On entry,  ROGUE  specifies  the  constant  used  to  pad the
*          non-referenced part of triangular or symmetric matrices.
*
*  WORK    (workspace) REAL array
*          On entry, WORK  is an array of dimension LWORK where LWORK is
*          at least  MAX( M, N ). This array is used to store the compu-
*          ted gauges (see PSMVCH).
*
*  INFO    (global output) INTEGER
*          On exit, if INFO = 0,  no  error  has  been  found, otherwise
*          if( MOD( INFO,   2 ) = 1 ) then an error on A has been found,
*          if( MOD( INFO/2, 2 ) = 1 ) then an error on X has been found,
*          if( MOD( INFO/4, 2 ) = 1 ) then an error on Y has been found.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, MYCOL, MYROW, NPCOL, NPROW
      REAL               ERR
*     ..
*     .. Local Arrays ..
      INTEGER            IERR( 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, pb_slaset, pschkmin, pschkvin,
     $                   psmvch, pstrmv, psvmch, psvmch2, strsv
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
      info = 0
*
*     Quick return if possible
*
      IF( ( m.LE.0 ).OR.( n.LE.0 ) )
     $   RETURN
*
*     Start the operations
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      DO 10 i = 1, 3
         ierr( i ) = 0
   10 CONTINUE
*
      IF( nrout.EQ.1 ) THEN
*
*        Test PSGEMV
*
*        Check the resulting vector Y
*
         CALL psmvch( ictxt, trans, m, n, alpha, a, ia, ja, desca, x,
     $                ix, jx, descx, incx, beta, y, py, iy, jy, descy,
     $                incy, work, err, ierr( 3 ) )
*
         IF( ierr( 3 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         CALL pschkmin( err, m, n, a, pa, ia, ja, desca, ierr( 1 ) )
         IF( lsame( trans, 'N' ) ) THEN
            CALL pschkvin( err, n, x, px, ix, jx, descx, incx,
     $                     ierr( 2 ) )
         ELSE
            CALL pschkvin( err, m, x, px, ix, jx, descx, incx,
     $                     ierr( 2 ) )
         END IF
*
      ELSE IF( nrout.EQ.2 ) THEN
*
*        Test PSSYMV
*
*        Check the resulting vector Y
*
         CALL psmvch( ictxt, 'No transpose', n, n, alpha, a, ia, ja,
     $                desca, x, ix, jx, descx, incx, beta, y, py, iy,
     $                jy, descy, incy, work, err, ierr( 3 ) )
*
         IF( ierr( 3 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         IF( lsame( uplo, 'L' ) ) THEN
            CALL pb_slaset( 'Upper', n-1, n-1, 0, rogue, rogue,
     $                      a( ia+ja*desca( m_ ) ), desca( m_ ) )
         ELSE
            CALL pb_slaset( 'Lower', n-1, n-1, 0, rogue, rogue,
     $                      a( ia+1+(ja-1)*desca( m_ ) ), desca( m_ ) )
         END IF
         CALL pschkmin( err, n, n, a, pa, ia, ja, desca, ierr( 1 ) )
         CALL pschkvin( err, n, x, px, ix, jx, descx, incx, ierr( 2 ) )
*
      ELSE IF( nrout.EQ.3 ) THEN
*
*        Test PSTRMV
*
*        Check the resulting vector X
*
         CALL psmvch( ictxt, trans, n, n, one, a, ia, ja, desca, y, ix,
     $                jx, descx, incx, zero, x, px, ix, jx, descx, incx,
     $                work, err, ierr( 2 ) )
*
         IF( ierr( 2 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         IF( lsame( uplo, 'L' ) ) THEN
            IF( lsame( diag, 'N' ) ) THEN
               CALL pb_slaset( 'Upper', n-1, n-1, 0, rogue, rogue,
     $                         a( ia+ja*desca( m_ ) ), desca( m_ ) )
            ELSE
               CALL pb_slaset( 'Upper', n, n, 0, rogue, one,
     $                         a( ia+(ja-1)*desca( m_ ) ), desca( m_ ) )
            END IF
         ELSE
            IF( lsame( diag, 'N' ) ) THEN
               CALL pb_slaset( 'Lower', n-1, n-1, 0, rogue, rogue,
     $                         a( ia+1+(ja-1)*desca( m_ ) ),
     $                         desca( m_ ) )
            ELSE
               CALL pb_slaset( 'Lower', n, n, 0, rogue, one,
     $                         a( ia+(ja-1)*desca( m_ ) ), desca( m_ ) )
            END IF
         END IF
         CALL pschkmin( err, n, n, a, pa, ia, ja, desca, ierr( 1 ) )
*
      ELSE IF( nrout.EQ.4 ) THEN
*
*        Test PSTRSV
*
*        Check the resulting vector X
*
         CALL strsv( uplo, trans, diag, n, a( ia+(ja-1)*desca( m_ ) ),
     $               desca( m_ ), x( ix+(jx-1)*descx( m_ ) ), incx )
         CALL pstrmv( uplo, trans, diag, n, pa, ia, ja, desca, px, ix,
     $                jx, descx, incx )
         CALL psmvch( ictxt, trans, n, n, one, a, ia, ja, desca, x, ix,
     $                jx, descx, incx, zero, y, px, ix, jx, descx, incx,
     $                work, err, ierr( 2 ) )
*
         IF( ierr( 2 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         IF( lsame( uplo, 'L' ) ) THEN
            IF( lsame( diag, 'N' ) ) THEN
               CALL pb_slaset( 'Upper', n-1, n-1, 0, rogue, rogue,
     $                         a( ia+ja*desca( m_ ) ), desca( m_ ) )
            ELSE
               CALL pb_slaset( 'Upper', n, n, 0, rogue, one,
     $                         a( ia+(ja-1)*desca( m_ ) ), desca( m_ ) )
            END IF
         ELSE
            IF( lsame( diag, 'N' ) ) THEN
               CALL pb_slaset( 'Lower', n-1, n-1, 0, rogue, rogue,
     $                         a( ia+1+(ja-1)*desca( m_ ) ),
     $                         desca( m_ ) )
            ELSE
               CALL pb_slaset( 'Lower', n, n, 0, rogue, one,
     $                         a( ia+(ja-1)*desca( m_ ) ), desca( m_ ) )
            END IF
         END IF
         CALL pschkmin( err, n, n, a, pa, ia, ja, desca, ierr( 1 ) )
*
      ELSE IF( nrout.EQ.5 ) THEN
*
*        Test PSGER
*
*        Check the resulting matrix A
*
         CALL psvmch( ictxt, 'Ge', m, n, alpha, x, ix, jx, descx,
     $                incx, y, iy, jy, descy, incy, a, pa, ia, ja,
     $                desca, work, err, ierr( 1 ) )
         IF( ierr( 1 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         CALL pschkvin( err, m, x, px, ix, jx, descx, incx, ierr( 2 ) )
         CALL pschkvin( err, n, y, py, iy, jy, descy, incy, ierr( 3 ) )
*
      ELSE IF( nrout.EQ.6 ) THEN
*
*        Test PSSYR
*
*        Check the resulting matrix A
*
         CALL psvmch( ictxt, uplo, n, n, alpha, x, ix, jx, descx,
     $                incx, x, ix, jx, descx, incx, a, pa, ia, ja,
     $                desca, work, err, ierr( 1 ) )
         IF( ierr( 1 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         CALL pschkvin( err, n, x, px, ix, jx, descx, incx, ierr( 2 ) )
*
      ELSE IF( nrout.EQ.7 ) THEN
*
*        Test PSSYR2
*
*        Check the resulting matrix A
*
         CALL psvmch2( ictxt, uplo, n, n, alpha, x, ix, jx, descx, incx,
     $                 y, iy, jy, descy, incy, a, pa, ia, ja, desca,
     $                 work, err, ierr( 1 ) )
         IF( ierr( 1 ).NE.0 ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9997 )
         ELSE IF( err.GT.thresh ) THEN
            IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $         WRITE( nout, fmt = 9996 ) err
         END IF
*
*        Check the input-only arguments
*
         CALL pschkvin( err, n, x, px, ix, jx, descx, incx, ierr( 2 ) )
         CALL pschkvin( err, n, y, py, iy, jy, descy, incy, ierr( 3 ) )
*
      END IF
*
      IF( ierr( 1 ).NE.0 ) THEN
         info = info + 1
         IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $      WRITE( nout, fmt = 9999 ) 'A'
      END IF
*
      IF( ierr( 2 ).NE.0 ) THEN
         info = info + 2
         IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $      WRITE( nout, fmt = 9998 ) 'X'
      END IF
*
      IF( ierr( 3 ).NE.0 ) THEN
         info = info + 4
         IF( myrow.EQ.0 .AND. mycol.EQ.0 )
     $      WRITE( nout, fmt = 9998 ) 'Y'
      END IF
*
 9999 FORMAT( 2x, '   ***** ERROR: Matrix operand ', a,
     $        ' is incorrect.' )
 9998 FORMAT( 2x, '   ***** ERROR: Vector operand ', a,
     $        ' is incorrect.' )
 9997 FORMAT( 2x, '   ***** FATAL ERROR - Computed result is less ',
     $        'than half accurate *****' )
 9996 FORMAT( 2x, '   ***** Test completed with maximum test ratio: ',
     $        f11.5, ' SUSPECT *****' )
*
      RETURN
*
*     End of PSBLAS2TSTCHK
*

Here is the call graph for this function:

Here is the caller graph for this function: