pschkmout()

subroutine pschkmout	(	integer	m,
		integer	n,
		real, dimension( * )	a,
		real, dimension( * )	pa,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	info
	)

Definition at line 3626 of file psblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            IA, INFO, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ), PA( * )
*     ..
*
*  Purpose
*  =======
*
*  PSCHKMOUT  checks  that the matrix PA \ sub( PA ) remained unchanged.
*  The  local array  entries  are compared element by element, and their
*  difference  is tested against 0.0 as well as the epsilon machine. No-
*  tice that this  difference should be numerically exactly the zero ma-
*  chine, but because  of  the  possible movement of some of the data we
*  flagged differently a difference less than twice the epsilon machine.
*  The largest error is reported.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          On entry,  M  specifies  the  number of rows of the submatrix
*          sub( PA ). M must be at least zero.
*
*  N       (global input) INTEGER
*          On entry, N specifies the  number of columns of the submatrix
*          sub( PA ). N must be at least zero.
*
*  A       (local input) REAL array
*          On entry, A is an array of  dimension  (DESCA( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PA.
*
*  PA      (local input) REAL array
*          On entry, PA is an array of dimension (DESCA( LLD_ ),*). This
*          array contains the local entries of the matrix PA.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO = 0, no error has been found,
*          If INFO > 0, the maximum abolute error found is in (0,eps],
*          If INFO < 0, the maximum abolute error found is in (eps,+oo).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLREP, ROWREP
      INTEGER            I, IB, ICTXT, ICURCOL, II, IMBA, J, JB, JJ, KK,
     $                   LDA, LDPA, LL, MPALL, MYCOL, MYROW, MYROWDIST,
     $                   NPCOL, NPROW
      REAL               EPS, ERR, ERRMAX
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, pserrset, sgamx2d
*     ..
*     .. External Functions ..
      INTEGER            PB_NUMROC
      REAL               PSLAMCH
      EXTERNAL           pslamch, pb_numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
      info = 0
      errmax = zero
*
*     Quick return if possible
*
      IF( ( desca( m_ ).LE.0 ).OR.( desca( n_ ).LE.0 ) )
     $   RETURN
*
*     Start the operations
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      eps = pslamch( ictxt, 'eps' )
*
      mpall = pb_numroc( desca( m_ ), 1, desca( imb_ ), desca( mb_ ),
     $                   myrow, desca( rsrc_ ), nprow )
*
      lda    = desca( m_ )
      ldpa   = desca( lld_ )
*
      ii = 1
      jj = 1
      rowrep  = ( desca( rsrc_ ).EQ.-1 )
      colrep  = ( desca( csrc_ ).EQ.-1 )
      icurcol = desca( csrc_ )
      IF( myrow.EQ.desca( rsrc_ ) .OR. rowrep ) THEN
         imba = desca( imb_ )
      ELSE
         imba = desca( mb_ )
      END IF
      IF( rowrep ) THEN
         myrowdist = 0
      ELSE
         myrowdist = mod( myrow - desca( rsrc_ ) + nprow, nprow )
      END IF
*
      IF( mycol.EQ.icurcol .OR. colrep ) THEN
*
         j = 1
         IF( myrowdist.EQ.0 ) THEN
            i = 1
         ELSE
            i = desca( imb_ ) + ( myrowdist - 1 ) * desca( mb_ ) + 1
         END IF
         ib = min( max( 0, desca( m_ ) - i + 1 ), imba )
         jb = min( desca( n_ ), desca( inb_ ) )
*
         DO 20 kk = 0, jb-1
            DO 10 ll = 0, ib-1
               IF( i+ll.LT.ia .OR. i+ll.GT.ia+m-1 .OR.
     $             j+kk.LT.ja .OR. j+kk.GT.ja+n-1 )
     $            CALL pserrset( err, errmax, a( i+ll+(j+kk-1)*lda ),
     $                           pa( ii+ll+(jj+kk-1)*ldpa ) )
   10       CONTINUE
   20    CONTINUE
         IF( rowrep ) THEN
            i = i + imba
         ELSE
            i = i + imba + ( nprow - 1 ) * desca( mb_ )
         END IF
*
         DO 50 ii = imba + 1, mpall, desca( mb_ )
            ib = min( mpall-ii+1, desca( mb_ ) )
*
            DO 40 kk = 0, jb-1
               DO 30 ll = 0, ib-1
                  IF( i+ll.LT.ia .OR. i+ll.GT.ia+m-1 .OR.
     $                j+kk.LT.ja .OR. j+kk.GT.ja+n-1 )
     $               CALL pserrset( err, errmax,
     $                              a( i+ll+(j+kk-1)*lda ),
     $                              pa( ii+ll+(jj+kk-1)*ldpa ) )
   30          CONTINUE
   40       CONTINUE
*
            IF( rowrep ) THEN
               i = i + desca( mb_ )
            ELSE
               i = i + nprow * desca( mb_ )
            END IF
*
   50    CONTINUE
*
         jj = jj + jb
*
      END IF
*
      icurcol = mod( icurcol + 1, npcol )
*
      DO 110 j = desca( inb_ ) + 1, desca( n_ ), desca( nb_ )
         jb = min( desca( n_ ) - j + 1, desca( nb_ ) )
*
         IF( mycol.EQ.icurcol .OR. colrep ) THEN
*
            IF( myrowdist.EQ.0 ) THEN
               i = 1
            ELSE
               i = desca( imb_ ) + ( myrowdist - 1 ) * desca( mb_ ) + 1
            END IF
*
            ii = 1
            ib = min( max( 0, desca( m_ ) - i + 1 ), imba )
            DO 70 kk = 0, jb-1
               DO 60 ll = 0, ib-1
                  IF( i+ll.LT.ia .OR. i+ll.GT.ia+m-1 .OR.
     $                j+kk.LT.ja .OR. j+kk.GT.ja+n-1 )
     $               CALL pserrset( err, errmax,
     $                              a( i+ll+(j+kk-1)*lda ),
     $                              pa( ii+ll+(jj+kk-1)*ldpa ) )
   60          CONTINUE
   70       CONTINUE
            IF( rowrep ) THEN
               i = i + imba
            ELSE
               i = i + imba + ( nprow - 1 ) * desca( mb_ )
            END IF
*
            DO 100 ii = imba+1, mpall, desca( mb_ )
               ib = min( mpall-ii+1, desca( mb_ ) )
*
               DO 90 kk = 0, jb-1
                  DO 80 ll = 0, ib-1
                     IF( i+ll.LT.ia .OR. i+ll.GT.ia+m-1 .OR.
     $                   j+kk.LT.ja .OR. j+kk.GT.ja+n-1 )
     $                  CALL pserrset( err, errmax,
     $                                 a( i+ll+(j+kk-1)*lda ),
     $                                 pa( ii+ll+(jj+kk-1)*ldpa ) )
   80             CONTINUE
   90          CONTINUE
*
               IF( rowrep ) THEN
                  i = i + desca( mb_ )
               ELSE
                  i = i + nprow * desca( mb_ )
               END IF
*
  100       CONTINUE
*
            jj = jj + jb
*
         END IF
*
         icurcol = mod( icurcol + 1, npcol )
*                                                           INSERT MODE
  110 CONTINUE
*
      CALL sgamx2d( ictxt, 'All', ' ', 1, 1, errmax, 1, kk, ll, -1,
     $              -1, -1 )
*
      IF( errmax.GT.zero .AND. errmax.LE.eps ) THEN
         info = 1
      ELSE IF( errmax.GT.eps ) THEN
         info = -1
      END IF
*
      RETURN
*
*     End of PSCHKMOUT
*

Here is the call graph for this function:

Here is the caller graph for this function: