zdbtf2()

subroutine zdbtf2	(	integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		complex*16, dimension( ldab, * )	ab,
		integer	ldab,
		integer	info
	)

Definition at line 1 of file zdbtf2.f.

*
*  -- ScaLAPACK auxiliary routine (version 2.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*
*     Modified by Andrew J. Cleary in November, 96 from:
*  -- LAPACK auxiliary routine (preliminary version) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     August 6, 1991
*
*
*     .. Scalar Arguments ..
      INTEGER            INFO, KL, KU, LDAB, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16           AB( LDAB, * )
*     ..
*
*  Purpose
*  =======
*
*  Zdbtrf computes an LU factorization of a real m-by-n band matrix A
*  without using partial pivoting with row interchanges.
*
*  This is the unblocked version of the algorithm, calling Level 2 BLAS.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  KL      (input) INTEGER
*          The number of subdiagonals within the band of A.  KL >= 0.
*
*  KU      (input) INTEGER
*          The number of superdiagonals within the band of A.  KU >= 0.
*
*  AB      (input/output) COMPLEX*16         array, dimension (LDAB,N)
*          On entry, the matrix A in band storage, in rows KL+1 to
*          2*KL+KU+1; rows 1 to KL of the array need not be set.
*          The j-th column of A is stored in the j-th column of the
*          array AB as follows:
*          AB(kl+ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(m,j+kl)
*
*          On exit, details of the factorization: U is stored as an
*          upper triangular band matrix with KL+KU superdiagonals in
*          rows 1 to KL+KU+1, and the multipliers used during the
*          factorization are stored in rows KL+KU+2 to 2*KL+KU+1.
*          See below for further details.
*
*  LDAB    (input) INTEGER
*          The leading dimension of the array AB.  LDAB >= 2*KL+KU+1.
*
*  INFO    (output) INTEGER
*          = 0: successful exit
*          < 0: if INFO = -i, the i-th argument had an illegal value
*          > 0: if INFO = +i, U(i,i) is exactly zero. The factorization
*               has been completed, but the factor U is exactly
*               singular, and division by zero will occur if it is used
*               to solve a system of equations.
*
*  Further Details
*  ===============
*
*  The band storage scheme is illustrated by the following example, when
*  M = N = 6, KL = 2, KU = 1:
*
*  On entry:                       On exit:
*
*      *   a12  a23  a34  a45  a56      *   u12  u23  u34  u45  u56
*     a11  a22  a33  a44  a55  a66     u11  u22  u33  u44  u55  u66
*     a21  a32  a43  a54  a65   *      m21  m32  m43  m54  m65   *
*     a31  a42  a53  a64   *    *      m31  m42  m53  m64   *    *
*
*  Array elements marked * are not used by the routine; elements marked
*  + need not be set on entry, but are required by the routine to store
*  elements of U, because of fill-in resulting from the row
*  interchanges.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0 )
      parameter( zero = 0.0d+0 )
      COMPLEX*16         CONE, CZERO
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
      parameter( czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            J, JP, JU, KM, KV
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      EXTERNAL           isamax
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgeru, zscal, zswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     KV is the number of superdiagonals in the factor U, allowing for
*     fill-in.
*
      kv = ku
*
*     Test the input parameters.
*
      info = 0
*ECA  IF( M.LT.0 ) THEN
*ECA     INFO = -1
*ECA  ELSE IF( N.LT.0 ) THEN
*ECA     INFO = -2
*ECA  ELSE IF( KL.LT.0 ) THEN
*ECA     INFO = -3
*ECA  ELSE IF( KU.LT.0 ) THEN
*ECA     INFO = -4
*ECA  ELSE IF( LDAB.LT.KL+KV+1 ) THEN
*ECA     INFO = -6
*ECA  END IF
*ECA  IF( INFO.NE.0 ) THEN
*ECA     CALL XERBLA( 'ZDBTF2', -INFO )
*ECA     RETURN
*ECA  END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Gaussian elimination without partial pivoting
*
*     JU is the index of the last column affected by the current stage
*     of the factorization.
*
      ju = 1
*
      DO 40 j = 1, min( m, n )
*
*        Test for singularity. KM is the number of
*        subdiagonal elements in the current column.
*
         km = min( kl, m-j )
         jp = 1
         IF( ab( kv+1, j ).NE.zero ) THEN
            ju = max( ju, min( j+ku, n ) )
*
            IF( km.GT.0 ) THEN
*
*              Compute multipliers.
*
               CALL zscal( km, one / ab( ku+1, j ), ab( ku+2, j ), 1 )
*
*              Update trailing submatrix within the band.
*
               IF( ju.GT.j ) THEN
                  CALL zgeru( km, ju-j, -cone, ab( ku+2, j ), 1,
     $                       ab( ku, j+1 ), ldab-1, ab( ku+1, j+1 ),
     $                       ldab-1 )
               END IF
            END IF
         ELSE
*
            IF( info.EQ.0 )
     $         info = j
         END IF
   40 CONTINUE
      RETURN
*
*     End of ZDBTF2
*

Here is the caller graph for this function: