pcvmch()

subroutine pcvmch	(	integer	ictxt,
		character*1	trans,
		character*1	uplo,
		integer	m,
		integer	n,
		complex	alpha,
		complex, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	incx,
		complex, dimension( * )	y,
		integer	iy,
		integer	jy,
		integer, dimension( * )	descy,
		integer	incy,
		complex, dimension( * )	a,
		complex, dimension( * )	pa,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	g,
		real	err,
		integer	info
	)

Definition at line 4603 of file pcblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        TRANS, UPLO
      INTEGER            IA, ICTXT, INCX, INCY, INFO, IX, IY, JA, JX,
     $                   JY, M, N
      REAL               ERR
      COMPLEX            ALPHA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCX( * ), DESCY( * )
      REAL               G( * )
      COMPLEX            A( * ), PA( * ), X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PCVMCH checks the results of the computational tests.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  ICTXT   (local input) INTEGER
*          On entry,  ICTXT  specifies the BLACS context handle, indica-
*          ting the global  context of the operation. The context itself
*          is global, but the value of ICTXT is local.
*
*  TRANS   (global input) CHARACTER*1
*          On entry,  TRANS  specifies  the operation to be performed in
*          the complex cases:
*             if TRANS = 'C',
*                sub( A ) := sub( A ) + alpha * sub( X ) * sub( Y )**H,
*             otherwise
*                sub( A ) := sub( A ) + alpha * sub( X ) * sub( Y )**T.
*
*  UPLO    (global input) CHARACTER*1
*          On entry, UPLO specifies which part of the submatrix sub( A )
*          is to be referenced as follows:
*             If UPLO = 'L', only the lower triangular part,
*             If UPLO = 'U', only the upper triangular part,
*             else the entire matrix is to be referenced.
*
*  M       (global input) INTEGER
*          On entry,  M  specifies  the  number of rows of the submatrix
*          operand matrix A. M must be at least zero.
*
*  N       (global input) INTEGER
*          On entry,  N  specifies  the  number of columns of the subma-
*          trix operand matrix A. N must be at least zero.
*
*  ALPHA   (global input) COMPLEX
*          On entry, ALPHA specifies the scalar alpha.
*
*  X       (local input) COMPLEX array
*          On entry, X is an array of  dimension  (DESCX( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PX.
*
*  IX      (global input) INTEGER
*          On entry, IX  specifies X's global row index, which points to
*          the beginning of the submatrix sub( X ).
*
*  JX      (global input) INTEGER
*          On entry, JX  specifies X's global column index, which points
*          to the beginning of the submatrix sub( X ).
*
*  DESCX   (global and local input) INTEGER array
*          On entry, DESCX  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix X.
*
*  INCX    (global input) INTEGER
*          On entry,  INCX   specifies  the  global  increment  for  the
*          elements of  X.  Only two values of  INCX   are  supported in
*          this version, namely 1 and M_X. INCX  must not be zero.
*
*  Y       (local input) COMPLEX array
*          On entry, Y is an array of  dimension  (DESCY( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PY.
*
*  IY      (global input) INTEGER
*          On entry, IY  specifies Y's global row index, which points to
*          the beginning of the submatrix sub( Y ).
*
*  JY      (global input) INTEGER
*          On entry, JY  specifies Y's global column index, which points
*          to the beginning of the submatrix sub( Y ).
*
*  DESCY   (global and local input) INTEGER array
*          On entry, DESCY  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix Y.
*
*  INCY    (global input) INTEGER
*          On entry,  INCY   specifies  the  global  increment  for  the
*          elements of  Y.  Only two values of  INCY   are  supported in
*          this version, namely 1 and M_Y. INCY  must not be zero.
*
*  A       (local input/local output) COMPLEX array
*          On entry, A is an array of  dimension  (DESCA( M_ ),*).  This
*          array contains a local copy of the initial entire matrix PA.
*
*  PA      (local input) COMPLEX array
*          On entry, PA is an array of dimension (DESCA( LLD_ ),*). This
*          array contains the local entries of the matrix PA.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  G       (workspace) REAL array
*          On entry, G is an array of dimension at least MAX( M, N ).  G
*          is used to compute the gauges.
*
*  ERR     (global output) REAL
*          On exit, ERR specifies the largest error in absolute value.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, the result is less than half accurate.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLREP, CTRAN, LOWER, ROWREP, UPPER
      INTEGER            I, IACOL, IAROW, IB, IBEG, ICURROW, IEND, IIA,
     $                   IN, IOFFA, IOFFX, IOFFY, J, JJA, KK, LDA, LDPA,
     $                   LDX, LDY, MYCOL, MYROW, NPCOL, NPROW
      REAL               EPS, ERRI, GTMP
      COMPLEX            ATMP, C
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igsum2d, pb_infog2l, sgamx2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               PSLAMCH
      EXTERNAL           lsame, pslamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, conjg, max, min, mod, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL               ABS1
      abs1( c ) = abs( real( c ) ) + abs( aimag( c ) )
*     ..
*     .. Executable Statements ..
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      eps = pslamch( ictxt, 'eps' )
*
      ctran = lsame( trans, 'C' )
      upper = lsame( uplo, 'U' )
      lower = lsame( uplo, 'L' )
*
      lda = max( 1, desca( m_ ) )
      ldx = max( 1, descx( m_ ) )
      ldy = max( 1, descy( m_ ) )
*
*     Compute expected result in A using data in A, X and Y.
*     Compute gauges in G. This part of the computation is performed
*     by every process in the grid.
*
      DO 70 j = 1, n
*
         ioffy = iy + ( jy - 1 ) * ldy + ( j - 1 ) * incy
*
         IF( lower ) THEN
            ibeg = j
            iend = m
            DO 10 i = 1, j-1
               g( i ) = zero
   10       CONTINUE
         ELSE IF( upper ) THEN
            ibeg = 1
            iend = j
            DO 20 i = j+1, m
               g( i ) = zero
   20       CONTINUE
         ELSE
            ibeg = 1
            iend = m
         END IF
*
         DO 30 i = ibeg, iend
*
            ioffx = ix + ( jx - 1 ) * ldx + ( i - 1 ) * incx
            ioffa = ia + i - 1 + ( ja + j - 2 ) * lda
            IF( ctran ) THEN
               atmp = x( ioffx ) * conjg( y( ioffy ) )
            ELSE
               atmp = x( ioffx ) * y( ioffy )
            END IF
            gtmp = abs1( x( ioffx ) ) * abs1( y( ioffy ) )
            g( i ) = abs1( alpha ) * gtmp + abs1( a( ioffa ) )
            a( ioffa ) = alpha * atmp + a( ioffa )
*
   30    CONTINUE
*
*        Compute the error ratio for this result.
*
         info = 0
         err  = zero
         ldpa = desca( lld_ )
         ioffa = ia + ( ja + j - 2 ) * lda
         CALL pb_infog2l( ia, ja+j-1, desca, nprow, npcol, myrow, mycol,
     $                    iia, jja, iarow, iacol )
         rowrep = ( iarow.EQ.-1 )
         colrep = ( iacol.EQ.-1 )
*
         IF( mycol.EQ.iacol .OR. colrep ) THEN
*
            icurrow = iarow
            ib = desca( imb_ ) - ia + 1
            IF( ib.LE.0 )
     $         ib = ( ( -ib ) / desca( mb_ ) + 1 ) * desca( mb_ ) + ib
            ib = min( ib, m )
            in = ia + ib - 1
*
            DO 40 i = ia, in
*
               IF( myrow.EQ.icurrow .OR. rowrep ) THEN
                  erri = abs( pa( iia+(jja-1)*ldpa ) - a( ioffa ) )/eps
                  IF( g( i-ia+1 ).NE.zero )
     $               erri = erri / g( i-ia+1 )
                  err = max( err, erri )
                  IF( err*sqrt( eps ).GE.one )
     $               info = 1
                  iia = iia + 1
               END IF
*
               ioffa = ioffa + 1
*
   40       CONTINUE
*
            icurrow = mod( icurrow+1, nprow )
*
            DO 60 i = in+1, ia+m-1, desca( mb_ )
               ib = min( ia+m-i, desca( mb_ ) )
*
               DO 50 kk = 0, ib-1
*
                  IF( myrow.EQ.icurrow .OR. rowrep ) THEN
                     erri = abs( pa( iia+(jja-1)*ldpa )-a( ioffa ) )/eps
                     IF( g( i+kk-ia+1 ).NE.zero )
     $                  erri = erri / g( i+kk-ia+1 )
                     err = max( err, erri )
                     IF( err*sqrt( eps ).GE.one )
     $                  info = 1
                     iia = iia + 1
                  END IF
*
                  ioffa = ioffa + 1
*
   50          CONTINUE
*
               icurrow = mod( icurrow+1, nprow )
*
   60       CONTINUE
*
         END IF
*
*        If INFO = 0, all results are at least half accurate.
*
         CALL igsum2d( ictxt, 'All', ' ', 1, 1, info, 1, -1, mycol )
         CALL sgamx2d( ictxt, 'All', ' ', 1, 1, err, 1, i, j, -1, -1,
     $                 mycol )
         IF( info.NE.0 )
     $      GO TO 80
*
   70 CONTINUE
*
   80 CONTINUE
*
      RETURN
*
*     End of PCVMCH
*

Here is the call graph for this function:

Here is the caller graph for this function: