pslamch()

real function pslamch	(	integer	ictxt,
		character*1	cmach
	)

Definition at line 6768 of file psblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        CMACH
      INTEGER            ICTXT
*     ..
*
*  Purpose
*  =======
*
*  PSLAMCH determines single precision machine parameters.
*
*  Arguments
*  =========
*
*  ICTXT   (local input) INTEGER
*          On entry,  ICTXT  specifies the BLACS context handle, indica-
*          ting the global  context of the operation. The context itself
*          is global, but the value of ICTXT is local.
*
*  CMACH   (global input) CHARACTER*1
*          On entry, CMACH specifies the value to be returned by PSLAMCH
*          as follows:
*             = 'E' or 'e',   PSLAMCH := eps,
*             = 'S' or 's ,   PSLAMCH := sfmin,
*             = 'B' or 'b',   PSLAMCH := base,
*             = 'P' or 'p',   PSLAMCH := eps*base,
*             = 'N' or 'n',   PSLAMCH := t,
*             = 'R' or 'r',   PSLAMCH := rnd,
*             = 'M' or 'm',   PSLAMCH := emin,
*             = 'U' or 'u',   PSLAMCH := rmin,
*             = 'L' or 'l',   PSLAMCH := emax,
*             = 'O' or 'o',   PSLAMCH := rmax,
*
*          where
*
*          eps   = relative machine precision,
*          sfmin = safe minimum, such that 1/sfmin does not overflow,
*          base  = base of the machine,
*          prec  = eps*base,
*          t     = number of (base) digits in the mantissa,
*          rnd   = 1.0 when rounding occurs in addition, 0.0 otherwise,
*          emin  = minimum exponent before (gradual) underflow,
*          rmin  = underflow threshold - base**(emin-1),
*          emax  = largest exponent before overflow,
*          rmax  = overflow threshold  - (base**emax)*(1-eps).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Local Scalars ..
      CHARACTER*1        TOP
      INTEGER            IDUMM
      REAL               TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           pb_topget, sgamn2d, sgamx2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH
      EXTERNAL           lsame, slamch
*     ..
*     .. Executable Statements ..
*
      temp = slamch( cmach )
*
      IF( lsame( cmach, 'E' ).OR.lsame( cmach, 'S' ).OR.
     $    lsame( cmach, 'M' ).OR.lsame( cmach, 'U' ) ) THEN
         CALL pb_topget( ictxt, 'Combine', 'All', top )
         idumm = 0
         CALL sgamx2d( ictxt, 'All', top, 1, 1, temp, 1, idumm,
     $                 idumm, -1, -1, idumm )
      ELSE IF( lsame( cmach, 'L' ).OR.lsame( cmach, 'O' ) ) THEN
         CALL pb_topget( ictxt, 'Combine', 'All', top )
         idumm = 0
         CALL sgamn2d( ictxt, 'All', top, 1, 1, temp, 1, idumm,
     $                 idumm, -1, -1, idumm )
      END IF
*
      pslamch = temp
*
      RETURN
*
*     End of PSLAMCH
*

Here is the call graph for this function: