pzchkvin()

subroutine pzchkvin	(	double precision	errmax,
		integer	n,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	px,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	incx,
		integer	info
	)

Definition at line 2580 of file pzblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INFO, IX, JX, N
      DOUBLE PRECISION   ERRMAX
*     ..
*     .. Array Arguments ..
      INTEGER            DESCX( * )
      COMPLEX*16         PX( * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  PZCHKVIN  checks that the submatrix sub( PX ) remained unchanged. The
*  local  array  entries are compared element by element, and their dif-
*  ference  is tested against 0.0 as well as the epsilon machine. Notice
*  that  this difference should be numerically exactly the zero machine,
*  but  because of the possible fluctuation of some of the data we flag-
*  ged differently a difference less than twice the epsilon machine. The
*  largest error is also returned.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  ERRMAX  (global output) DOUBLE PRECISION
*          On exit,  ERRMAX  specifies the largest absolute element-wise
*          difference between sub( X ) and sub( PX ).
*
*  N       (global input) INTEGER
*          On entry,  N  specifies  the  length of the subvector operand
*          sub( X ). N must be at least zero.
*
*  X       (local input) COMPLEX*16 array
*          On entry, X is an array of  dimension  (DESCX( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PX.
*
*  PX      (local input) COMPLEX*16 array
*          On entry, PX is an array of dimension (DESCX( LLD_ ),*). This
*          array contains the local entries of the matrix PX.
*
*  IX      (global input) INTEGER
*          On entry, IX  specifies X's global row index, which points to
*          the beginning of the submatrix sub( X ).
*
*  JX      (global input) INTEGER
*          On entry, JX  specifies X's global column index, which points
*          to the beginning of the submatrix sub( X ).
*
*  DESCX   (global and local input) INTEGER array
*          On entry, DESCX  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix X.
*
*  INCX    (global input) INTEGER
*          On entry,  INCX   specifies  the  global  increment  for  the
*          elements of  X.  Only two values of  INCX   are  supported in
*          this version, namely 1 and M_X. INCX  must not be zero.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO = 0, no error has been found,
*          If INFO > 0, the maximum abolute error found is in (0,eps],
*          If INFO < 0, the maximum abolute error found is in (eps,+oo).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLREP, ROWREP
      INTEGER            I, IB, ICTXT, ICURCOL, ICURROW, IIX, IN, IXCOL,
     $                   IXROW, J, JB, JJX, JN, KK, LDPX, LDX, LL,
     $                   MYCOL, MYROW, NPCOL, NPROW
      DOUBLE PRECISION   ERR, EPS
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dgamx2d, pb_infog2l, pzerrset
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min, mod
*     ..
*     .. Executable Statements ..
*
      info = 0
      errmax = zero
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      eps = pdlamch( ictxt, 'eps' )
*
      CALL pb_infog2l( ix, jx, descx, nprow, npcol, myrow, mycol, iix,
     $                 jjx, ixrow, ixcol )
*
      ldx    = descx( m_ )
      ldpx   = descx( lld_ )
      rowrep = ( ixrow.EQ.-1 )
      colrep = ( ixcol.EQ.-1 )
*
      IF( n.EQ.1 ) THEN
*
         IF( ( myrow.EQ.ixrow .OR. rowrep ) .AND.
     $       ( mycol.EQ.ixcol .OR. colrep ) )
     $      CALL pzerrset( err, errmax, x( ix+(jx-1)*ldx ),
     $                     px( iix+(jjx-1)*ldpx ) )
*
      ELSE IF( incx.EQ.descx( m_ ) ) THEN
*
*        sub( X ) is a row vector
*
         jb = descx( inb_ ) - jx + 1
         IF( jb.LE.0 )
     $      jb = ( ( -jb ) / descx( nb_ ) + 1 ) * descx( nb_ ) + jb
         jb = min( jb, n )
         jn = jx + jb - 1
*
         IF( myrow.EQ.ixrow .OR. rowrep ) THEN
*
            icurcol = ixcol
            IF( mycol.EQ.icurcol .OR. colrep ) THEN
               DO 10 j = jx, jn
                  CALL pzerrset( err, errmax, x( ix+(j-1)*ldx ),
     $                           px( iix+(jjx-1)*ldpx ) )
                  jjx = jjx + 1
   10          CONTINUE
            END IF
            icurcol = mod( icurcol+1, npcol )
*
            DO 30 j = jn+1, jx+n-1, descx( nb_ )
               jb = min( jx+n-j, descx( nb_ ) )
*
               IF( mycol.EQ.icurcol .OR. colrep ) THEN
*
                  DO 20 kk = 0, jb-1
                     CALL pzerrset( err, errmax, x( ix+(j+kk-1)*ldx ),
     $                              px( iix+(jjx+kk-1)*ldpx ) )
   20             CONTINUE
*
                  jjx = jjx + jb
*
               END IF
*
               icurcol = mod( icurcol+1, npcol )
*
   30       CONTINUE
*
         END IF
*
      ELSE
*
*        sub( X ) is a column vector
*
         ib = descx( imb_ ) - ix + 1
         IF( ib.LE.0 )
     $      ib = ( ( -ib ) / descx( mb_ ) + 1 ) * descx( mb_ ) + ib
         ib = min( ib, n )
         in = ix + ib - 1
*
         IF( mycol.EQ.ixcol .OR. colrep ) THEN
*
            icurrow = ixrow
            IF( myrow.EQ.icurrow .OR. rowrep ) THEN
               DO 40 i = ix, in
                  CALL pzerrset( err, errmax, x( i+(jx-1)*ldx ),
     $                           px( iix+(jjx-1)*ldpx ) )
                  iix = iix + 1
   40          CONTINUE
            END IF
            icurrow = mod( icurrow+1, nprow )
*
            DO 60 i = in+1, ix+n-1, descx( mb_ )
               ib = min( ix+n-i, descx( mb_ ) )
*
               IF( myrow.EQ.icurrow .OR. rowrep ) THEN
*
                  DO 50 kk = 0, ib-1
                     CALL pzerrset( err, errmax, x( i+kk+(jx-1)*ldx ),
     $                              px( iix+kk+(jjx-1)*ldpx ) )
   50             CONTINUE
*
                  iix = iix + ib
*
               END IF
*
               icurrow = mod( icurrow+1, nprow )
*
   60       CONTINUE
*
         END IF
*
      END IF
*
      CALL dgamx2d( ictxt, 'All', ' ', 1, 1, errmax, 1, kk, ll, -1,
     $              -1, -1 )
*
      IF( errmax.GT.zero .AND. errmax.LE.eps ) THEN
         info = 1
      ELSE IF( errmax.GT.eps ) THEN
         info = -1
      END IF
*
      RETURN
*
*     End of PZCHKVIN
*

Here is the call graph for this function:

Here is the caller graph for this function: