psmmch3()

subroutine psmmch3	(	character*1	uplo,
		character*1	trans,
		integer	m,
		integer	n,
		real	alpha,
		real, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real	beta,
		real, dimension( * )	c,
		real, dimension( * )	pc,
		integer	ic,
		integer	jc,
		integer, dimension( * )	descc,
		real	err,
		integer	info
	)

Definition at line 6370 of file psblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        TRANS, UPLO
      INTEGER            IA, IC, INFO, JA, JC, M, N
      REAL               ALPHA, BETA, ERR
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      REAL               A( * ), C( * ), PC( * )
*     ..
*
*  Purpose
*  =======
*
*  PSMMCH3 checks the results of the computational tests.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER*1
*          On entry,  UPLO  specifies which part of C should contain the
*          result.
*
*  TRANS   (global input) CHARACTER*1
*          On entry,  TRANS  specifies  whether  the  matrix A has to be
*          transposed  or not  before computing the  matrix-matrix addi-
*          tion.
*
*  M       (global input) INTEGER
*          On entry, M specifies the number of rows of C.
*
*  N       (global input) INTEGER
*          On entry, N specifies the number of columns of C.
*
*  ALPHA   (global input) REAL
*          On entry, ALPHA specifies the scalar alpha.
*
*  A       (local input) REAL array
*          On entry, A is an array of  dimension  (DESCA( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PA.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  BETA    (global input) REAL
*          On entry, BETA specifies the scalar beta.
*
*  C       (local input/local output) REAL array
*          On entry, C is an array of  dimension  (DESCC( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PC.
*
*  PC      (local input) REAL array
*          On entry, PC is an array of dimension (DESCC( LLD_ ),*). This
*          array contains the local pieces of the matrix PC.
*
*  IC      (global input) INTEGER
*          On entry, IC  specifies C's global row index, which points to
*          the beginning of the submatrix sub( C ).
*
*  JC      (global input) INTEGER
*          On entry, JC  specifies C's global column index, which points
*          to the beginning of the submatrix sub( C ).
*
*  DESCC   (global and local input) INTEGER array
*          On entry, DESCC  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix C.
*
*  ERR     (global output) REAL
*          On exit, ERR specifies the largest error in absolute value.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, the result is less than half accurate.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLREP, LOWER, NOTRAN, ROWREP, UPPER
      INTEGER            I, ICCOL, ICROW, ICTXT, IIC, IOFFA, IOFFC, J,
     $                   JJC, LDA, LDC, LDPC, MYCOL, MYROW, NPCOL,
     $                   NPROW
      REAL               ERR0, ERRI, PREC
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igsum2d, pb_infog2l,
     $                   pserraxpby, sgamx2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               PSLAMCH
      EXTERNAL           lsame, pslamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      ictxt = descc( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      prec   = pslamch( ictxt, 'eps' )
*
      upper  = lsame( uplo,  'U' )
      lower  = lsame( uplo,  'L' )
      notran = lsame( trans, 'N' )
*
*     Compute expected result in C using data in A and C. This part of
*     the computation is performed by every process in the grid.
*
      info   = 0
      err    = zero
*
      lda    = max( 1, desca( m_   ) )
      ldc    = max( 1, descc( m_   ) )
      ldpc   = max( 1, descc( lld_ ) )
      rowrep = ( descc( rsrc_ ).EQ.-1 )
      colrep = ( descc( csrc_ ).EQ.-1 )
*
      IF( notran ) THEN
*
         DO 20 j = jc, jc + n - 1
*
            ioffc = ic + ( j  - 1          ) * ldc
            ioffa = ia + ( ja - 1 + j - jc ) * lda
*
            DO 10 i = ic, ic + m - 1
*
               IF( upper ) THEN
                  IF( ( j - jc ).GE.( i - ic ) ) THEN
                     CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                                c( ioffc ), prec )
                  ELSE
                     erri = zero
                  END IF
               ELSE IF( lower ) THEN
                  IF( ( j - jc ).LE.( i - ic ) ) THEN
                     CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                                c( ioffc ), prec )
                  ELSE
                     erri = zero
                  END IF
               ELSE
                  CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                             c( ioffc ), prec )
               END IF
*
               CALL pb_infog2l( i, j, descc, nprow, npcol, myrow, mycol,
     $                          iic, jjc, icrow, iccol )
               IF( ( myrow.EQ.icrow .OR. rowrep ) .AND.
     $             ( mycol.EQ.iccol .OR. colrep ) ) THEN
                  err0 = abs( pc( iic+(jjc-1)*ldpc )-c( ioffc ) )
                  IF( err0.GT.erri )
     $               info = 1
                  err = max( err, err0 )
               END IF
*
               ioffa = ioffa + 1
               ioffc = ioffc + 1
*
   10       CONTINUE
*
   20    CONTINUE
*
      ELSE
*
         DO 40 j = jc, jc + n - 1
*
            ioffc = ic +              ( j  - 1 ) * ldc
            ioffa = ia + ( j - jc ) + ( ja - 1 ) * lda
*
            DO 30 i = ic, ic + m - 1
*
               IF( upper ) THEN
                  IF( ( j - jc ).GE.( i - ic ) ) THEN
                     CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                               c( ioffc ), prec )
                  ELSE
                     erri = zero
                  END IF
               ELSE IF( lower ) THEN
                  IF( ( j - jc ).LE.( i - ic ) ) THEN
                     CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                               c( ioffc ), prec )
                  ELSE
                     erri = zero
                  END IF
               ELSE
                  CALL pserraxpby( erri, alpha, a( ioffa ), beta,
     $                            c( ioffc ), prec )
               END IF
*
               CALL pb_infog2l( i, j, descc, nprow, npcol, myrow, mycol,
     $                          iic, jjc, icrow, iccol )
               IF( ( myrow.EQ.icrow .OR. rowrep ) .AND.
     $             ( mycol.EQ.iccol .OR. colrep ) ) THEN
                  err0 = abs( pc( iic+(jjc-1)*ldpc )-c( ioffc ) )
                  IF( err0.GT.erri )
     $               info = 1
                  err = max( err, err0 )
               END IF
*
               ioffc = ioffc + 1
               ioffa = ioffa + lda
*
   30       CONTINUE
*
   40    CONTINUE
*
      END IF
*
*     If INFO = 0, all results are at least half accurate.
*
      CALL igsum2d( ictxt, 'All', ' ', 1, 1, info, 1, -1, mycol )
      CALL sgamx2d( ictxt, 'All', ' ', 1, 1, err, 1, i, j, -1, -1,
     $              mycol )
*
      RETURN
*
*     End of PSMMCH3
*

Here is the call graph for this function:

Here is the caller graph for this function: