pserraxpy()

subroutine pserraxpy	(	real	errbnd,
		real	psclr,
		real	x,
		real	y,
		real	prec
	)

Definition at line 3312 of file psblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      REAL               ERRBND, PREC, PSCLR, X, Y
*     ..
*
*  Purpose
*  =======
*
*  PSERRAXPY  serially computes Y := Y + PSCLR * X and returns a scaled
*  relative acceptable error bound on the result.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) REAL
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  PSCLR   (global input) REAL
*          On entry, PSCLR specifies the scale factor.
*
*  X       (global input) REAL
*          On entry, X  specifies the scalar to be scaled.
*
*  Y       (global input/global output) REAL
*          On entry, Y specifies the scalar to be added. On exit, Y con-
*          tains the resulting scalar.
*
*  PREC    (global input) REAL
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO, ZERO
      parameter( one = 1.0e+0, two = 2.0e+0,
     $                   zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               ADDBND, FACT, SUMPOS, SUMNEG, TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      sumpos = zero
      sumneg = zero
      fact = one + two * prec
      addbnd = two * two * two * prec
*
      tmp = psclr * x
      IF( tmp.GE.zero ) THEN
         sumpos = sumpos + tmp * fact
      ELSE
         sumneg = sumneg - tmp * fact
      END IF
*
      tmp = y
      IF( tmp.GE.zero ) THEN
         sumpos = sumpos + tmp
      ELSE
         sumneg = sumneg - tmp
      END IF
*
      y = y + ( psclr * x )
*
      errbnd = addbnd * max( sumpos, sumneg )
*
      RETURN
*
*     End of PSERRAXPY
*

Here is the caller graph for this function: