immtadd()

subroutine immtadd	(	integer	m,
		integer	n,
		integer	alpha,
		integer, dimension( lda, * )	a,
		integer	lda,
		integer	beta,
		integer, dimension( ldb, * )	b,
		integer	ldb
	)

Definition at line 1 of file immtadd.f.

*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, M, N
      INTEGER            ALPHA, BETA
*     ..
*     .. Array Arguments ..
      INTEGER            A( LDA, * ), B( LDB, * )
*     ..
*
*  Purpose
*  =======
*
*  IMMTADD performs the following operation:
*
*     B := alpha * A' + beta * B,
*
*  where alpha, beta are scalars; A is an m by n matrix and B is an n by
*  m matrix.
*
*  Arguments
*  =========
*
*  M       (local input) INTEGER
*          On entry, M  specifies the number of rows of A and the number
*          of columns of B. M must be at least zero.
*
*  N       (local input) INTEGER
*          On entry, N  specifies the number of rows of B and the number
*          of columns of A. N must be at least zero.
*
*  ALPHA   (local input) INTEGER
*          On entry,  ALPHA  specifies the scalar alpha. When  ALPHA  is
*          supplied as zero then the local entries of the array  A  need
*          not be set on input.
*
*  A       (local input) INTEGER array
*          On entry, A is an array of dimension ( LDA, N ).
*
*  LDA     (local input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, M ).
*
*  BETA    (local input) INTEGER
*          On entry,  BETA  specifies the scalar beta. When BETA is sup-
*          plied as zero then the local entries of the array B need  not
*          be set on input.
*
*  B       (local input/local output) INTEGER array
*          On entry, B is an array of dimension ( LDB, M ). On exit, the
*          leading m by n part of A has been added to the leading n by m
*          part of B.
*
*  LDB     (local input) INTEGER
*          On entry, LDB specifies the leading dimension of the array B.
*          LDB must be at least max( 1, N ).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ONE, ZERO
      parameter( one = 1, zero = 0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. Executable Statements ..
*
      IF( m.GE.n ) THEN
         IF( alpha.EQ.one ) THEN
            IF( beta.EQ.zero ) THEN
               DO 20 j = 1, n
                  DO 10 i = 1, m
                     b( j, i ) = a( i, j )
   10             CONTINUE
   20          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 40 j = 1, n
                  DO 30 i = 1, m
                     b( j, i ) = a( i, j ) + beta * b( j, i )
   30             CONTINUE
   40          CONTINUE
            ELSE
               DO 60 j = 1, n
                  DO 50 i = 1, m
                     b( j, i ) = a( i, j ) + b( j, i )
   50             CONTINUE
   60          CONTINUE
            END IF
         ELSE IF( alpha.NE.zero ) THEN
            IF( beta.EQ.zero ) THEN
               DO 80 j = 1, n
                  DO 70 i = 1, m
                     b( j, i ) = alpha * a( i, j )
   70             CONTINUE
   80          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 100 j = 1, n
                  DO 90 i = 1, m
                     b( j, i ) = alpha * a( i, j ) + beta * b( j, i )
   90             CONTINUE
  100          CONTINUE
            ELSE
               DO 120 j = 1, n
                  DO 110 i = 1, m
                     b( j, i ) = alpha * a( i, j ) + b( j, i )
  110             CONTINUE
  120          CONTINUE
            END IF
         ELSE
            IF( beta.EQ.zero ) THEN
               DO 140 j = 1, m
                  DO 130 i = 1, n
                     b( i, j ) = zero
  130             CONTINUE
  140          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 160 j = 1, m
                  DO 150 i = 1, n
                     b( i, j ) = beta * b( i, j )
  150             CONTINUE
  160          CONTINUE
            END IF
         END IF
      ELSE
         IF( alpha.EQ.one ) THEN
            IF( beta.EQ.zero ) THEN
               DO 180 j = 1, m
                  DO 170 i = 1, n
                     b( i, j ) = a( j, i )
  170             CONTINUE
  180          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 200 j = 1, m
                  DO 190 i = 1, n
                     b( i, j ) = a( j, i ) + beta * b( i, j )
  190             CONTINUE
  200          CONTINUE
            ELSE
               DO 220 j = 1, m
                  DO 210 i = 1, n
                     b( i, j ) = a( j, i ) + b( i, j )
  210             CONTINUE
  220          CONTINUE
            END IF
         ELSE IF( alpha.NE.zero ) THEN
            IF( beta.EQ.zero ) THEN
               DO 240 j = 1, m
                  DO 230 i = 1, n
                     b( i, j ) = alpha * a( j, i )
  230             CONTINUE
  240          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 260 j = 1, m
                  DO 250 i = 1, n
                     b( i, j ) = alpha * a( j, i ) + beta * b( i, j )
  250             CONTINUE
  260          CONTINUE
            ELSE
               DO 280 j = 1, m
                  DO 270 i = 1, n
                     b( i, j ) = alpha * a( j, i ) + b( i, j )
  270             CONTINUE
  280          CONTINUE
            END IF
         ELSE
            IF( beta.EQ.zero ) THEN
               DO 300 j = 1, m
                  DO 290 i = 1, n
                     b( i, j ) = zero
  290             CONTINUE
  300          CONTINUE
            ELSE IF( beta.NE.one ) THEN
               DO 320 j = 1, m
                  DO 310 i = 1, n
                     b( i, j ) = beta * b( i, j )
  310             CONTINUE
  320          CONTINUE
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of IMMTADD
*