pserrdot()

subroutine pserrdot	(	real	errbnd,
		integer	n,
		real	sclr,
		real, dimension( * )	x,
		integer	incx,
		real, dimension( * )	y,
		integer	incy,
		real	prec
	)

Definition at line 2932 of file psblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      REAL               ERRBND, PREC, SCLR
*     ..
*     .. Array Arguments ..
      REAL               X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PSERRDOT  serially  computes  the  dot product X**T * Y and returns a
*  scaled relative acceptable error bound on the result.
*
*  Notes
*  =====
*
*  If dot1 = SCLR and  dot2 are two different computed results, and dot1
*  is being assumed to be correct, we require
*
*     abs( dot1 - dot2 ) <= ERRBND = ERRFACT * abs( dot1 ),
*
*  where ERRFACT is computed as the maximum of the positive and negative
*  partial  sums  multiplied  by  a constant proportional to the machine
*  precision.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) REAL
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  N       (global input) INTEGER
*          On entry, N specifies the length of the vector operands.
*
*  SCLR    (global output) REAL
*          On exit,  SCLR  specifies  the dot product of the two vectors
*          X and Y.
*
*  X       (global input) REAL array
*          On   entry,   X   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCX ) ).  Before  entry,  the incremen-
*          ted array X must contain the vector x.
*
*  INCX    (global input) INTEGER.
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  Y       (global input) REAL array
*          On   entry,   Y   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCY ) ).  Before  entry,  the incremen-
*          ted array Y must contain the vector y.
*
*  INCY    (global input) INTEGER.
*          On entry, INCY specifies the increment for the elements of Y.
*          INCY must not be zero.
*
*  PREC    (global input) REAL
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO, ZERO
      parameter( one = 1.0e+0, two = 2.0e+0,
     $                   zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, IY
      REAL               ADDBND, FACT, SUMNEG, SUMPOS, TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      ix = 1
      iy = 1
      sclr = zero
      sumpos = zero
      sumneg = zero
      fact = two * ( one + prec )
      addbnd = two * two * two * prec
*
      DO 10 i = 1, n
         tmp = x( ix ) * y( iy )
         sclr = sclr + tmp
         IF( tmp.GE.zero ) THEN
            sumpos = sumpos + tmp * fact
         ELSE
            sumneg = sumneg - tmp * fact
         END IF
         ix = ix + incx
         iy = iy + incy
   10 CONTINUE
*
      errbnd = addbnd * max( sumpos, sumneg )
*
      RETURN
*
*     End of PSERRDOT
*

Here is the caller graph for this function: