pzlaset.f

Go to the documentation of this file.

      SUBROUTINE pzlaset( UPLO, M, N, ALPHA, BETA, A, IA, JA, DESCA )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, JA, M, N
      COMPLEX*16         ALPHA, BETA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZLASET initializes an M-by-N distributed matrix sub( A ) denoting
*  A(IA:IA+M-1,JA:JA+N-1) to BETA on the diagonal and ALPHA on the
*  offdiagonals.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies the part of the distributed matrix sub( A ) to be
*          set:
*          = 'U':      Upper triangular part is set; the strictly lower
*                      triangular part of sub( A ) is not changed;
*          = 'L':      Lower triangular part is set; the strictly upper
*                      triangular part of sub( A ) is not changed;
*          Otherwise:  All of the matrix sub( A ) is set.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  ALPHA   (global input) COMPLEX*16
*          The constant to which the offdiagonal elements are to be
*          set.
*
*  BETA    (global input) COMPLEX*16
*          The constant to which the diagonal elements are to be set.
*
*  A       (local output) COMPLEX*16 pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+N-1)).  This array
*          contains the local pieces of the distributed matrix sub( A )
*          to be set.  On exit, the leading M-by-N submatrix sub( A )
*          is set as follows:
*
*          if UPLO = 'U', A(IA+i-1,JA+j-1) = ALPHA, 1<=i<=j-1, 1<=j<=N,
*          if UPLO = 'L', A(IA+i-1,JA+j-1) = ALPHA, j+1<=i<=M, 1<=j<=N,
*          otherwise,     A(IA+i-1,JA+j-1) = ALPHA, 1<=i<=M, 1<=j<=N,
*                                                   IA+i.NE.JA+j,
*          and, for all UPLO, A(IA+i-1,JA+i-1) = BETA, 1<=i<=min(M,N).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IAA, IBLK, IN, ITMP, J, JAA, JBLK, JN, JTMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           pzlase2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL
      EXTERNAL           iceil, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
      IF( m.LE.( desca( mb_ ) - mod( ia-1, desca( mb_ ) ) ) .OR.
     $    n.LE.( desca( nb_ ) - mod( ja-1, desca( nb_ ) ) ) ) THEN
         CALL pzlase2( uplo, m, n, alpha, beta, a, ia, ja, desca )
      ELSE
*
         IF( lsame( uplo, 'U' ) ) THEN
            in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
            CALL pzlase2( uplo, in-ia+1, n, alpha, beta, a, ia, ja,
     $                    desca )
            DO 10 i = in+1, ia+m-1, desca( mb_ )
               itmp = i-ia
               iblk = min( desca( mb_ ), m-itmp )
               jaa = ja + itmp
               CALL pzlase2( uplo, iblk, n-itmp, alpha, beta,
     $                       a, i, jaa, desca )
   10       CONTINUE
         ELSE IF( lsame( uplo, 'L' ) ) THEN
            jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
            CALL pzlase2( uplo, m, jn-ja+1, alpha, beta, a, ia, ja,
     $                    desca )
            DO 20 j = jn+1, ja+n-1, desca( nb_ )
               jtmp = j-ja
               jblk = min( desca( nb_ ), n-jtmp )
               iaa = ia + jtmp
               CALL pzlase2( uplo, m-jtmp, jblk, alpha, beta, a, iaa,
     $                       j, desca )
   20       CONTINUE
         ELSE
            IF( m.LE.n ) THEN
               in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ),
     $                   ia+m-1 )
               CALL pzlase2( uplo, in-ia+1, n, alpha, beta, a, ia,
     $                       ja, desca )
               DO 30 i = in+1, ia+m-1, desca( mb_ )
                  itmp = i-ia
                  iblk = min( desca( mb_ ), m-itmp )
                  CALL pzlase2( uplo, iblk, i-ia, alpha, alpha, a, i,
     $                          ja, desca )
                  CALL pzlase2( uplo, iblk, n-i+ia, alpha, beta, a, i,
     $                          ja+i-ia, desca )
   30          CONTINUE
            ELSE
               jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ),
     $                   ja+n-1 )
               CALL pzlase2( uplo, m, jn-ja+1, alpha, beta, a, ia,
     $                       ja, desca )
               DO 40 j = jn+1, ja+n-1, desca( nb_ )
                  jtmp = j-ja
                  jblk = min( desca( nb_ ), n-jtmp )
                  CALL pzlase2( uplo, j-ja, jblk, alpha, alpha, a, ia,
     $                          j, desca )
                  CALL pzlase2( uplo, m-j+ja, jblk, alpha, beta, a,
     $                          ia+j-ja, j, desca )
   40          CONTINUE
            END IF
         END IF
*
      END IF
*
      RETURN
*
*     End of PZLASET
*
      END