psqrt16()

subroutine psqrt16	(	character	trans,
		integer	m,
		integer	n,
		integer	nrhs,
		real, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		real, dimension( * )	b,
		integer	ib,
		integer	jb,
		integer, dimension( * )	descb,
		real, dimension( * )	rwork,
		real	resid
	)

Definition at line 1 of file psqrt16.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IA, IB, IX, JA, JB, JX, M, N, NRHS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * ), DESCX( * )
      REAL               A( * ), B( * ), RWORK( * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  PSQRT16 computes the residual for a solution of a system of linear
*  equations  sub( A )*sub( X ) = B  or  sub( A' )*sub( X ) = B:
*     RESID = norm(B - sub( A )*sub( X ) ) /
*             ( max(m,n) * norm(sub( A ) ) * norm(sub( X ) ) * EPS ),
*  where EPS is the machine epsilon, sub( A ) denotes
*  A(IA:IA+N-1,JA,JA+N-1), and sub( X ) denotes
*  X(IX:IX+N-1, JX:JX+NRHS-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  TRANS   (global input) CHARACTER*1
*          Specifies the form of the system of equations:
*          = 'N':  sub( A )*sub( X ) = sub( B )
*          = 'T':  sub( A' )*sub( X )= sub( B ), where A' is the
*                  transpose of sub( A ).
*          = 'C':  sub( A' )*sub( X )= B, where A' is the transpose
*                  of sub( A ).
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  NRHS    (global input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the distributed submatrix sub( B ). NRHS >= 0.
*
*  A       (local input) REAL pointer into the local
*          memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          The original M x N matrix A.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  X       (local input) REAL pointer into the local
*          memory to an array of dimension (LLD_X,LOCc(JX+NRHS-1)). This
*          array contains the local pieces of the computed solution
*          distributed vectors for the system of linear equations.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  B       (local input/local output) REAL pointer into
*          the local memory to an array of dimension
*          (LLD_B,LOCc(JB+NRHS-1)).  On entry, this array contains the
*          local pieces of the distributes right hand side vectors for
*          the system of linear equations. On exit, sub( B ) is over-
*          written with the difference sub( B ) - sub( A )*sub( X ) or
*          sub( B ) - sub( A )'*sub( X ).
*
*  IB      (global input) INTEGER
*          The row index in the global array B indicating the first
*          row of sub( B ).
*
*  JB      (global input) INTEGER
*          The column index in the global array B indicating the
*          first column of sub( B ).
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix B.
*
*  RWORK   (local workspace) REAL array, dimension (LRWORK)
*          LWORK >= Nq0 if TRANS = 'N', and LRWORK >= Mp0 otherwise.
*
*          where
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          Mp0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*          Nq0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  RESID   (global output) REAL
*          The maximum over the number of right hand sides of
*          norm( sub( B )- sub( A )*sub( X ) ) /
*          ( max(m,n) * norm( sub( A ) ) * norm( sub( X ) ) * EPS ).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            ICTXT, IDUMM, J, MYCOL, MYROW, N1, N2, NPCOL,
     $                   NPROW
      REAL               ANORM, BNORM, EPS, XNORM
*     ..
*     .. Local Arrays ..
      REAL               TEMP( 2 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               PSLAMCH, PSLANGE
      EXTERNAL           lsame, pslamch, pslange
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, psasum, psgemm, sgamx2d
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Quick exit if M = 0 or N = 0 or NRHS = 0
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.EQ.0 ) THEN
         resid = zero
         RETURN
      END IF
*
      IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
         anorm = pslange( 'I', m, n, a, ia, ja, desca, rwork )
         n1 = n
         n2 = m
      ELSE
         anorm = pslange( '1', m, n, a, ia, ja, desca, rwork )
         n1 = m
         n2 = n
      END IF
*
      eps = pslamch( ictxt, 'Epsilon' )
*
*     Compute  B - sub( A )*sub( X )  (or  B - sub( A' )*sub( X ) ) and
*     store in B.
*
      CALL psgemm( trans, 'No transpose', n1, nrhs, n2, -one, a, ia,
     $            ja, desca, x, ix, jx, descx, one, b, ib, jb, descb )
*
*     Compute the maximum over the number of right hand sides of
*        norm( sub( B ) - sub( A )*sub( X ) ) /
*        ( max(m,n) * norm( sub( A ) ) * norm( sub( X ) ) * EPS ).
*
      resid = zero
      DO 10 j = 1, nrhs
*
         CALL psasum( n1, bnorm, b, ib, jb+j-1, descb, 1 )
         CALL psasum( n2, xnorm, x, ix, jx+j-1, descx, 1 )
*
*        Only the process columns owning the vector operands will have
*        the correct result, the other will have zero.
*
         temp( 1 ) = bnorm
         temp( 2 ) = xnorm
         idumm = 0
         CALL sgamx2d( ictxt, 'All', ' ', 2, 1, temp, 2, idumm, idumm,
     $                 -1, -1, idumm )
         bnorm = temp( 1 )
         xnorm = temp( 2 )
*
*        Every processes have ANORM, BNORM and XNORM now.
*
         IF( anorm.EQ.zero .AND. bnorm.EQ.zero ) THEN
            resid = zero
         ELSE IF( anorm.LE.zero .OR. xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) /
     $              ( max( m, n )*eps ) )
         END IF
*
   10 CONTINUE
*
      RETURN
*
*     End of PSQRT16
*

Here is the caller graph for this function: