pzmvch()

subroutine pzmvch	(	integer	ictxt,
		character*1	trans,
		integer	m,
		integer	n,
		complex*16	alpha,
		complex*16, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		complex*16, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	incx,
		complex*16	beta,
		complex*16, dimension( * )	y,
		complex*16, dimension( * )	py,
		integer	iy,
		integer	jy,
		integer, dimension( * )	descy,
		integer	incy,
		double precision, dimension( * )	g,
		double precision	err,
		integer	info
	)

Definition at line 4169 of file pzblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        TRANS
      INTEGER            IA, ICTXT, INCX, INCY, INFO, IX, IY, JA, JX,
     $                   JY, M, N
      DOUBLE PRECISION   ERR
      COMPLEX*16         ALPHA, BETA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCX( * ), DESCY( * )
      DOUBLE PRECISION   G( * )
      COMPLEX*16         A( * ), PY( * ), X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PZMVCH checks the results of the computational tests.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  ICTXT   (local input) INTEGER
*          On entry,  ICTXT  specifies the BLACS context handle, indica-
*          ting the global  context of the operation. The context itself
*          is global, but the value of ICTXT is local.
*
*  TRANS   (global input) CHARACTER*1
*          On entry,  TRANS  specifies which matrix-vector product is to
*          be computed as follows:
*             If TRANS = 'T',
*                sub( Y ) = BETA * sub( Y ) + sub( A )**T  * sub( X ),
*             else if TRANS = 'C',
*                sub( Y ) = BETA * sub( Y ) + sub( A )**H  * sub( X ),
*             otherwise
*                sub( Y ) = BETA * sub( Y ) + sub( A )     * sub( X ).
*
*  M       (global input) INTEGER
*          On entry,  M  specifies  the  number of rows of the submatrix
*          operand matrix A. M must be at least zero.
*
*  N       (global input) INTEGER
*          On entry,  N  specifies  the  number of columns of the subma-
*          trix operand matrix A. N must be at least zero.
*
*  ALPHA   (global input) COMPLEX*16
*          On entry, ALPHA specifies the scalar alpha.
*
*  A       (local input) COMPLEX*16 array
*          On entry, A is an array of  dimension  (DESCA( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PA.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  X       (local input) COMPLEX*16 array
*          On entry, X is an array of  dimension  (DESCX( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PX.
*
*  IX      (global input) INTEGER
*          On entry, IX  specifies X's global row index, which points to
*          the beginning of the submatrix sub( X ).
*
*  JX      (global input) INTEGER
*          On entry, JX  specifies X's global column index, which points
*          to the beginning of the submatrix sub( X ).
*
*  DESCX   (global and local input) INTEGER array
*          On entry, DESCX  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix X.
*
*  INCX    (global input) INTEGER
*          On entry,  INCX   specifies  the  global  increment  for  the
*          elements of  X.  Only two values of  INCX   are  supported in
*          this version, namely 1 and M_X. INCX  must not be zero.
*
*  BETA    (global input) COMPLEX*16
*          On entry, BETA specifies the scalar beta.
*
*  Y       (local input/local output) COMPLEX*16 array
*          On entry, Y is an array of  dimension  (DESCY( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PY.
*
*  PY      (local input) COMPLEX*16 array
*          On entry, PY is an array of dimension (DESCY( LLD_ ),*). This
*          array contains the local entries of the matrix PY.
*
*  IY      (global input) INTEGER
*          On entry, IY  specifies Y's global row index, which points to
*          the beginning of the submatrix sub( Y ).
*
*  JY      (global input) INTEGER
*          On entry, JY  specifies Y's global column index, which points
*          to the beginning of the submatrix sub( Y ).
*
*  DESCY   (global and local input) INTEGER array
*          On entry, DESCY  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix Y.
*
*  INCY    (global input) INTEGER
*          On entry,  INCY   specifies  the  global  increment  for  the
*          elements of  Y.  Only two values of  INCY   are  supported in
*          this version, namely 1 and M_Y. INCY  must not be zero.
*
*  G       (workspace) DOUBLE PRECISION array
*          On entry, G is an array of dimension at least MAX( M, N ).  G
*          is used to compute the gauges.
*
*  ERR     (global output) DOUBLE PRECISION
*          On exit, ERR specifies the largest error in absolute value.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, the result is less than half accurate.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      DOUBLE PRECISION   RZERO, RONE
      parameter( rzero = 0.0d+0, rone = 1.0d+0 )
      COMPLEX*16         ZERO, ONE
      parameter( zero = ( 0.0d+0, 0.0d+0 ),
     $                   one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLREP, CTRAN, ROWREP, TRAN
      INTEGER            I, IB, ICURCOL, ICURROW, IIY, IN, IOFFA, IOFFX,
     $                   IOFFY, IYCOL, IYROW, J, JB, JJY, JN, KK, LDA,
     $                   LDPY, LDX, LDY, ML, MYCOL, MYROW, NL, NPCOL,
     $                   NPROW
      DOUBLE PRECISION   EPS, ERRI, GTMP
      COMPLEX*16         C, TBETA, YTMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dgamx2d, igsum2d, pb_infog2l
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           lsame, pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, dimag, max, min, mod, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   ABS1
      abs1( c ) = abs( dble( c ) ) + abs( dimag( c ) )
*     ..
*     .. Executable Statements ..
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      eps = pdlamch( ictxt, 'eps' )
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         tbeta = one
      ELSE
         tbeta = beta
      END IF
*
      tran = lsame( trans, 'T' )
      ctran = lsame( trans, 'C' )
      IF( tran.OR.ctran ) THEN
         ml = n
         nl = m
      ELSE
         ml = m
         nl = n
      END IF
*
      lda = max( 1, desca( m_ ) )
      ldx = max( 1, descx( m_ ) )
      ldy = max( 1, descy( m_ ) )
*
*     Compute expected result in Y using data in A, X and Y.
*     Compute gauges in G. This part of the computation is performed
*     by every process in the grid.
*
      ioffy = iy + ( jy - 1 ) * ldy
      DO 40 i = 1, ml
         ytmp = zero
         gtmp = rzero
         ioffx = ix + ( jx - 1 ) * ldx
         IF( tran )THEN
            ioffa = ia + ( ja + i - 2 ) * lda
            DO 10 j = 1, nl
               ytmp = ytmp + a( ioffa ) * x( ioffx )
               gtmp = gtmp + abs1( a( ioffa ) ) * abs1( x( ioffx ) )
               ioffa = ioffa + 1
               ioffx = ioffx + incx
   10       CONTINUE
         ELSE IF( ctran )THEN
            ioffa = ia + ( ja + i - 2 ) * lda
            DO 20 j = 1, nl
               ytmp = ytmp + dconjg( a( ioffa ) ) * x( ioffx )
               gtmp = gtmp + abs1( a( ioffa ) ) * abs1( x( ioffx ) )
               ioffa = ioffa + 1
               ioffx = ioffx + incx
   20       CONTINUE
         ELSE
            ioffa = ia + i - 1 + ( ja - 1 ) * lda
            DO 30 j = 1, nl
               ytmp = ytmp + a( ioffa ) * x( ioffx )
               gtmp = gtmp + abs1( a( ioffa ) ) * abs1( x( ioffx ) )
               ioffa = ioffa + lda
               ioffx = ioffx + incx
   30       CONTINUE
         END IF
         g( i ) = abs1( alpha )*gtmp + abs1( tbeta )*abs1( y( ioffy ) )
         y( ioffy ) = alpha * ytmp + tbeta * y( ioffy )
         ioffy = ioffy + incy
   40 CONTINUE
*
*     Compute the error ratio for this result.
*
      err  = rzero
      info = 0
      ldpy = descy( lld_ )
      ioffy = iy + ( jy - 1 ) * ldy
      CALL pb_infog2l( iy, jy, descy, nprow, npcol, myrow, mycol, iiy,
     $                 jjy, iyrow, iycol )
      icurrow = iyrow
      icurcol = iycol
      rowrep  = ( iyrow.EQ.-1 )
      colrep  = ( iycol.EQ.-1 )
*
      IF( incy.EQ.descy( m_ ) ) THEN
*
*        sub( Y ) is a row vector
*
         jb = descy( inb_ ) - jy + 1
         IF( jb.LE.0 )
     $      jb = ( ( -jb ) / descy( nb_ ) + 1 ) * descy( nb_ ) + jb
         jb = min( jb, ml )
         jn = jy + jb - 1
*
         DO 50 j = jy, jn
*
            IF( ( myrow.EQ.icurrow .OR. rowrep ) .AND.
     $          ( mycol.EQ.icurcol .OR. colrep ) ) THEN
               erri = abs( py( iiy+(jjy-1)*ldpy ) - y( ioffy ) ) / eps
               IF( g( j-jy+1 ).NE.rzero )
     $            erri = erri / g( j-jy+1 )
               err = max( err, erri )
               IF( err*sqrt( eps ).GE.rone )
     $            info = 1
               jjy = jjy + 1
            END IF
*
            ioffy = ioffy + incy
*
   50    CONTINUE
*
         icurcol = mod( icurcol+1, npcol )
*
         DO 70 j = jn+1, jy+ml-1, descy( nb_ )
            jb = min( jy+ml-j, descy( nb_ ) )
*
            DO 60 kk = 0, jb-1
*
               IF( ( myrow.EQ.icurrow .OR. rowrep ) .AND.
     $             ( mycol.EQ.icurcol .OR. colrep ) ) THEN
                  erri = abs( py( iiy+(jjy-1)*ldpy ) - y( ioffy ) )/eps
                  IF( g( j+kk-jy+1 ).NE.rzero )
     $               erri = erri / g( j+kk-jy+1 )
                  err = max( err, erri )
                  IF( err*sqrt( eps ).GE.rone )
     $               info = 1
                  jjy = jjy + 1
               END IF
*
               ioffy = ioffy + incy
*
   60       CONTINUE
*
            icurcol = mod( icurcol+1, npcol )
*
   70    CONTINUE
*
      ELSE
*
*        sub( Y ) is a column vector
*
         ib = descy( imb_ ) - iy + 1
         IF( ib.LE.0 )
     $      ib = ( ( -ib ) / descy( mb_ ) + 1 ) * descy( mb_ ) + ib
         ib = min( ib, ml )
         in = iy + ib - 1
*
         DO 80 i = iy, in
*
            IF( ( myrow.EQ.icurrow .OR. rowrep ) .AND.
     $          ( mycol.EQ.icurcol .OR. colrep ) ) THEN
               erri = abs( py( iiy+(jjy-1)*ldpy ) - y( ioffy ) ) / eps
               IF( g( i-iy+1 ).NE.rzero )
     $            erri = erri / g( i-iy+1 )
               err = max( err, erri )
               IF( err*sqrt( eps ).GE.rone )
     $            info = 1
               iiy = iiy + 1
            END IF
*
            ioffy = ioffy + incy
*
   80    CONTINUE
*
         icurrow = mod( icurrow+1, nprow )
*
         DO 100 i = in+1, iy+ml-1, descy( mb_ )
            ib = min( iy+ml-i, descy( mb_ ) )
*
            DO 90 kk = 0, ib-1
*
               IF( ( myrow.EQ.icurrow .OR. rowrep ) .AND.
     $             ( mycol.EQ.icurcol .OR. colrep ) ) THEN
                  erri = abs( py( iiy+(jjy-1)*ldpy ) - y( ioffy ) )/eps
                  IF( g( i+kk-iy+1 ).NE.rzero )
     $               erri = erri / g( i+kk-iy+1 )
                  err = max( err, erri )
                  IF( err*sqrt( eps ).GE.rone )
     $               info = 1
                  iiy = iiy + 1
               END IF
*
               ioffy = ioffy + incy
*
   90       CONTINUE
*
            icurrow = mod( icurrow+1, nprow )
*
  100    CONTINUE
*
      END IF
*
*     If INFO = 0, all results are at least half accurate.
*
      CALL igsum2d( ictxt, 'All', ' ', 1, 1, info, 1, -1, mycol )
      CALL dgamx2d( ictxt, 'All', ' ', 1, 1, err, 1, i, j, -1, -1,
     $              mycol )
*
      RETURN
*
*     End of PZMVCH
*

Here is the call graph for this function:

Here is the caller graph for this function: