pjlaenv()

integer function pjlaenv	(	integer	ictxt,
		integer	ispec,
		character*( * )	name,
		character*( * )	opts,
		integer	n1,
		integer	n2,
		integer	n3,
		integer	n4
	)

Definition at line 1 of file xpjlaenv.f.

*
*  -- ScaLAPACK test routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     March 2, 2000
*
*     .. Scalar Arguments ..
      CHARACTER*( * )    NAME, OPTS
      INTEGER            ICTXT, ISPEC, N1, N2, N3, N4
*     ..
*
*  xpjlaenv.f versus pjlaenv.f
*  ===========================
*
*  xpjlaenv.f is used during testing to allow the timer/tester to
*  control pjlaenv's return values by setting common variables.
*  xpjlaenv.f guarantees that the return value is the same as the
*  corresponding value in common.  xpjlaenv.f either reads values
*  from common and uses them as return values or it writes the
*  return value to common.  Either way, xpjlaenv.f's return
*  value and the correpsonding value in common will always match.
*
*  When the common variable "TIMING" is set, the other common
*  variables are set to the values returned by xpjlaenv.f, else
*  xpjlaenv.f returns the values as set in common.
*
*  Purpose
*
*  =======
*
*  PJLAENV is called from the ScaLAPACK symmetric and Hermitian
*  tailored eigen-routines to choose
*  problem-dependent parameters for the local environment.  See ISPEC
*  for a description of the parameters.
*
*  This version provides a set of parameters which should give good,
*  but not optimal, performance on many of the currently available
*  computers.  Users are encouraged to modify this subroutine to set
*  the tuning parameters for their particular machine using the option
*  and problem size information in the arguments.
*
*  This routine will not function correctly if it is converted to all
*  lower case.  Converting it to all upper case is allowed.
*
*  Arguments
*  =========
*
*  ISPEC   (global input) INTEGER
*          Specifies the parameter to be returned as the value of
*          PJLAENV.
*          = 1: the data layout blocksize;
*          = 2: the panel blocking factor;
*          = 3: the algorithmic blocking factor;
*          = 4: execution path control;
*          = 5: maximum size for direct call to the LAPACK routine
*
*  NAME    (global input) CHARACTER*(*)
*          The name of the calling subroutine, in either upper case or
*          lower case.
*
*  OPTS    (global input) CHARACTER*(*)
*          The character options to the subroutine NAME, concatenated
*          into a single character string.  For example, UPLO = 'U',
*          TRANS = 'T', and DIAG = 'N' for a triangular routine would
*          be specified as OPTS = 'UTN'.
*
*  N1      (global input) INTEGER
*  N2      (global input) INTEGER
*  N3      (global input) INTEGER
*  N4      (global input) INTEGER
*          Problem dimensions for the subroutine NAME; these may not all
*          be required.
*
*          At present, only N1 is used, and it (N1) is used only for
*          'TTRD'
*
* (PJLAENV) (global or local output) INTEGER
*          >= 0: the value of the parameter specified by ISPEC
*          < 0:  if PJLAENV = -k, the k-th argument had an illegal
*          value.
*
*          Most parameters set via a call to PJLAENV must be identical
*          on all processors and hence PJLAENV will return the same
*          value to all procesors (i.e. global output).  However some,
*          in particular, the panel blocking factor can be different
*          on each processor and hence PJLAENV can return different
*          values on different processors (i.e. local output).
*
*  Further Details
*  ===============
*
*  The following conventions have been used when calling PJLAENV from
*  the ScaLAPACK routines:
*  1)  OPTS is a concatenation of all of the character options to
*      subroutine NAME, in the same order that they appear in the
*      argument list for NAME, even if they are not used in determining
*      the value of the parameter specified by ISPEC.
*  2)  The problem dimensions N1, N2, N3, N4 are specified in the order
*      that they appear in the argument list for NAME.  N1 is used
*      first, N2 second, and so on, and unused problem dimensions are
*      passed a value of -1.
*  3)  The parameter value returned by PJLAENV is checked for validity
*      in the calling subroutine.  For example, PJLAENV is used to
*      retrieve the optimal blocksize for STRTRI as follows:
*
*      NB = PJLAENV( 1, 'STRTRI', UPLO // DIAG, N, -1, -1, -1 )
*      IF( NB.LE.1 ) NB = MAX( 1, N )
*
*  PJLAENV is patterned after ILAENV and keeps the same interface in
*  anticipation of future needs, even though PJLAENV is only sparsely
*  used at present in ScaLAPACK.  Most ScaLAPACK codes use the input
*  data layout blocking factor as the algorithmic blocking factor -
*  hence there is no need or opportunity to set the algorithmic or
*  data decomposition blocking factor.
*
*  pXYYtevx.f and pXYYtgvx.f and pXYYttrd.f are the only codes which
*  call PJLAENV in this release.  pXYYtevx.f and pXYYtgvx.f redistribute
*  the data to the best data layout for each transformation.  pXYYttrd.f
*  uses a data layout blocking factor of 1 and a
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            CNAME, GLOBAL, SNAME, TIME
      CHARACTER          C1
      CHARACTER*2        C2, C4
      CHARACTER*3        C3
      CHARACTER*8        SUBNAM
      INTEGER            I, IC, IDUMM, IZ, MSZ, NB
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          char, ichar
*     ..
*
*
*     .. Scalars in Common ..
      INTEGER            ANB, BALANCED, BCKBLOCK, GSTBLOCK, INTERLEAVE,
     $                   LLTBLOCK, MINSZ, PNB, TIMING, TRSBLOCK,
     $                   TWOGEMMS
*     ..
*     .. External Subroutines ..
      EXTERNAL           igamx2d
*     ..
*     .. Common blocks ..
      COMMON             / blocksizes / gstblock, lltblock, bckblock,
     $                   trsblock
      COMMON             / minsize / minsz
      COMMON             / pjlaenvtiming / timing
      COMMON             / tailoredopts / pnb, anb, interleave,
     $                   balanced, twogemms
*     ..
*     .. Executable Statements ..
*
      time = ( timing.EQ.1 )
*
*
      GO TO ( 10, 10, 10, 10, 10 )ispec
*
*     Invalid value for ISPEC
*
      pjlaenv = -1
      RETURN
*
   10 CONTINUE
*
*     Convert NAME to upper case if the first character is lower case.
*
      pjlaenv = 1
      subnam = name
      ic = ichar( subnam( 1: 1 ) )
      iz = ichar( 'Z' )
      IF( iz.EQ.100 .OR. iz.EQ.122 ) THEN
*
*        ASCII character set
*
         IF( ic.GE.97 .AND. ic.LE.122 ) THEN
            subnam( 1: 1 ) = char( ic-32 )
            DO 20 i = 2, 6
               ic = ichar( subnam( i: i ) )
               IF( ic.GE.97 .AND. ic.LE.122 )
     $            subnam( i: i ) = char( ic-32 )
   20       CONTINUE
         END IF
*
      ELSE IF( iz.EQ.233 .OR. iz.EQ.169 ) THEN
*
*        EBCDIC character set
*
         IF( ( ic.GE.129 .AND. ic.LE.137 ) .OR.
     $       ( ic.GE.145 .AND. ic.LE.153 ) .OR.
     $       ( ic.GE.162 .AND. ic.LE.169 ) ) THEN
            subnam( 1: 1 ) = char( ic+64 )
            DO 30 i = 2, 6
               ic = ichar( subnam( i: i ) )
               IF( ( ic.GE.129 .AND. ic.LE.137 ) .OR.
     $             ( ic.GE.145 .AND. ic.LE.153 ) .OR.
     $             ( ic.GE.162 .AND. ic.LE.169 ) )subnam( i:
     $             i ) = char( ic+64 )
   30       CONTINUE
         END IF
*
      ELSE IF( iz.EQ.218 .OR. iz.EQ.250 ) THEN
*
*        Prime machines:  ASCII+128
*
         IF( ic.GE.225 .AND. ic.LE.250 ) THEN
            subnam( 1: 1 ) = char( ic-32 )
            DO 40 i = 2, 6
               ic = ichar( subnam( i: i ) )
               IF( ic.GE.225 .AND. ic.LE.250 )
     $            subnam( i: i ) = char( ic-32 )
   40       CONTINUE
         END IF
      END IF
*
      c1 = subnam( 2: 2 )
      sname = c1.EQ.'S' .OR. c1.EQ.'D'
      cname = c1.EQ.'C' .OR. c1.EQ.'Z'
      IF( .NOT.( cname .OR. sname ) )
     $   RETURN
      c2 = subnam( 3: 4 )
      c3 = subnam( 5: 7 )
      c4 = c3( 2: 3 )
*
*     This is to keep ftnchek happy
*
      IF( ( n2+n3+n4 )*0.NE.0 ) THEN
         c4 = opts
         c3 = c4
      END IF
*
      GO TO ( 50, 60, 70, 80, 90 )ispec
*
   50 CONTINUE
*
*     ISPEC = 1:  data layout block size
*     (global - all processes must use the same value)
*
*     In these examples, separate code is provided for setting NB for
*     real and complex.  We assume that NB will take the same value in
*     single or double precision.
*
      nb = 1
*
      IF( c2.EQ.'SY' .OR. c2.EQ.'HE' ) THEN
         IF( c3.EQ.'LLT' ) THEN
            IF( sname ) THEN
               nb = 64
            ELSE
               nb = 64
            END IF
            IF( time ) THEN
               lltblock = nb
            ELSE
               nb = lltblock
               IF( nb.LE.0 ) THEN
                  print *, 'xpjlaenv.f ERROR common variable LLTBLOCK',
     $               ' may be unitialized'
c                 CALL EXIT( 13 )
                  stop
               END IF
            END IF
         ELSE IF( c3.EQ.'TTR' ) THEN
            IF( sname ) THEN
               nb = 1
            ELSE
               nb = 1
            END IF
         ELSE IF( c3.EQ.'GST' ) THEN
            IF( sname ) THEN
               nb = 32
            ELSE
               nb = 32
            END IF
            IF( time ) THEN
               gstblock = nb
            ELSE
               nb = gstblock
               IF( nb.LE.0 ) THEN
                  print *, 'xpjlaenv.f ERROR common variable GSTBLOCK',
     $               ' may be unitialized'
c                 CALL EXIT( 13 )
                  stop
               END IF
            END IF
         ELSE IF( c3.EQ.'BCK' ) THEN
            IF( sname ) THEN
               nb = 32
            ELSE
               nb = 32
            END IF
            IF( time ) THEN
               bckblock = nb
            ELSE
               nb = bckblock
               IF( nb.LE.0 ) THEN
                  print *, 'xpjlaenv.f ERROR common variable BCKBLOCK',
     $               ' may be unitialized'
c                 CALL EXIT( 13 )
                  stop
               END IF
            END IF
         ELSE IF( c3.EQ.'TRS' ) THEN
            IF( sname ) THEN
               nb = 64
            ELSE
               nb = 64
            END IF
            IF( time ) THEN
               trsblock = nb
            ELSE
               nb = trsblock
               IF( nb.LE.0 ) THEN
                  print *, 'xpjlaenv.f ERROR common variable TRSBLOCK',
     $               ' may be unitialized'
c                 CALL EXIT( 13 )
                  stop 
               END IF
            END IF
         END IF
      END IF
*
*
      pjlaenv = nb
      global = .true.
      GO TO 100
*
   60 CONTINUE
*
*     ISPEC = 2:  panel blocking factor (Used only in PxyyTTRD)
*     (local - different processes may use different values)
*
      nb = 16
      IF( c2.EQ.'SY' .OR. c2.EQ.'HE' ) THEN
         IF( c3.EQ.'TTR' ) THEN
            IF( sname ) THEN
               nb = 32
            ELSE
               nb = 32
            END IF
         END IF
      END IF
      IF( time ) THEN
         pnb = nb
      ELSE
         nb = pnb
         IF( nb.LE.0 ) THEN
            print *, 'xpjlaenv.f ERROR common variable PNB',
     $         ' may be unitialized'
c           CALL EXIT( 13 )
            stop
         END IF
      END IF
      pjlaenv = nb
      global = .false.
      GO TO 100
*
*
   70 CONTINUE
*
*     ISPEC = 3:  algorithmic blocking factor (Used only in PxyyTTRD)
*     (global - all processes must use the same value)
*
      nb = 16
      nb = 1
      IF( c2.EQ.'SY' .OR. c2.EQ.'HE' ) THEN
         IF( c3.EQ.'TTR' ) THEN
            IF( sname ) THEN
               nb = 16
            ELSE
               nb = 16
            END IF
         END IF
      END IF
      IF( time ) THEN
         anb = nb
      ELSE
         nb = anb
         IF( nb.LE.0 ) THEN
            print *, 'xpjlaenv.f ERROR common variable ANB',
     $         ' may be unitialized'
c           CALL EXIT( 13 )
            stop
         END IF
      END IF
      pjlaenv = nb
      global = .true.
      GO TO 100
*
   80 CONTINUE
*
*     ISPEC = 4:  Execution path options (Used only in PxyyTTRD)
*     (global - all processes must use the same value)
*
      pjlaenv = -4
      IF( c2.EQ.'SY' .OR. c2.EQ.'HE' ) THEN
         IF( c3.EQ.'TTR' ) THEN
*           V and H interleaved (default is not interleaved)
            IF( n1.EQ.1 ) THEN
               pjlaenv = 1
               IF( time ) THEN
                  interleave = pjlaenv
               ELSE
                  pjlaenv = interleave
               END IF
            END IF
*
*           Two ZGEMMs (default is one ZGEMM)
            IF( n1.EQ.2 ) THEN
               pjlaenv = 0
               IF( time ) THEN
                  twogemms = pjlaenv
               ELSE
                  pjlaenv = twogemms
               END IF
            END IF
*           Balanced Update (default is minimum communication update)
            IF( n1.EQ.3 ) THEN
               pjlaenv = 0
               IF( time ) THEN
                  balanced = pjlaenv
               ELSE
                  pjlaenv = balanced
               END IF
            END IF
         END IF
      END IF
      global = .true.
      GO TO 100
*
   90 CONTINUE
*
*     ISPEC = 5:  Minimum size to justify call to parallel code
*     (global - all processes must use the same value)
*
      msz = 0
      IF( c2.EQ.'SY' .OR. c2.EQ.'HE' ) THEN
         IF( c3.EQ.'TTR' ) THEN
            IF( sname ) THEN
               msz = 100
            ELSE
               msz = 100
            END IF
         END IF
      END IF
      IF( time ) THEN
         minsz = msz
      ELSE
         msz = minsz
      END IF
      pjlaenv = msz
      global = .true.
      GO TO 100
*
  100 CONTINUE
*
      IF( global ) THEN
         idumm = 0
         CALL igamx2d( ictxt, 'All', ' ', 1, 1, pjlaenv, 1, idumm,
     $                 idumm, -1, -1, idumm )
      END IF
*
*
*
      RETURN
*
*     End of PJLAENV
*

Here is the call graph for this function: