pdmatee()

subroutine pdmatee	(	integer	ictxt,
		integer	nout,
		external	subptr,
		integer	scode,
		character*7	sname
	)

Definition at line 1189 of file pdblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER             ICTXT, NOUT, SCODE
*     ..
*     .. Array Arguments ..
      CHARACTER*7         SNAME
*     ..
*     .. Subroutine Arguments ..
      EXTERNAL            subptr
*     ..
*
*  Purpose
*  =======
*
*  PDMATEE  tests  whether  the  PBLAS respond correctly to a bad matrix
*  argument.  Each  matrix <mat> is described by: <mat>, I<mat>, J<mat>,
*  and DESC<mat>.  Out  of  all these, only I<vec>, J<vec> and DESC<mat>
*  can be tested.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  ICTXT   (local input) INTEGER
*          On entry,  ICTXT  specifies the BLACS context handle, indica-
*          ting the global  context of the operation. The context itself
*          is global, but the value of ICTXT is local.
*
*  NOUT    (global input) INTEGER
*          On entry, NOUT specifies the unit number for the output file.
*          When NOUT is 6, output to screen,  when  NOUT is 0, output to
*          stderr. NOUT is only defined for process 0.
*
*  SUBPTR  (global input) SUBROUTINE
*          On entry,  SUBPTR  is  a  subroutine. SUBPTR must be declared
*          EXTERNAL in the calling subroutine.
*
*  SCODE   (global input) INTEGER
*          On entry, SCODE specifies the calling sequence code.
*
*  SNAME   (global input) CHARACTER*(*)
*          On entry,  SNAME  specifies  the subroutine name calling this
*          subprogram.
*
*  Calling sequence encodings
*  ==========================
*
*  code Formal argument list                                Examples
*
*  11   (n,      v1,v2)                                     _SWAP, _COPY
*  12   (n,s1,   v1   )                                     _SCAL, _SCAL
*  13   (n,s1,   v1,v2)                                     _AXPY, _DOT_
*  14   (n,s1,i1,v1   )                                     _AMAX
*  15   (n,u1,   v1   )                                     _ASUM, _NRM2
*
*  21   (     trans,     m,n,s1,m1,v1,s2,v2)                _GEMV
*  22   (uplo,             n,s1,m1,v1,s2,v2)                _SYMV, _HEMV
*  23   (uplo,trans,diag,  n,   m1,v1      )                _TRMV, _TRSV
*  24   (                m,n,s1,v1,v2,m1)                   _GER_
*  25   (uplo,             n,s1,v1,   m1)                   _SYR
*  26   (uplo,             n,u1,v1,   m1)                   _HER
*  27   (uplo,             n,s1,v1,v2,m1)                   _SYR2, _HER2
*
*  31   (          transa,transb,     m,n,k,s1,m1,m2,s2,m3) _GEMM
*  32   (side,uplo,                   m,n,  s1,m1,m2,s2,m3) _SYMM, _HEMM
*  33   (     uplo,trans,               n,k,s1,m1,   s2,m3) _SYRK
*  34   (     uplo,trans,               n,k,u1,m1,   u2,m3) _HERK
*  35   (     uplo,trans,               n,k,s1,m1,m2,s2,m3) _SYR2K
*  36   (     uplo,trans,               n,k,s1,m1,m2,u2,m3) _HER2K
*  37   (                             m,n,  s1,m1,   s2,m3) _TRAN_
*  38   (side,uplo,transa,       diag,m,n,  s1,m1,m2      ) _TRMM, _TRSM
*  39   (          trans,             m,n,  s1,m1,   s2,m3) _GEADD
*  40   (     uplo,trans,             m,n,  s1,m1,   s2,m3) _TRADD
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER             APOS
*     ..
*     .. External Subroutines ..
      EXTERNAL            pdchkmat
*     ..
*     .. Executable Statements ..
*
*     Level 2 PBLAS
*
      IF( scode.EQ.21 .OR. scode.EQ.23 ) THEN
*
*        Check 1st (and only) matrix
*
         apos = 5
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
      ELSE IF( scode.EQ.22 ) THEN
*
*        Check 1st (and only) matrix
*
         apos = 4
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
      ELSE IF( scode.EQ.24 .OR. scode.EQ.27 ) THEN
*
*        Check 1st (and only) matrix
*
         apos = 14
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
      ELSE IF( scode.EQ.25 .OR. scode.EQ.26 ) THEN
*
*        Check 1st (and only) matrix
*
         apos = 9
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*     Level 3 PBLAS
*
      ELSE IF( scode.EQ.31 ) THEN
*
*        Check 1st matrix
*
         apos = 7
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 11
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'B', apos )
*
*        Check 3nd matrix
*
         apos = 16
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      ELSE IF( scode.EQ.32 .OR. scode.EQ.35 .OR. scode.EQ.36 ) THEN
*
*        Check 1st matrix
*
         apos = 6
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 10
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'B', apos )
*
*        Check 3nd matrix
*
         apos = 15
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      ELSE IF( scode.EQ.33 .OR. scode.EQ.34 ) THEN
*
*        Check 1st matrix
*
         apos = 6
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 11
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      ELSE IF( scode.EQ.37 ) THEN
*
*        Check 1st matrix
*
         apos = 4
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 9
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      ELSE IF( scode.EQ.38 ) THEN
*
*        Check 1st matrix
*
         apos = 8
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 12
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'B', apos )
*
      ELSE IF( scode.EQ.39 ) THEN
*
*        Check 1st matrix
*
         apos = 5
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 10
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      ELSE IF( scode.EQ.40 ) THEN
*
*        Check 1st matrix
*
         apos = 6
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'A', apos )
*
*        Check 2nd matrix
*
         apos = 11
         CALL pdchkmat( ictxt, nout, subptr, scode, sname, 'C', apos )
*
      END IF
*
      RETURN
*
*     End of PDMATEE
*

Here is the call graph for this function:

Here is the caller graph for this function: