pzevcinfo()

subroutine pzevcinfo	(	character*( * )	summry,
		integer	nout,
		integer	nmat,
		integer, dimension( ldnval )	nval,
		integer	ldnval,
		integer	nnb,
		integer, dimension( ldnbval )	nbval,
		integer	ldnbval,
		integer	ngrids,
		integer, dimension( ldpval )	pval,
		integer	ldpval,
		integer, dimension( ldqval )	qval,
		integer	ldqval,
		real	thresh,
		integer, dimension( * )	work,
		integer	iam,
		integer	nprocs
	)

Definition at line 1 of file pzevcinfo.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     March, 2000
*
*     .. Scalar Arguments ..
      CHARACTER*( * )    SUMMRY
      INTEGER            IAM, LDNBVAL, LDNVAL, LDPVAL, LDQVAL, NGRIDS,
     $                   NMAT, NNB, NOUT, NPROCS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            NBVAL( LDNBVAL ), NVAL( LDNVAL ),
     $                   PVAL( LDPVAL ), QVAL( LDQVAL ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZEVCINFO gets needed startup information for PZTREVC driver
*  and transmits it to all processes.
*
*  Arguments
*  =========
*
*  SUMMRY   (global output) CHARACTER*(*)
*           Name of output (summary) file (if any). Only defined for
*           process 0.
*
*  NOUT     (global output) INTEGER
*           The unit number for output file. NOUT = 6, ouput to screen,
*           NOUT = 0, output to stderr.  Only defined for process 0.
*
*  NMAT     (global output) INTEGER
*           The number of different values that can be used for N.
*
*  NVAL     (global output) INTEGER array, dimension (LDNVAL)
*           The values of N (the order of the matrix) to run the code
*           with.
*
*  LDNVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           N, LDNVAL > =  NMAT.
*
*  NNB      (global output) INTEGER
*           The number of different values that can be used for NB.
*
*  NBVAL    (global output) INTEGER array, dimension (LDNBVAL)
*           The values of NB (blocksize) to run the code with.
*
*  LDNBVAL  (global input) INTEGER
*           The maximum number of different values that can be used for
*           NB, LDNBVAL >= NNB.
*
*  NGRIDS   (global output) INTEGER
*           The number of different values that can be used for P & Q.
*
*  PVAL     (global output) INTEGER array, dimension (LDPVAL)
*           The values of P (number of process rows) to run the code
*           with.
*
*  LDPVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           P, LDPVAL >= NGRIDS.
*
*  QVAL     (global output) INTEGER array, dimension (LDQVAL)
*           The values of Q (number of process columns) to run the code
*           with.
*
*  LDQVAL   (global input) INTEGER
*           The maximum number of different values that can be used for
*           Q, LDQVAL >= NGRIDS.
*
*  THRESH   (global output) REAL
*           Indicates what error checks shall be run and printed out:
*           < 0 : Perform no error checking
*           > 0 : report all residuals greater than THRESH
*
*  WORK     (local workspace) INTEGER array of dimension >=
*           MAX( 3, LDNVAL+LDNBVAL+LDPVAL+LDQVAL ), used to pack all
*           input arrays in order to send info in one message.
*
*  IAM      (local input) INTEGER
*           My process number.
*
*  NPROCS   (global input) INTEGER
*           The total number of processes.
*
*  Further Details
*  ===============
*
*  Implemented by:  M. Fahey, June 2000
*
* ======================================================================
*
* Note: For packing the information we assumed that the length in bytes
* ===== of an integer is equal to the length in bytes of a real single
*       precision.
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            NIN
      parameter( nin = 11 )
*     ..
*     .. Local Scalars ..
      CHARACTER*79       USRINFO
      INTEGER            I, ICTXT
      DOUBLE PRECISION   EPS
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_get, blacs_gridexit,
     $                   blacs_gridinit, blacs_setup, icopy, igebr2d,
     $                   igebs2d, sgebr2d, sgebs2d
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Process 0 reads the input data, broadcasts to other processes and
*     writes needed information to NOUT
*
      IF( iam.EQ.0 ) THEN
*
*        Open file and skip data file header
*
         OPEN( nin, file = 'EVC.dat', status = 'OLD' )
         READ( nin, fmt = * )summry
         summry = ' '
*
*        Read in user-supplied info about machine type, compiler, etc.
*
         READ( nin, fmt = 9999 )usrinfo
*
*        Read name and unit number for summary output file
*
         READ( nin, fmt = * )summry
         READ( nin, fmt = * )nout
         IF( nout.NE.0 .AND. nout.NE.6 )
     $      OPEN( nout, file = summry, status = 'UNKNOWN' )
*
*        Read and check the parameter values for the tests.
*
*        Get number of matrices and their dimensions
*
         READ( nin, fmt = * )nmat
         IF( nmat.LT.1 .OR. nmat.GT.ldnval ) THEN
            WRITE( nout, fmt = 9994 )'N', ldnval
            GO TO 30
         END IF
         READ( nin, fmt = * )( nval( i ), i = 1, nmat )
*
*        Get values of NB
*
         READ( nin, fmt = * )nnb
         IF( nnb.GT.ldnbval ) THEN
            WRITE( nout, fmt = 9994 )'NB', ldnbval
            GO TO 30
         END IF
         READ( nin, fmt = * )( nbval( i ), i = 1, nnb )
*
         DO 10 i = 1, nnb
            IF( nbval( i ).LT.6 ) THEN
               WRITE( nout, fmt = 9992 )nbval( i )
               GO TO 30
            END IF
   10    CONTINUE
*
*        Get number of grids
*
         READ( nin, fmt = * )ngrids
         IF( ngrids.LT.1 .OR. ngrids.GT.ldpval ) THEN
            WRITE( nout, fmt = 9994 )'Grids', ldpval
            GO TO 30
         ELSE IF( ngrids.GT.ldqval ) THEN
            WRITE( nout, fmt = 9994 )'Grids', ldqval
            GO TO 30
         END IF
*
*        Get values of P and Q
*
         READ( nin, fmt = * )( pval( i ), i = 1, ngrids )
         READ( nin, fmt = * )( qval( i ), i = 1, ngrids )
*
*        Get level of checking
*
         READ( nin, fmt = * )thresh
*
*        Close input file
*
         CLOSE ( nin )
*
*        For pvm only: if virtual machine not set up, allocate it and
*        spawn the correct number of processes.
*
         IF( nprocs.LT.1 ) THEN
            nprocs = 0
            DO 20 i = 1, ngrids
               nprocs = max( nprocs, pval( i )*qval( i ) )
   20       CONTINUE
            CALL blacs_setup( iam, nprocs )
         END IF
*
*        Temporarily define blacs grid to include all processes so
*        information can be broadcast to all processes
*
         CALL blacs_get( -1, 0, ictxt )
         CALL blacs_gridinit( ictxt, 'Row-major', 1, nprocs )
*
*        Compute machine epsilon
*
         eps = pdlamch( ictxt, 'eps' )
*
*        Pack information arrays and broadcast
*
         CALL sgebs2d( ictxt, 'All', ' ', 1, 1, thresh, 1 )
*
         work( 1 ) = nmat
         work( 2 ) = nnb
         work( 3 ) = ngrids
         CALL igebs2d( ictxt, 'All', ' ', 3, 1, work, 3 )
*
         i = 1
         CALL icopy( nmat, nval, 1, work( i ), 1 )
         i = i + nmat
         CALL icopy( nnb, nbval, 1, work( i ), 1 )
         i = i + nnb
         CALL icopy( ngrids, pval, 1, work( i ), 1 )
         i = i + ngrids
         CALL icopy( ngrids, qval, 1, work( i ), 1 )
         i = i + ngrids - 1
         CALL igebs2d( ictxt, 'All', ' ', i, 1, work, i )
*
*        regurgitate input
*
         WRITE( nout, fmt = 9999 )
     $      'ScaLAPACK nonsymmetric eigenvector calculation.'
         WRITE( nout, fmt = 9999 )usrinfo
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )'Tests of the parallel ' //
     $      'complex double precision eigenvector calculation.'
         WRITE( nout, fmt = 9999 )'The following scaled residual ' //
     $      'checks will be computed:'
         WRITE( nout, fmt = 9999 )
     $      ' Residual  = max( ||T*R-R*D||/(||H||*eps*N)' //
     $      ' , ||T^H*L-L*D^H||/(||H||*eps*N) )'
         WRITE( nout, fmt = 9999 )
     $      ' Normalization residual = max(max_j(max|R(j)|-1),' //
     $      ' max_j(max|L(j)|-1))/(eps*N)'
         WRITE( nout, fmt = 9999 )'The matrix A is randomly ' //
     $      'generated for each test.'
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )'An explanation of the input/output '
     $       // 'parameters follows:'
         WRITE( nout, fmt = 9999 )
     $      'TIME    : Indicates whether WALL or ' //
     $      'CPU time was used.'
*
         WRITE( nout, fmt = 9999 )
     $      'N       : The number of columns in the ' // 'matrix A.'
         WRITE( nout, fmt = 9999 )
     $      'NB      : The size of the square blocks the' //
     $      ' matrix A is split into.'
         WRITE( nout, fmt = 9999 )
     $      'P       : The number of process rows.'
         WRITE( nout, fmt = 9999 )
     $      'Q       : The number of process columns.'
         WRITE( nout, fmt = 9999 )
     $      'THRESH  : If a residual value is less than' //
     $      ' THRESH, CHECK is flagged as PASSED'
         WRITE( nout, fmt = 9999 )
     $      'NEP time : Time in seconds to decompose the ' // ' matrix'
         WRITE( nout, fmt = 9999 )'MFLOPS  : Rate of execution '
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9999 )
     $      'The following parameter values will be used:'
         WRITE( nout, fmt = 9996 )'N    ',
     $      ( nval( i ), i = 1, min( nmat, 10 ) )
         IF( nmat.GT.10 )
     $      WRITE( nout, fmt = 9997 )( nval( i ), i = 11, nmat )
         WRITE( nout, fmt = 9996 )'NB   ',
     $      ( nbval( i ), i = 1, min( nnb, 10 ) )
         IF( nnb.GT.10 )
     $      WRITE( nout, fmt = 9997 )( nbval( i ), i = 11, nnb )
         WRITE( nout, fmt = 9996 )'P    ',
     $      ( pval( i ), i = 1, min( ngrids, 10 ) )
         IF( ngrids.GT.10 )
     $      WRITE( nout, fmt = 9997 )( pval( i ), i = 11, ngrids )
         WRITE( nout, fmt = 9996 )'Q    ',
     $      ( qval( i ), i = 1, min( ngrids, 10 ) )
         IF( ngrids.GT.10 )
     $      WRITE( nout, fmt = 9997 )( qval( i ), i = 11, ngrids )
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9995 )eps
         WRITE( nout, fmt = 9998 )thresh
*
      ELSE
*
*        If in pvm, must participate setting up virtual machine
*
         IF( nprocs.LT.1 )
     $      CALL blacs_setup( iam, nprocs )
*
*        Temporarily define blacs grid to include all processes so
*        information can be broadcast to all processes
*
         CALL blacs_get( -1, 0, ictxt )
         CALL blacs_gridinit( ictxt, 'Row-major', 1, nprocs )
*
*        Compute machine epsilon
*
         eps = pdlamch( ictxt, 'eps' )
*
         CALL sgebr2d( ictxt, 'All', ' ', 1, 1, thresh, 1, 0, 0 )
         CALL igebr2d( ictxt, 'All', ' ', 3, 1, work, 3, 0, 0 )
         nmat = work( 1 )
         nnb = work( 2 )
         ngrids = work( 3 )
*
         i = nmat + nnb + 2*ngrids
         CALL igebr2d( ictxt, 'All', ' ', i, 1, work, i, 0, 0 )
         i = 1
         CALL icopy( nmat, work( i ), 1, nval, 1 )
         i = i + nmat
         CALL icopy( nnb, work( i ), 1, nbval, 1 )
         i = i + nnb
         CALL icopy( ngrids, work( i ), 1, pval, 1 )
         i = i + ngrids
         CALL icopy( ngrids, work( i ), 1, qval, 1 )
*
      END IF
*
      CALL blacs_gridexit( ictxt )
*
      RETURN
*
   30 CONTINUE
      WRITE( nout, fmt = 9993 )
      CLOSE ( nin )
      IF( nout.NE.6 .AND. nout.NE.0 )
     $   CLOSE ( nout )
      CALL blacs_abort( ictxt, 1 )
*
      stop
*
 9999 FORMAT( a )
 9998 FORMAT( 'Routines pass computational tests if scaled residual ',
     $      'is less than ', g12.5 )
 9997 FORMAT( '                 ', 10i6 )
 9996 FORMAT( 2x, a5, '   :        ', 10i6 )
 9995 FORMAT( 'Relative machine precision (eps) is taken to be ',
     $      e18.6 )
 9994 FORMAT( ' Number of values of ', 5a,
     $      ' is less than 1 or greater ', 'than ', i2 )
 9993 FORMAT( ' Illegal input in file ', 40a, '.  Aborting run.' )
 9992 FORMAT( ' Blocking size too small at ', i2, ' must be >=6.' )
*
*     End of PZEVCINFO
*

Here is the call graph for this function:

Here is the caller graph for this function: